JDynamics.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable:  DEBUG         DYNAMICS_DEBUG       2
set_variable:  WORKDIR       DYNAMICS_WORKDIR     ./
set_variable:  PERIOD        DYNAMICS_PERIOD      100    # range of runs per output file
set_variable:  MARGIN        DYNAMICS_MARGIN      5      # overlap of runs at edges between output files
set_variable   RANGE         1-99999999
 
if do_usage $*; then
    usage "$script <archive> <detector identifier|detector file> <version> [run-run]"\
          "\nAuxiliary script to process dynamical positions and orientations data."\
          "\nThe static and dynamic data are stored in the archive with the given version."
fi
 
case $# in
     4) set_variable  RANGE           $argv[4];&
     3) set_variable  VERSION         $argv[3];
        set_variable  DETECTOR        $argv[2];
        set_variable  ARCHIVE         $argv[1];;
     *) fatal "Wrong number of arguments."
esac
 
JCookie.sh
 
CHECK_EXIT_CODE
 
if [[ -f $DETECTOR ]]; then
    eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`
else
    set_variable  DETECTOR_ID   `getDetector -D $DETECTOR -O int`
    set_variable  DETECTOR      detector.datx
fi
 
if [[ ! -f $DETECTOR ]]; then
    fatal "Missing file $DETECTOR"\
          "\nYou may want to execute archive-get-calibration.sh beforehand."
fi
 
JAcoustics.sh $DETECTOR_ID
 
CHECK_EXIT_CODE
 
archive-put-calibration.sh  $ARCHIVE  $VERSION  ./
 
CHECK_EXIT_CODE
 
RUNS=(`JRuns -D $DETECTOR_ID -F RUN -@ "RUN >= ${RANGE%%-*}" -@ "RUN <= ${RANGE##*-}" | sort -g`)
 
for (( L = 1; $L <= ${#RUNS}; L += $PERIOD )); do
 
    let "R  = $L + $PERIOD - 1"
 
    if (( $R > ${#RUNS} )); then
        let "R  = ${#RUNS}"
    fi
 
    let "LS = $L - $MARGIN"
    let "RS = $R + $MARGIN"
 
    if (( $LS < 1 )); then
        let "LS = 1"
    fi
    if (( $RS > ${#RUNS} )); then
        let "RS = ${#RUNS}"
    fi
 
    echo "\n\nProcessing runs $RUNS[$L]-$RUNS[$R]\n"
 
 
    set_variable  TYPE          positions
    set_variable  OUTPUT_FILE   katoomba_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUNS[$L]}.root
 
    INPUT_FILES=()
 
    for (( i = $LS; $i <= $RS; i += 1 )); do
 
        set_variable  INPUT_FILE    KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUNS[$i]}_event.root
 
        if [[ ! -f $INPUT_FILE ]]; then
            JAcousticsEventBuilder.sh  $DETECTOR  $RUNS[$i]
        fi
 
        if [[   -f $INPUT_FILE ]]; then
            INPUT_FILES+=($INPUT_FILE)
        fi
    done
 
    if [[ ! -f $OUTPUT_FILE ]]; then
 
        if (( ${#INPUT_FILES} != 0 )); then
 
            set_variable  ACOUSTICS_STRIP
 
            JKatoomba.sh  $DETECTOR  $INPUT_FILES[*]  $OUTPUT_FILE
 
            putFile.sh  $OUTPUT_FILE  $ARCHIVE  $DETECTOR_ID  $RUNS[$L]  $RUNS[$R]  $TYPE  $VERSION
 
        else
            error "No input files for $OUTPUT_FILE"
        fi
    fi
 
 
    set_variable  TYPE          orientations
    set_variable  OUTPUT_FILE   ballarat_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUNS[$L]}.root
 
    if [[ ! -f $OUTPUT_FILE ]]; then
 
        JBallarat.sh  $DETECTOR  $RUNS[$LS,$RS]  $OUTPUT_FILE
 
        putFile.sh  $OUTPUT_FILE  $ARCHIVE  $DETECTOR_ID  $RUNS[$L]  $RUNS[$R]  $TYPE  $VERSION
    fi
done