JAcousticsMonitorPeriod.sh

Go to the documentation of this file.

#!/bin/zsh                                                                                                                                        
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable:  WORKDIR     ACOUSTICS_WORKDIR      ./
set_variable:  FORMAT      GRAPHICS_FORMAT        gif
 
if do_usage $*; then
    usage "$script <detector file> minrun maxrun"
fi
 
if (( $# == 3 )); then
    set_variable  DETECTOR        $argv[1]
    set_variable  MINRUN          $argv[2]
    set_variable  MAXRUN          $argv[3]
else
    fatal "Wrong number of arguments."
fi
 
JCookie.sh
 
eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`
eval `JPrintDetector -a $DETECTOR -O SUMMARY`
 
JAcoustics.sh   $DETECTOR_ID
 
source JAcousticsToolkit.sh
 
CHECK_EXIT_CODE
 
set_variable  MONITOR_FILE_WEEK     $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${MINRUN}_${MAXRUN}_monitor.root
set_variable  TEST_FILE_WEEK        $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${MINRUN}_${MAXRUN}_test.root
set_variable  PLOT_ACOUS_RATE       $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${MINRUN}_${MAXRUN}_acous_rate
set_variable  PLOT_ACOUS_RATE_TEST  $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${MINRUN}_${MAXRUN}_acous_rate-test 
set_variable  NUM_RUNS              $(($MAXRUN - $MINRUN + 1))
set_array     MONITOR_FILES
set_array     TEST_FILES
 
for ((RUN=$MINRUN; RUN<=$MAXRUN; RUN++)); do
 
    set_variable  MONITOR_FILE      $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_monitor.root
    set_variable  TEST_FILE         $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_test.root
 
    MONITOR_FILES+=($MONITOR_FILE)
    TEST_FILES+=($TEST_FILE)
 
    if [[ ! -f $MONITOR_FILE || ! -f $TEST_FILE ]]; then
        $JPP_DIR/examples/JAcoustics/JAcousticsMonitor_short.sh $DETECTOR $RUN $RUN 0
    fi
 
done
 
hadd -f $MONITOR_FILE_WEEK $MONITOR_FILES
hadd -f $TEST_FILE_WEEK $TEST_FILES
 
typeset -A EMITTERS
 
get_tripods+     $WORKDIR/tripod.txt       EMITTERS
get_transmitters+ $WORKDIR/transmitter.txt EMITTERS
 
for EMITTER in ${(@k)EMITTERS}; do
 
    JScale1D \
        -f "${MONITOR_FILE_WEEK}:H\[${EMITTER}\].event"   \
        -F "1.0/$NUM_RUNS"                                \
        -o "scale.root"                                   >& /dev/null
 
    JPlot2D \
        -f "scale.root:H\[${EMITTER}\].event"             \
        -> "string"                                      \
        -< "floor"                                       \
        -\^ "rate [Hz]"                                   \
        -O COLZ                                           \
        -p "57"                                           \
        -T "Emitter ${EMITTER}"                           \
        -o ${PLOT_ACOUS_RATE}_\[${EMITTER}\].$FORMAT      -B
 
    JScale1D \
        -f "${TEST_FILE_WEEK}:H\[${EMITTER}\].rate-test"  \
        -F "1.0/$NUM_RUNS"                                \
        -o "scale_test.root"                              >& /dev/null
 
    JPlot2D \
        -f "scale_test.root:H\[${EMITTER}\].rate-test"    \
        -> "string"                                      \
        -< "floor"                                       \
        -\^ "fraction of runs outside the rate range"     \
        -z "0 1"                                          \
        -O COLZ                                           \
        -T "Emitter ${EMITTER}"                           \
        -o ${PLOT_ACOUS_RATE_TEST}_\[${EMITTER}\].$FORMAT -B
 
        #remove temporary files
        rm -f "scale.root"
        rm -f "scale_test.root"
done
 
if [[ -f ${PLOT_ACOUS_RATE}.$FORMAT ]]; then
    rm -f ${PLOT_ACOUS_RATE}.$FORMAT
fi
 
if [[ -f ${PLOT_ACOUS_RATE_TEST}.$FORMAT ]]; then
    rm -f ${PLOT_ACOUS_RATE_TEST}.$FORMAT
fi
 
set_array start_time $(JRuns -D "$DETECTOR_ID" -@ "run = ${MINRUN}" -F UNIXJOBSTART -F UNIXJOBEND --)
set_array end_time $(JRuns -D "$DETECTOR_ID" -@ "run = ${MAXRUN}" -F UNIXJOBSTART -F UNIXJOBEND --)
 
set_variable start_time_h $(date '+%d-%m-%Y %H:%M' -d @$(($start_time[1]/1000)))
set_variable end_time_h $(date '+%d-%m-%Y %H:%M' -d @$(($end_time[2]/1000)))
 
montage                       \
    -tile 3x10                \
    -geometry +0+10            \
    -title "Average acoustic rate \n Runs: ${MINRUN}-${MAXRUN}, Time: ${start_time_h} - ${end_time_h}" \
    ${PLOT_ACOUS_RATE}_*.$FORMAT \
    ${PLOT_ACOUS_RATE}.$FORMAT  >& /dev/null
 
montage                            \
    -tile 3x10                     \
    -geometry +0+10                 \
    -title "Fraction of runs outside accepted rate range: 10% < rate < 102% of the expected rate \n Runs: ${MINRUN}-${MAXRUN}, Time: ${start_time_h} - ${end_time_h}" \
    ${PLOT_ACOUS_RATE_TEST}_*.$FORMAT \
    ${PLOT_ACOUS_RATE_TEST}.$FORMAT  >& /dev/null
 
#clean
rm -f ${PLOT_ACOUS_RATE}_*.$FORMAT
rm -f ${PLOT_ACOUS_RATE_TEST}_*.$FORMAT