examples/JReconstruction/JORCAShowerReconstruction.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
# \author adomi
#
script=${0##*/}
 
 
# ------------------------------------------------------------------------------------------
#
#                         Script to run the JPP Shower Reconstruction Chain for ORCA.
#
# ------------------------------------------------------------------------------------------
 
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
 
source reconstruction.sh
 
set_variable:  DEBUG              RECONSTRUCTION_DEBUG                1
set_variable:  PDF                RECONSTRUCTION_PDF                  $JPP_DATA/J%p.dat.gz
set_variable:  SUFFIX             RECONSTRUCTION_SUFFIX               jshower
set_variable:  ENERGY_CORRECTION  RECONSTRUCTION_ENERGY_CORRECTION    energy_correction_showerfit_fullorca.txt
set_variable:  NUMBER_OF_EVENTS   RECONSTRUCTION_NUMBER_OF_EVENTS     $((2**31))
set_variable:  NUMBER_OF_THREADS  RECONSTRUCTION_NUMBER_OF_THREADS    0
set_variable+  OVERWRITE          RECONSTRUCTION_OVERWRITE            1
set_variable:  TMAX_S             RECONSTRUCTION_TMAX_S               100
set_variable:  RATE_HZ            RECONSTRUCTION_RATE_HZ              6.0e3
 
if do_usage $*; then
    usage "$script <detector file> <input file> <output file> <PMT parameters file> [(calibration file)+]"
fi
 
set_variable DETECTOR        $argv[1]
set_variable INPUT_FILE      $argv[2]
set_variable OUTPUT_FILE     $argv[3]
set_variable PMT             $argv[4]
set_array    CALIBRATION     $argv[5,-1]
 
if [[ ! "$OUTPUT_FILE" == *"%"* ]]; then
    fatal "The output file must have the wildcard % in the name, e.g. %.root"
fi
 
typeset -A PARAMETERS
typeset -a APPLICATIONS
 
APPLICATIONS=()
 
 
if [[ "$OVERWRITE" == 1 ]]; then
    rm -vf \
           ${OUTPUT_FILE/\%/jshprefit}          \
           ${OUTPUT_FILE/\%/jshpointsimplex}    \
           ${OUTPUT_FILE/\%/jshpositionfit}     \
           ${OUTPUT_FILE/\%/jshdirectionprefit} \
           ${OUTPUT_FILE/\%/jshfit}             \
           ${OUTPUT_FILE/\%/jhistory}           \
           ${OUTPUT_FILE/\%/${SUFFIX}}          \
           ${OUTPUT_FILE/\%/${SUFFIX}.offline}
fi
 
 
# ------------------------------------------------------------------------------------------
#                                       JShowerPrefit
# ------------------------------------------------------------------------------------------
 
PARAMETERS=(
    numberOfPrefits          200
    numberOfGrids            2
    factoryLimit             20
    sigma_ns                 2.5
    numberOfOutliers         4
    TMaxLocal_ns             10.0
    TMaxExtra_ns             80.0
    ctMin                    -0.3
    DMax_m                   50.0
    pos_grid_m               10.0
    pos_step_m               10.0
    time_grid_ns             50.0
    time_step_ns             50.0)
 
timer_start
 
eval JShowerPrefit                      \
     -a $DETECTOR                        \
     -+${^CALIBRATION}                   \
     -T $TMAX_S                          \
     -f $INPUT_FILE                      \
     -o ${OUTPUT_FILE/\%/jshprefit}      \
     -n ${NUMBER_OF_EVENTS}              \
     -N ${NUMBER_OF_THREADS}             \
     -@ `make_equation PARAMETERS`       \
     -d ${DEBUG} --!
 
CHECK_EXIT_CODE
 
APPLICATIONS+=$JSHOWERPREFIT
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JShowerPointSimplex
# ------------------------------------------------------------------------------------------
 
PARAMETERS=(
    numberOfPrefits         0
    sigma_ns                2.5
    TMaxLocal_ns            15.0
    TMax_ns                 +60.0
    TMin_ns                 -60.0
    DMax_m                  50.0
    ctMin                   0.0
    mestimator              1)
 
timer_start
 
eval JShowerPointSimplex                  \
     -a $DETECTOR                          \
     -+${^CALIBRATION}                     \
     -T $TMAX_S                            \
     -N ${NUMBER_OF_THREADS}               \
     -f ${OUTPUT_FILE/\%/jshprefit}        \
     -o ${OUTPUT_FILE/\%/jshpointsimplex}  \
     -@ `make_equation PARAMETERS`         \
     -d ${DEBUG} --!
 
CHECK_EXIT_CODE
 
rm -vf  ${OUTPUT_FILE/\%/jshprefit}       
 
APPLICATIONS+=$JSHOWERPOINTSIMPLEX
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JShowerPositionFit
# ------------------------------------------------------------------------------------------
 
PARAMETERS=(
    numberOfPrefits        100
    TMax_ns                +120.0
    TMin_ns                -120.0
    DMax_m                 80.0
    Emin_GeV               1.0
    Emax_GeV               200.0
    En                     3.0
    R_Hz                   $RATE_HZ
    TTS_ns                 2.0)
 
timer_start
 
eval JShowerPositionFit                   \
     -a $DETECTOR                          \
     -+${^CALIBRATION}                     \
     -T $TMAX_S                            \
     -N ${NUMBER_OF_THREADS}               \
     -f ${OUTPUT_FILE/\%/jshpointsimplex}  \
     -F $PDF                               \
     -o ${OUTPUT_FILE/\%/jshpositionfit}   \
     -@ `make_equation PARAMETERS`         \
     -d ${DEBUG} --!
 
CHECK_EXIT_CODE
 
rm -vf  ${OUTPUT_FILE/\%/jshpointsimplex}       
 
APPLICATIONS+=$JSHOWERPOSITIONFIT
 
timer_stop
timer_print
 
 
 
# ------------------------------------------------------------------------------------------
#                                       JShowerDirectionPrefit
# ------------------------------------------------------------------------------------------
 
PARAMETERS=(
    numberOfPrefits       1
    TMax_ns               +30.0
    TMin_ns               -30.0
    DMax_m                60.0
    R_Hz                  $RATE_HZ
    scanAngle_deg         10
    Emin_GeV              1
    Emax_GeV              1000
    En                    100)
 
timer_start
 
eval JShowerDirectionPrefit                  \
     -a $DETECTOR                             \
     -+${^CALIBRATION}                        \
     -T $TMAX_S                               \
     -f ${OUTPUT_FILE/\%/jshpositionfit}      \
     -F $PDF                                  \
     -o ${OUTPUT_FILE/\%/jshdirectionprefit}  \
     -@ `make_equation PARAMETERS`            \
     -N ${NUMBER_OF_THREADS}                  \
     -d $DEBUG --!
 
CHECK_EXIT_CODE
 
rm -vf  ${OUTPUT_FILE/\%/jshpositionfit}
 
APPLICATIONS+=$JSHOWERDIRECTIONPREFIT
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JShowerFit
# ------------------------------------------------------------------------------------------
 
PARAMETERS=(
    numberOfPrefits             4
    TMax_ns                     +30.0
    TMin_ns                     -30.0
    DMax_m                      60.0
    DStep_m                     5
    R_Hz                        $RATE_HZ
    mestimator                  3)
 
timer_start
 
eval JShowerFit                              \
     -a $DETECTOR                             \
     -+${^CALIBRATION}                        \
     -T $TMAX_S                               \
     -f ${OUTPUT_FILE/\%/jshdirectionprefit}  \
     -F $PDF                                  \
     -N ${NUMBER_OF_THREADS}                  \
     -o ${OUTPUT_FILE/\%/jshfit}              \
     -@ `make_equation PARAMETERS`            \
     -E $ENERGY_CORRECTION                    \
     -d $DEBUG --!
 
CHECK_EXIT_CODE
 
rm -vf  ${OUTPUT_FILE/\%/jshdirectionprefit}
 
APPLICATIONS+=$JSHOWERCOMPLETEFIT
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JHistory
# ------------------------------------------------------------------------------------------
 
timer_start
 
JHistory \
    -f ${OUTPUT_FILE/\%/jshfit}    \
    -o ${OUTPUT_FILE/\%/jhistory}  \
    -A "$APPLICATIONS[*]"          \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
rm -vf  ${OUTPUT_FILE/\%/jshfit}
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                      rename outputfile
# ------------------------------------------------------------------------------------------
 
timer_start
 
mv -v \
   ${OUTPUT_FILE/\%/jhistory}               \
   ${OUTPUT_FILE/\%/${SUFFIX}}              
 
timer_stop
timer_print
 
 
# ------------------------------------------------------------------------------------------
#                                       JConvertEvt
# ------------------------------------------------------------------------------------------
 
timer_start
 
JConvertEvt \
    -f ${OUTPUT_FILE/\%/${SUFFIX}}          \
    -o ${OUTPUT_FILE/\%/${SUFFIX}.offline}  \
    -a $DETECTOR                            \
    -+${^CALIBRATION}                       \
    -T $TMAX_S                              \
    -P $PMT                                 \
    -d $DEBUG --!
 
timer_stop
timer_print