JAcousticsMonitor_short.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable:  DEBUG       ACOUSTICS_DEBUG        2
set_variable:  WORKDIR     ACOUSTICS_WORKDIR      ./
set_variable:  FORMAT      GRAPHICS_FORMAT        gif
set_variable   LOGBOOK     \"Individual Logbooks\"
set_variable   AUTHOR      \"GatiusOliver C\"
set_variable   FACET       "ELcode"
 
if do_usage $*; then
    usage "$script <detector file> minrun maxrun report"\
    "\nIn case of failures, if report = 1 an elog entry is created, if report =! 1 no elog entry is created."
fi
 
if (( $# == 4 )); then
    set_variable  DETECTOR        $argv[1]
    set_variable  MINRUN          $argv[2]
    set_variable  MAXRUN          $argv[3]
    set_variable  REPORT          $argv[4]
else
    fatal "Wrong number of arguments."
fi
 
set_variable  USER            km3net
set_variable  PASSWORD        pyrosoma
 
JCookie.sh 
 
eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`
eval `JPrintDetector -a $DETECTOR -O SUMMARY`
 
JAcoustics.sh   $DETECTOR_ID
 
source JAcousticsToolkit.sh
 
CHECK_EXIT_CODE
 
for ((RUN=$MINRUN; RUN<=$MAXRUN; RUN++)); do
 
    set_variable  INPUT_FILE        $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_toashort.root
    set_variable  OUTPUT_FILE       $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_event.root
    set_variable  MONITOR_FILE      $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_monitor.root
    set_variable  SUMMARY_FILE      $WORKDIR/summary_${(l:8::0::0:)RUN}.txt
    set_variable  TEST_FILE         $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_test.root
    set_variable  PARAMETERS_FILE   $JPP_DIR/examples/JAcoustics/acoustics_monitor_${(l:8::0::0:)DETECTOR_ID}.txt
 
    if [[ ! -f $INPUT_FILE ]]; then
 
        JConvertDB \
        -q toashort                                  \
        -@ "detid  = `getDetector -D $DETECTOR_ID`"  \
        -@ "minrun = $RUN"                           \
        -@ "maxrun = $RUN"                           \
        -o $INPUT_FILE                               \
        -d $DEBUG --!                                
    fi
 
    if [[ ! -f $OUTPUT_FILE ]]; then
 
        JAcousticsEventBuilder \
        -a $DETECTOR                                 \
        -f $INPUT_FILE                               \
        -T $WORKDIR/tripod.txt                       \
        -Y $WORKDIR/transmitter.txt                  \
        -V $WORKDIR/sound_velocity.txt               \
        -W $WORKDIR/waveform.txt                     \
        -@ $WORKDIR/acoustics_trigger_parameters.txt \
        -H $WORKDIR/hydrophone.txt                   \
        -o $OUTPUT_FILE                              \
        -d $DEBUG --!                                
    fi
 
    set_array time_range $(JRuns -D "$DETECTOR_ID" -@ "run = ${RUN}" -F UNIXJOBSTART -F UNIXJOBEND --)
   
    set_variable lifetime_s $(( ($time_range[2]-$time_range[1])/1000 ))
    
    #if lifetime is unknown, assume 6hr
    if [ -z "$lifetime_s" ]; then
        lifetime_s=21600
    
    #avoid 0 sec lifetime
    elif (($lifetime_s == 0)); then
        lifetime_s=1
    fi
    
    $JPP_DIR/examples/JAcoustics/JAcousticsMonitor_short \
    -a $DETECTOR                                         \
    -f $OUTPUT_FILE                                      \
    -l $lifetime_s                                       \
    -o $MONITOR_FILE                                     \
    -d $DEBUG                                            
 
    read -r NUMBER_OF_FAILURES <<< "$($JPP_DIR/examples/JAcoustics/JAcousticsMonitorTest  \
    -f $MONITOR_FILE                                    \
    -a $DETECTOR                                        \
    -P $PARAMETERS_FILE                                 \
    -F $FACET                                           \
    -w $SUMMARY_FILE                                    \
    -t $TEST_FILE                                       \
    -r $RUN                                             \
    -d "1")"
 
 
    #report to e-log
    if [[ ${NUMBER_OF_FAILURES[-1]} -gt 0 && $REPORT == 1 ]]; then
 
        typeset -A EMITTERS
 
        get_tripods+     $WORKDIR/tripod.txt       EMITTERS
        get_transmitters+ $WORKDIR/transmitter.txt EMITTERS
 
        ATTACHMENTS=""
 
        for EMITTER in ${(@k)EMITTERS}; do
 
            JPlot2D \
                -f "${MONITOR_FILE}:H\[${EMITTER}\].event"         \
                -> "string"                                       \
                -< "floor"                                        \
                -\^ "rate [Hz]"                                    \
                -O COLZ                                            \
                -p "57"                                            \
                -T "Emitter ${EMITTER}"                            \
                -o $WORKDIR/rate\[${EMITTER}\]_${RUN}.$FORMAT      \
                -B
 
            JPlot2D \
                -f "${TEST_FILE}:H\[${EMITTER}\].rate-test"        \
                -> "string"                                       \
                -< "floor"                                        \
                -z "0 1"                                           \
                -O COLZ                                            \
                -T "Emitter ${EMITTER}"                            \
                -o $WORKDIR/rate-test\[${EMITTER}\]_${RUN}.$FORMAT \
                -B
        done
 
        set_variable  PLOT_ACOUS_RATE       $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${RUN}_acous_rate
        set_variable  PLOT_ACOUS_RATE_TEST  $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${RUN}_acous_rate-test
 
        montage                          \
            -tile 3x10                   \
            -geometry +0+10              \
            -title "Average acoustic rate \n Run: ${RUN}" \
            $WORKDIR/rate\[*\]_${RUN}.$FORMAT \
            $WORKDIR/${PLOT_ACOUS_RATE}.$FORMAT  >& /dev/null
 
        montage                               \
            -tile 3x10                        \
            -geometry +0+10                   \
            -title "In red modules measuring a rate out of the accepted rate range: 10% < rate < 102% of the expected rate \n Run: ${RUN}" \
            $WORKDIR/rate-test\[*\]_${RUN}.$FORMAT \
            $WORKDIR/${PLOT_ACOUS_RATE_TEST}.$FORMAT  >& /dev/null
 
        ATTACHMENTS+=" -f $WORKDIR/${PLOT_ACOUS_RATE}.$FORMAT"
        ATTACHMENTS+=" -f $WORKDIR/${PLOT_ACOUS_RATE_TEST}.$FORMAT"
 
        eval elog                \
        -h elog.km3net.de        \
        -p 3000                  \
        -u $USER $PASSWORD       \
        -l $LOGBOOK              \
        -a Subject=\"Warning detector ID ${DETECTOR_ID}\"  \
        -a Type=\"Acoustics monitoring\"         \
        -a Author=$AUTHOR        \
        -n 0 -v                  \
        -m $SUMMARY_FILE         \
        $ATTACHMENTS
 
        #remove temporary files
        rm -f $WORKDIR/rate*_${RUN}.$FORMAT
        rm -f $SUMMARY_FILE
        rm -f $WORKDIR/${PLOT_ACOUS_RATE}.$FORMAT
        rm -f $WORKDIR/${PLOT_ACOUS_RATE_TEST}.$FORMAT
 
    fi
 
    CHECK_EXIT_CODE
    
done