JOMGsim.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
#
# \author mdejong
#
version=1.0
script=${0##*/}
 
# ------------------------------------------------------------------------------------------
#
#                         Utility script to process OMGsim output.
#
# ------------------------------------------------------------------------------------------
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
zmodload zsh/mathfunc
 
set_variable   DEBUG       2      
set_variable   WORKDIR     ./
set_variable   DIR         $JPP_DIR/examples/JCalibrate/
set_variable   OMGSIM      $DIR/OMGsim.txt
set_variable:  FACTOR      OMGSIM_FACTOR          0.5
set_variable:  FORMAT      GRAPHICS_FORMAT        gif
set_variable+  BATCH       GRAPHICS_BATCH         -B
 
if do_usage $*; then
    usage "$script <detector file> <file name pattern> <OMGsim data card>"
fi
 
case $# in
    3)  set_variable  OMGSIM              $argv[3];&
    2)  set_variable  FILE_NAME_PATTERN   $argv[2];
        set_variable  DETECTOR            $argv[1];;
    *)  fatal "Wrong number of arguments."
esac
 
function getv() { JPrintProperties -f $OMGSIM -k $1 -@ "cc=#" }
 
typeset -A BUFFER
 
let "BUFFER[K40Glass]   = `getv glass.K40  ` * `getv mass.glass`"
let "BUFFER[Th232Glass] = `getv glass.Th232` * `getv mass.glass`"
let "BUFFER[U238Glass]  = `getv glass.U238 ` * `getv mass.glass`"
let "BUFFER[K40Water]   = `getv water.K40  ` * (4.0/3.0) * acos(-1.0) * (`getv radius.K40 `**3 - `getv radius.glass`**3)"
let "BUFFER[U238Water]  = `getv water.U238 ` * (4.0/3.0) * acos(-1.0) * (`getv radius.U238`**3 - `getv radius.glass`**3)"
 
echo Radio activities:
 
for KEY VALUE in ${(kv)BUFFER}; do
    printf "%-12s %12.2f [Bq]\n" $KEY $VALUE 
done
 
typeset -a KEYS
 
for KEY VALUE in ${(kv)BUFFER}; do
 
    set_variable  INPUT_FILE   ${FILE_NAME_PATTERN/\%/$KEY}
    set_variable  OUTPUT_FILE  $WORKDIR/\[${KEY}\].root
 
    echo $INPUT_FILE
 
    if [[ -f $INPUT_FILE ]] && [[ ! -f $OUTPUT_FILE ]]; then
 
        $DIR/JOMGsim   \
            -a $DETECTOR           \
            -f $INPUT_FILE         \
            -o $OUTPUT_FILE        \
            -R $VALUE              \
            -P "QE = $FACTOR"      \
            -d $DEBUG --!
    fi
 
    if [[ -f $OUTPUT_FILE ]]; then
        KEYS+=($KEY)
    fi
done
 
JOpera2D \
    -f$WORKDIR/\[${^KEYS}\].root:1.2S    \
    -u Add                               \
    -O =                                 \
    -o $WORKDIR/\[Total\].root           >& /dev/null
    
JPlot2D \
    -w 1200x600                          \
    -f $WORKDIR/\[Total\].root:1.2S      \
    -> "PMT pair"                       \
    -< "#DeltaT [ns]"                   \
    -\^ "rate [Hz]"                      \
    -O COLZ                              \
    -T "OMGsim"                          \
    -o monitor.$FORMAT                   $BATCH