JCalibratePosition.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable:  DEBUG       CALIBRATION_DEBUG  1
set_variable   WORKDIR     `pwd`            
set_variable   QUEUE_NAME  ${TMPDIR:-/tmp}/queue       
set_variable   QUEUE_SIZE  3                
    
APPLICATIONS=(prefit simplex gandalf)      # fit applications
 
if do_usage $*; then
    usage "$script <detector file> <string identifier> (input file)+"
fi
 
if (( $# < 3 )); then
    fatal "Not enough arguments."
fi
    
set_variable  DETECTOR            $argv[1]
set_variable  STRING_ID           $argv[2]
 
INPUT_FILES=($argv[3,-1])
 
if ( ! is_CCLyon ); then
    
    # local batch processor
 
    source qlib.sh
    
    $JPP_DIR/examples/scripts/mkqueue.sh  $QUEUE_NAME  $QUEUE_SIZE  continue
 
else
    fatal "The job submission should be changed for running in CC-Lyon."
fi
 
if [[ $DETECTOR != *\.detx ]]; then
    fatal "Invalid detector file <${DETECTOR}>."
fi
 
# set path
 
for (( i=1; i <= ${#INPUT_FILES}; i+=1 )); do
 
    set_variable  INPUT_FILE   ${INPUT_FILES[${i}]}
 
    if [[ -f `pwd`/$INPUT_FILE ]]; then
        INPUT_FILES[${i}]=`pwd`/$INPUT_FILE
    fi
done
 
for TIME_OFFSET_NS in 0; do
    for X_OFFSET_M in 0; do
        for Y_OFFSET_M in 0; do
            for Z_OFFSET_M in 0; do
 
                set_variable  OUTPUT_DIRECTORY  $WORKDIR/T=${TIME_OFFSET_NS}:X=${X_OFFSET_M}:Y=${Y_OFFSET_M}:Z=${Z_OFFSET_M}
 
                mkdir -p --  $OUTPUT_DIRECTORY
 
                # detector calibration
 
                if [[ ! -f $OUTPUT_DIRECTORY/detector.detx ]]; then
                
                    JEditDetector \
                        -a $DETECTOR                                             \
                        -S "$STRING_ID add $X_OFFSET_M $Y_OFFSET_M $Z_OFFSET_M"  \
                        -s "$STRING_ID add $TIME_OFFSET_NS"                      \
                        -o $OUTPUT_DIRECTORY/detector.detx --!
                    
                fi
                
                for FILE_NAME in $INPUT_FILES[*]; do
                    
                    set_variable  APP          ${APPLICATIONS[-1]}
                    set_variable  INPUT_FILE   ${FILE_NAME}
                    set_variable  OUTPUT_FILE  ${OUTPUT_DIRECTORY}/${${FILE_NAME##*/}/\.root/_${APP}.root}
                    set_variable  BATCH_FILE   ${OUTPUT_DIRECTORY}/${${FILE_NAME##*/}/\.root/.sh}
 
                    rm -f        $BATCH_FILE
                    
                    echo "#!/usr/bin/env zsh"  >>  $BATCH_FILE
 
                    if [[ ! -f ${OUPUT_FILE} ]]; then
 
                        # sequentially processing of applications
                        
                        for APP in $APPLICATIONS[*]; do
                            
                            set_variable  OUTPUT_FILE  ${OUTPUT_DIRECTORY}/${${FILE_NAME##*/}/\.root/_${APP}.root}
                            
                            echo "JARCA${(C)APP}.sh  $OUTPUT_DIRECTORY/detector.detx  $INPUT_FILE $OUTPUT_FILE >& /dev/null"  >>  $BATCH_FILE
                            
                            set_variable  INPUT_FILE   ${OUTPUT_FILE}
                            
                        done
 
                        # cleanup
                        
                        for (( i=1; i < ${#APPLICATIONS}; i+=1 )); do
                            
                            set_variable  APP          ${APPLICATIONS[${i}]}
                            set_variable  OUTPUT_FILE  ${OUTPUT_DIRECTORY}/${${FILE_NAME##*/}/\.root/_${APP}.root}
                            
                            echo "rm -f  $OUTPUT_FILE"  >>  $BATCH_FILE
                            
                        done
 
                        echo "rm -f $BATCH_FILE"  >>  $BATCH_FILE
                        
                        # submit job
 
                        chmod +x    $BATCH_FILE
                        puts_queue  $QUEUE_NAME  $BATCH_FILE
 
                    fi
                done
            done
        done
    done
done