JSTDevK40.sh

Go to the documentation of this file.

#!/bin/zsh
#
#
# \author mdejong
#
version=1.0
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
zmodload zsh/mathfunc
 
set_variable   DEBUG           2
set_variable   WORKDIR         `pwd`
set_variable   OUTPUT_FILE     $WORKDIR/stdev.root
set_variable   DIR             $JPP_DIR/examples/JCalibrate/
set_variable:  ZMAX            CALIBRATION_ZMAX       -3.0
set_variable:  ZMIN            CALIBRATION_ZMIN       +3.0
set_variable:  OPTION          CALIBRATION_OPTION     address
set_variable:  FORMAT          GRAPHICS_FORMAT        gif
set_variable+  BATCH           GRAPHICS_BATCH         -B
 
 
if do_usage $*; then
    usage "$script <detector file> <input file> <input file>" \
          "\nThe 1st input file corresponds to the output of JMergeCalibrateK40 and the 2nd to the output of JFitK40."
fi
 
if (( $# != 3 )); then
    fatal "Wrong number of parameters."
fi
 
set_variable     DETECTOR                $argv[1]
set_array        INPUT_FILES             $argv[2,-1]
 
$DIR/JSTDevK40 \
    -a $DETECTOR                          \
    -f"$INPUT_FILES[1] $INPUT_FILES[2]"   \
    -o $OUTPUT_FILE                       \
    -O $OPTION
 
eval `JPrintDetector -a $DETECTOR -O SUMMARY`
 
set_variable  FIRST_FLOOR  1
 
kill_child_processes_at_exit
 
attach getModule -a $DETECTOR
 
typeset -Z 4 STRING
typeset -Z 2 FLOOR
 
for STRING in $STRINGS[*]; do
 
    echo -n "Creating graphics for string $STRING.."
 
    for (( FLOOR = $FIRST_FLOOR; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do
 
        sput $STRING $FLOOR
        sget  MODULE
 
        JTestRange2D \
            -f ${OUTPUT_FILE}:$MODULE.2X                      \
            -z "$((-1 * fabs($ZMIN))) $((+1 * fabs($ZMIN)))"  \
            -d 3                                              |& grep -E failed
 
        JPlot2D \
            -f ${OUTPUT_FILE}:$MODULE.2X                      \
            -> "PMT"                                         \
            -< "PMT"                                         \
            -z "$ZMIN $ZMAX"                                  \
            -O COLZ                                           \
            -G X                                              \
            -G Y                                              \
            -T "(${STRING},${FLOOR})"                         \
            -o ${TMPDIR:-/tmp}/M_${STRING}_${FLOOR}.$FORMAT   $BATCH
    done
 
    montage \
        -tile 6x3                                             \
        -geometry +0+0                                        \
        ${TMPDIR:-/tmp}/M_${STRING}_{01..18}.$FORMAT          \
        $WORKDIR/M_${STRING}.$FORMAT                          >& /dev/null
 
    echo " => $WORKDIR/M_${STRING}.$FORMAT"
done
 
detach
 
rm -f ${TMPDIR:-/tmp}/M_*_*.$FORMAT