plot-PMTParameters2D.sh

Go to the documentation of this file.

#!/bin/zsh
#
#
# \author mdejong
#
version=1.0
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
 
set_variable   DEBUG           3                             
set_variable   WORKDIR         `pwd`                         
set_variable   OUTPUT_FILE     $WORKDIR/pmt_parameters.root  
set_variable   DIR             $JPP_DIR/examples/JDetector/  
set_variable:  FORMAT          GRAPHICS_FORMAT        gif
set_variable+  BATCH           GRAPHICS_BATCH         -B
 
if do_usage $*; then
    usage "$script <detector file> (PMT parameters file)+"
fi
 
if (( $# < 2 )); then
    fatal "Wrong number of parameters."
fi
 
set_variable     DETECTOR                $argv[1]
set_array        INPUT_FILES             $argv[2,-1]
 
$DIR/JPlotPMTParameters2D \
    -a  $DETECTOR       \
    -P "$INPUT_FILES"   \
    -o  $OUTPUT_FILE    \
    -d  $DEBUG -A --!
 
# parameters and plot ranges
 
typeset -A Y_RANGE
 
Y_RANGE+=(EFFICIENCY   " 0.0   1.5") 
Y_RANGE+=(QE           " 0.0   1.5") 
Y_RANGE+=(gain         " 0.0   1.5") 
Y_RANGE+=(gainSpread   " 0.0   1.0") 
Y_RANGE+=(riseTime_ns  " 0.0  15.0") 
Y_RANGE+=(TTS_ns       "-5.0  +5.0") 
Y_RANGE+=(threshold    " 0.0   1.0") 
Y_RANGE+=(slope        " 0.0  15.0") 
Y_RANGE+=(saturation   " 0.0 250.0") 
Y_RANGE+=(slewing      " 0.0   1.5") 
 
eval `JPrintDetector -a $DETECTOR -O SUMMARY`
 
set_variable  FIRST_FLOOR  1
 
kill_child_processes_at_exit
 
attach getModule -a $DETECTOR
 
typeset -Z 4 STRING
typeset -Z 2 FLOOR
 
typeset -A   PMT_RANGE
 
PMT_RANGE[-]="0-30"
PMT_RANGE[A]="0-0"
PMT_RANGE[B]="1-6"
PMT_RANGE[C]="7-12"
PMT_RANGE[D]="13-18"
PMT_RANGE[E]="19-24"
PMT_RANGE[F]="25-30"
 
for STRING in $STRINGS[*]; do
 
    for (( FLOOR = $FIRST_FLOOR; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do
 
        sput $STRING $FLOOR
        sget  MODULE
 
        for KEY in ${(k)Y_RANGE}; do
 
            debug "($STRING,$FLOOR) $KEY"
 
            JPlot2D \
                -f ${OUTPUT_FILE}:${MODULE}\.${KEY}\$                    \
                -z $Y_RANGE[${KEY}]                                      \
                -O COLZ                                                  \
                -> "index"                                              \
                -< "PMT"                                                \
                -\^ "$KEY"                                               \
                -T "(${STRING},${FLOOR})"                                \
                -o ${TMPDIR:-/tmp}/${KEY}_${STRING}_${FLOOR}.$FORMAT     $BATCH
 
            for RING RANGE in ${(@kv)PMT_RANGE[*]}; do
 
                let "YMIN = ${RANGE%%-*} - 0.5"
                let "YMAX = ${RANGE##*-} + 0.5"
 
                JProject2D \
                    -f ${OUTPUT_FILE}:${MODULE}\.${KEY}\$                    \
                    -P X -y "$YMIN $YMAX"                                    \
                    -o ${TMPDIR:-/tmp}/project.root
 
                JScale1D \
                    -f ${TMPDIR:-/tmp}/project.root:\.\*                     \
                    -o ${TMPDIR:-/tmp}/scale\[$RING\].root                   \
                    -F "1.0 / ($YMAX - $YMIN)"                               \
                    -O "nosw2"
            done
 
            set_array ABC `ls -f ${TMPDIR:-/tmp}/scale\[-\].root ${TMPDIR:-/tmp}/scale\[[A-Z]\].root`
 
            JPlot1D \
                -f${^ABC}:\.\*                                           \
                -y $Y_RANGE[${KEY}]                                      \
                -> "index"                                              \
                -\^ "<$KEY>"                                             \
                -L BL                                                    \
                -T "(${STRING},${FLOOR})"                                \
                -o ${TMPDIR:-/tmp}/P_${KEY}_${STRING}_${FLOOR}.$FORMAT   $BATCH
        done
    done
 
    for KEY in ${(k)Y_RANGE}; do
 
        montage \
            -tile 6x3                                             \
            -geometry +0+0                                        \
            ${TMPDIR:-/tmp}/${KEY}_${STRING}_{01..18}.$FORMAT     \
            $WORKDIR/${KEY}_${STRING}.$FORMAT                     >& /dev/null
    done
 
    for KEY in ${(k)Y_RANGE}; do
 
        montage \
            -tile 6x3                                             \
            -geometry +0+0                                        \
            ${TMPDIR:-/tmp}/P_${KEY}_${STRING}_{01..18}.$FORMAT   \
            $WORKDIR/P_${KEY}_${STRING}.$FORMAT                   >& /dev/null
    done
done
 
detach