archive-input_data.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable:  WORKDIR        ARCHIVE_WORKDIR        ${TMPDIR:-/tmp}/
set_variable:  VERSION        ARCHIVE_VERSION        \*
set_array      RUNS           1  99999999
 
 
if do_usage $*; then
    usage "$script <archive> <detector> <directory>"\
          "\nAuxiliary script to check auxiliary data in archive for a given detector."\
          "\nThe directory corresponds to the location of the input tables (see https://git.km3net.de/calibration/input_tables) "\
          "\nand the archive to auxiliary data (see https://git.km3net.de/auxiliary_data/jpp)."
fi
 
if (( $# != 3 )); then
    fatal "Wrong number of arguments."
fi
 
set_variable  ARCHIVE         $argv[1]
set_variable  DETECTOR        $argv[2]
set_variable  DIR             $argv[3]
 
 
JCookie.sh
 
set_variable  DETECTOR      `getDetector -D $DETECTOR -O string`
let          "DETECTOR_ID = `getDetector -D $DETECTOR -O int`"
 
 
# map name in input_data/data/ to name in auxiliary_data/jpp/
 
typeset -A BUFFER
 
BUFFER[tripods]=tripod
BUFFER[baseAcousticBeacon]=transmitter
BUFFER[hydrophones]=hydrophone
BUFFER[waveforms]=waveform
 
 
# processing functions
 
function typeout()
{
    grep -E -v "^#" $1  |  tail -n+2  |  tr ',' ' '  
}
 
function typeout_tripod()
{
    typeout  $1
}
 
function typeout_hydrophone()
{
    typeout  $1  |  awk -v DEGTORAD=0.017453293 '{ $5 *= DEGTORAD; if ($2 != -1) { print $1, $2,     ($3 * -cos($5) + $4 * -sin($5)), ($3 * +sin($5) + $4 * -cos($5)), $6 }}'
}
 
function typeout_transmitter()
{
    typeout  $1  |  awk -v DEGTORAD=0.017453293 '{ $6 *= DEGTORAD; if ($3 != -1) { print $1, $2, $3, ($4 * -cos($6) + $5 * -sin($6)), ($4 * +sin($6) + $5 * -cos($6)), $7 }}'
}
 
function typeout_waveform()
{
    typeout  $1
}
 
 
# format aliases with given precision
 
alias format_tripod='awk "{ printf \"%2d %+12.${PRECISION}f %+12.${PRECISION}f %+9.${PRECISION}f\n\", \$1, \$2, \$3, \$4 }"'
alias format_transmitter='awk "{ printf \"%2d %3d %2d %7.${PRECISION}f %7.${PRECISION}f %7.${PRECISION}f\n\", \$1, \$2, \$3, \$4, \$5, \$6 }"'
alias format_hydrophone='awk "{ printf \"%2d %3d %7.${PRECISION}f %7.${PRECISION}f %7.${PRECISION}f\n\", \$1, \$2, \$3, \$4, \$5 }"'
alias format_waveform='awk "{ printf \"%3d  %d\n\", \$1, \$2 }"'
 
 
# comparison
 
function compare()
{
    set_variable   PRECISION      2
 
    eval grep -E  -v \"^#\"  $1  \|  $3  >  $WORKDIR/.A.txt
    eval grep -E  -v \"^#\"  $2  \|  $3  >  $WORKDIR/.B.txt
    
    diff   $WORKDIR/.A.txt  $WORKDIR/.B.txt; export RESULT=$?
    rm -f  $WORKDIR/.A.txt  $WORKDIR/.B.txt
}
 
 
for KEY VALUE in ${(kv)BUFFER}; do
 
    set_variable  INPUT_FILE  $DIR/data/$DETECTOR/${DETECTOR}_${KEY}.csv
 
    if [[ -f $INPUT_FILE ]]; then
 
        set_variable   PRECISION      4
 
        eval  typeout_$VALUE   $INPUT_FILE  \|  format_$VALUE  >  $WORKDIR/${VALUE}.txt 
        
        rm -f  $WORKDIR/${VALUE}_A.txt
 
        getFile.sh  $ARCHIVE  $DETECTOR_ID  $RUNS[1]  $VALUE  master  $WORKDIR/${VALUE}_A >& /dev/null
 
        echo -n "Comparing ${INPUT_FILE:t} with archived file..."
        
        compare  $WORKDIR/${VALUE}_A.txt  $WORKDIR/${VALUE}.txt  format_$VALUE
        
        if (( $RESULT == 0 )); then
            echo "$GREEN OK $RESET"
        else
            echo "$RED Alternative input file $WORKDIR/${VALUE}.txt. $RESET"
        fi
    fi
done