JORCAMuonReconstruction.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author bofearraigh
#
script=${0##*/}
 
# ------------------------------------------------------------------------------------------
#
#                         Script to run the JPP Track Reconstruction Chain for ORCA.
#
# ------------------------------------------------------------------------------------------
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
source $JPP_DIR/externals/km3net-dataformat/definitions/reconstruction.sh
 
set_variable:  DEBUG             RECONSTRUCTION_DEBUG                1
set_variable:  PDF               RECONSTRUCTION_PDF                  $JPP_DATA/J%p.dat
set_variable:  SUFFIX            RECONSTRUCTION_SUFFIX               jmuon
set_variable:  NUMBER_OF_EVENTS  RECONSTRUCTION_NUMBER_OF_EVENTS     $((2**31))
set_variable+  OVERWRITE         RECONSTRUCTION_OVERWRITE            1
set_variable:  TMAX_S            RECONSTRUCTION_TMAX_S               100
 
if do_usage $*; then
    usage "$script <detector file> <input file> <output file> <PMT parameters file> [(calibration file)+]"
fi
 
if (( $# < 4 )); then
    fatal "Wrong number of arguments."
fi
 
set_variable DETECTOR        $argv[1]
set_variable INPUT_FILE      $argv[2]
set_variable OUTPUT_FILE     $argv[3]
set_variable PMT             $argv[4]
set_array    CALIBRATION     $argv[5,-1]
 
if [[ ! "$OUTPUT_FILE" == *"%"* ]]; then
  fatal "The output file must have the wildcard % in the name, e.g. %.root"
fi
 
typeset -A PARAMETERS
typeset -a APPLICATIONS
 
APPLICATIONS=()
 
 
if [[ "$OVERWRITE" == 1 ]]; then
    rm -vf \
        ${OUTPUT_FILE/\%/jprefit}         \
        ${OUTPUT_FILE/\%/jsimplex}        \
        ${OUTPUT_FILE/\%/jstart}          \
        ${OUTPUT_FILE/\%/jgandalf}        \
        ${OUTPUT_FILE/\%/jstart2}         \
        ${OUTPUT_FILE/\%/jenergy}         \
        ${OUTPUT_FILE/\%/jhistory}        \
        ${OUTPUT_FILE/\%/${SUFFIX}}       \
        ${OUTPUT_FILE/\%/${SUFFIX}.offline}
fi
 
 
if (( ${#CALIBRATION} != 0 )); then
    getMechanics.sh  $DETECTOR
fi
 
 
# ------------------------------------------------------------------------------------------
#                                       JMuonPrefit
# ------------------------------------------------------------------------------------------
 
PARAMETERS=(
    sigma_ns           5
    gridAngle_deg      4
    useL0              1
    numberOfOutliers   2
    numberOfPrefits    50
    DZMax              0.0
    numberOfDZMax      1
    TMaxLocal_ns       12
    ctMin              0.0
    roadWidth_m        50.0
    Qmin               1.5)
 
timer_start
 
eval JMuonPrefit \
    -a $DETECTOR                   \
    -+${^CALIBRATION}              \
    -T $TMAX_S                     \
    -f $INPUT_FILE                 \
    -o ${OUTPUT_FILE/\%/jprefit}   \
    -n ${NUMBER_OF_EVENTS}         \
    -@ `make_equation PARAMETERS`  \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
APPLICATIONS+=$JMUONPREFIT
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JMuonSimplex
# ------------------------------------------------------------------------------------------
 
PARAMETERS=(
    sigma_ns         3
    TMaxLocal_ns     15.0
    ctMin            0.0
    roadWidth_m      50.0
    numberOfPrefits  0)
 
timer_start
 
eval JMuonSimplex \
    -a $DETECTOR                   \
    -+${^CALIBRATION}              \
    -T $TMAX_S                     \
    -f ${OUTPUT_FILE/\%/jprefit}   \
    -o ${OUTPUT_FILE/\%/jsimplex}  \
    -@ `make_equation PARAMETERS`  \
    -d ${DEBUG} --!
 
CHECK_EXIT_CODE
 
rm -vf ${OUTPUT_FILE/\%/jprefit}
 
APPLICATIONS+=$JMUONSIMPLEX
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JMuonStart
# ------------------------------------------------------------------------------------------
 
PARAMETERS=(
    roadWidth_m      50.0
    R_Hz             7.0e3
    TMin_ns          -25.0
    TMax_ns          +25.0
    Pmin1            1.0e-3
    Pmin2            1.0e-2
    numberOfPrefits  0)
 
timer_start
 
eval JMuonStart \
    -a $DETECTOR                   \
    -+${^CALIBRATION}              \
    -T $TMAX_S                     \
    -f ${OUTPUT_FILE/\%/jsimplex}  \
    -o ${OUTPUT_FILE/\%/jstart}    \
    -P $PDF                        \
    -@ `make_equation PARAMETERS`  \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
rm -vf ${OUTPUT_FILE/\%/jsimplex}
 
APPLICATIONS+=$JMUONSTART
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JMuonGandalf
# ------------------------------------------------------------------------------------------
 
PARAMETERS=(
    TTS_ns          2
    E_GeV           10.0
    TMin_ns         -50.0
    TMax_ns         +450.0
    ZMin_m          -3.0
    ZMax_m          +9.0
    R_Hz            7.0e3
    roadWidth_m     50.0
    numberOfPrefits   0)
 
timer_start
 
eval JMuonGandalf \
    -a $DETECTOR                   \
    -+${^CALIBRATION}              \
    -T $TMAX_S                     \
    -f ${OUTPUT_FILE/\%/jstart}    \
    -o ${OUTPUT_FILE/\%/jgandalf}  \
    -P $PDF                        \
    -@ `make_equation PARAMETERS`  \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
rm -vf ${OUTPUT_FILE/\%/jstart}
 
APPLICATIONS+=$JMUONGANDALF
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JMuonStart
# ------------------------------------------------------------------------------------------
 
PARAMETERS=(
    roadWidth_m      50.0
    R_Hz             7.0e3
    TMin_ns          -25.0
    TMax_ns          +25.0
    Pmin1            1.0e-3
    Pmin2            1.0e-2
    numberOfPrefits  1)
 
timer_start
 
eval JMuonStart \
    -a $DETECTOR                   \
    -+${^CALIBRATION}              \
    -T $TMAX_S                     \
    -f ${OUTPUT_FILE/\%/jgandalf}  \
    -o ${OUTPUT_FILE/\%/jstart2}   \
    -P $PDF                        \
    -@ `make_equation PARAMETERS`  \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
rm -vf ${OUTPUT_FILE/\%/jgandalf}
 
APPLICATIONS+=$JMUONSTART
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JMuonEnergy
# ------------------------------------------------------------------------------------------
 
PARAMETERS=(
    roadWidth_m      80.0
    R_Hz             7.0e3
    EMin_log         0.0
    EMax_log         7.0
    TMin_ns          -25.0
    TMax_ns          +25.0
    ZMin_m          -3.0    
    resolution       0.01
    mestimator       3
    numberOfPrefits  1)
 
timer_start
 
eval JMuonEnergy \
    -a $DETECTOR                   \
    -+${^CALIBRATION}              \
    -T $TMAX_S                     \
    -f ${OUTPUT_FILE/\%/jstart2}   \
    -o ${OUTPUT_FILE/\%/jenergy}   \
    -P $PDF                        \
    -@ `make_equation PARAMETERS`  \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
rm -vf ${OUTPUT_FILE/\%/jstart2}
 
APPLICATIONS+=$JMUONENERGY
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JHistory
# ------------------------------------------------------------------------------------------
 
timer_start
 
JHistory \
    -f ${OUTPUT_FILE/\%/jenergy}   \
    -o ${OUTPUT_FILE/\%/jhistory}  \
    -A "$APPLICATIONS[*]"          \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
rm -vf ${OUTPUT_FILE/\%/jenergy}
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                   rename outputfile and remove intermediate files
# ------------------------------------------------------------------------------------------
 
timer_start
 
mv -v \
    ${OUTPUT_FILE/\%/jhistory}    \
    ${OUTPUT_FILE/\%/${SUFFIX}}   
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JConvertEvt
# ------------------------------------------------------------------------------------------
 
timer_start
 
JConvertEvt \
    -f ${OUTPUT_FILE/\%/${SUFFIX}}          \
    -o ${OUTPUT_FILE/\%/${SUFFIX}.offline}  \
    -a $DETECTOR                            \
    -+${^CALIBRATION}                       \
    -T $TMAX_S                              \
    -P $PMT                                 \
    -d $DEBUG --!
 
timer_stop
timer_print