JFootprint.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable:  DEBUG    ACOUSTICS_DEBUG    2
set_variable:  WORKDIR  ACOUSTICS_WORKDIR  ./
 
if do_usage $*; then
    usage "$script <detector file> <tripod file> <Tx> <Ty>"\
          "\nAuxiliary script to tilt footprint of system including detector and tripods."
fi
 
if (( $# != 4 )); then
    fatal "Wrong number of arguments."
fi
 
set_variable  DETECTOR            $argv[1]
set_variable  TRIPOD              $argv[2]
set_variable  TX                  $argv[3]
set_variable  TY                  $argv[4]
 
if [[ ! -f $DETECTOR ]]; then
    fatal "No detector file $DETECTOR."
fi
 
if [[ ! -f $TRIPOD ]]; then
    fatal "No tripod file $TRIPOD."
fi
 
source JAcousticsToolkit.sh
 
CHECK_EXIT_CODE
 
typeset -A TRIPODS
 
get_tripods $TRIPOD TRIPODS
 
if (( ${#TRIPODS} == 0 )); then
    fatal "Number of tripods ${#TRIPODS}."
fi
 
let "X_CENTER = 0.0"
let "Y_CENTER = 0.0"
 
for _X _Y _Z in `echo ${(@v)TRIPODS}`; do
    let "X_CENTER = $X_CENTER + $_X"
    let "Y_CENTER = $Y_CENTER + $_Y"
done
 
let "X_CENTER = $X_CENTER / ${#TRIPODS}"
let "Y_CENTER = $Y_CENTER / ${#TRIPODS}"
 
printf "\ncenter %15.5f %15.5f\n\n"  $X_CENTER  $Y_CENTER
 
# Modify tripod positions
 
for ID in ${(k)TRIPODS}; do
                
    echo $TRIPODS[${ID}] | read X Y Z
 
    let "DZ = ${TX} * (${X} - ${X_CENTER}) + ${TY} * (${Y} - ${Y_CENTER})"
 
    JEditTripod -f $TRIPOD -T "$ID add 0.0 0.0 $DZ" -o $TRIPOD --!
done
 
 
# Modify module positions
 
eval `JPrintDetector -a $DETECTOR -O HEADER`
 
typeset -a OPTION
 
JPrintDetector -a $DETECTOR -O modules | while read KEY MODULE STRING FLOOR X Y Z T0; do
 
    let "DZ = $TX * ($X + $UTM_EAST - $X_CENTER)  +  $TY * ($Y + $UTM_NORTH - $Y_CENTER)"
 
    OPTION+=("$MODULE add 0.0 0.0 $DZ;")
done
 
JEditDetector \
    -a $DETECTOR                              \
    -M${^OPTION}                              \
    -o $DETECTOR                              \
    -d $DEBUG --!