JTurbot.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author mdejong
#
version=1.0
script=${0##*/}
 
# ------------------------------------------------------------------------------------------
#
#                         Example script to run JTurbot.
#
# ------------------------------------------------------------------------------------------
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
set_variable   DEBUG       1
set_variable   WORKDIR     ./
set_variable   DETECTOR    detector.datx
set_variable   XMIN        -1.0e9
set_variable   XMAX        +1.0e9
set_variable:  FORMAT      GRAPHICS_FORMAT       gif
set_variable+  BATCH       GRAPHICS_BATCH        -B
 
if do_usage $*; then
    usage "$script <input file>"
fi
 
if (( $# != 1 )); then
    fatal "Wrong number of arguments."
fi
 
set_variable   INPUT_FILE  $1
 
JCookie.sh
 
typeset -Z 8 DETECTOR_ID
typeset -Z 8 RUN
 
JPrintDAQHeader -f $INPUT_FILE  |  read DETECTOR_ID RUN FRAME_INDEX UTC
 
if [[ ! -f $DETECTOR ]]; then
    JDetectorDB -D $DETECTOR_ID -r $RUN -o $DETECTOR
fi
 
if ( ! reuse_file turbot_${RUN}.root ); then
 
    JTurbot \
        -a $DETECTOR                     \
        -f $INPUT_FILE                   \
        -d 1                             \
        -o turbot_${RUN}.root            >& turbot_${RUN}.log
fi
 
eval `JPrintDetector -a $DETECTOR -O SUMMARY`
 
kill_child_processes_at_exit
 
attach getModule -a $DETECTOR
 
typeset -Z 4 STRING
typeset -Z 2 FLOOR
 
for STRING in $STRINGS[*]; do
 
    echo -n "Creating graphics for string $STRING.."
 
    for (( FLOOR = 1; $FLOOR <= 18; FLOOR += 1 )); do
 
        sput $STRING $FLOOR
        sget  MODULE
 
        JPlot1D \
            -f turbot_${RUN}.root:M_${MODULE}                        \
            -x "$XMIN $XMAX"                                         \
            -> "#Deltat [ns]"                                       \
            -T "${STRING}.${FLOOR} ($MODULE)"                        \
            -o ${TMPDIR:-/tmp}/M_${STRING}_${FLOOR}.$FORMAT          $BATCH
    done
 
    montage \
        -tile 6x3                                      \
        -geometry +0+0                                 \
        ${TMPDIR:-/tmp}/M_${STRING}_{01..18}.$FORMAT   \
        M_${STRING}.$FORMAT                            >& /dev/null
 
    echo " -> M_${STRING}.$FORMAT"
 
    rm -f ${TMPDIR:-/tmp}/M_${STRING}_*.$FORMAT
done