JRandomEventRunByRun.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
# \author zaly
#
version=1.0
script=${0##*/}
 
# ------------------------------------------------------------------------------------------
#
#    Script to jointly run JRandomTimesliceWriter and JTriggerProcessor in run-by-run mode.
#
# ------------------------------------------------------------------------------------------
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
set_variable:  DEBUG                 RANDOMEVENT_DEBUG                      1
set_variable:  WORKDIR               RANDOMEVENT_WORKDIR                    ./
set_variable:  BACKGROUND_HZ         RANDOMEVENT_BACKGROUND_HZ              `getK40Rates`
set_variable:  MIXED_BACKGROUND_HZ   RANDOMEVENT_MIXED_BACKGROUND_HZ        8.0 6.0
set_variable:  SEED                  RANDOMEVENT_SEED                       0
set_variable:  NUMBER_OF_SLICES      RANDOMEVENT_SLICES                     10
set_variable:  RECYCLING             RANDOMEVENT_RECYCLING                  "0 0"
set_variable:  FACTOR                RANDOMEVENT_FACTOR                     1.0
set_variable:  SAMPLER               RANDOMEVENT_SAMPLER                    "1 1000"
 
set_variable   DAQ_TIMESLICE         JDAQTimesliceL0
 
if do_usage $*; then
    usage "$script <detector file> <detector file> <output file> <DAQ file> <PMT parameters file>"\
          "\nAuxiliary script to produce random event data."\
          "\nThe first detector file is used to convert the true data to DAQ data and the second to covert DAQ data to calibrated data."\
          "\nNormally, these correspond to the 'perfect' calibration and the 'online' calibration, respectively."
 
fi
 
if (( $# == 5 )); then
    set_variable  DETECTORA    $1
    set_variable  DETECTORB    $2
    set_variable  OUTPUT_FILE  $3
    set_variable  DAQ_FILE     $4
    set_variable  PMT_FILE     $5
else
    fatal "Wrong number of arguments."
fi
 
JPrintTree -f $DAQ_FILE -@ "type = JDAQSummaryslice" -k number_of_entries  |  read N
 
set_variable   RUNBYRUN             "file=$DAQ_FILE; sampler=${SAMPLER%% *} $(($N / 2))"
 
#################################################################################################
#
# The sampler values correspond to N_on N_off, respectively (note that sampler calls JSampler),
# where:
# N_on   =  number of time slices to read;
# N_off  =  number of time slices to skip.
#
# The sampler option works as follows.
# It will
# read -on average- N_on  consecutive time slices and  
# skip -on average- N_off time slices
# modulo the number of time slices in the file.
#
# The larger N_on, the faster the reading, because this reduces the random accesses 
# of the data taking file to pick up a next time slice.
# The smaller N_off, the less time slices are skipped.
# So, N_on = 0 guarantees that all time slices are sampled.
# Note that if the number of time slices to be produced is small, then too small a value of N_off
# could create a bias because only the first time slices of the data taking file are then sampled.
#################################################################################################
 
set_variable   DIR                  `mktemp -d $WORKDIR/XXXXXX`
set_variable   PIPE                 $DIR/pipe.dat
set_variable   PARAMETERS           $DIR/trigger_parameters.txt
set_variable   TRIGGER              $DIR/trigger_processor.root
set_variable   HEADER               $DIR/header.root
 
eval `JPrintDetector -a $DETECTORA -O GEOMETRY`
 
if (( $MINIMAL_DISTANCE_M > 15.0 )); then
    MIXED_BACKGROUND_HZ="0.0 0.0"
fi
 
mkfifo $PIPE
 
if [[ ! -p $PIPE ]]; then
    fatal "Error opening $PIPE."
fi
 
timer_start
 
JRandomTimesliceWriter \
    -a ${DETECTORA}               \
    -o ${HEADER}                  \
    -o ${PIPE}                    \
    -n ${NUMBER_OF_SLICES}        \
    -P ${PMT_FILE}                \
    -P "QE=${FACTOR}"             \
    -S ${SEED}                    \
    -B "$BACKGROUND_HZ"           \
    -X "$MIXED_BACKGROUND_HZ"     \
    -N "$RECYCLING"               \
    -r "${RUNBYRUN}"              \
    -d ${DEBUG}                   \
    --! &
 
BG=$!
 
JPrintTriggerParameters \
    -f ${DAQ_FILE}                > $PARAMETERS
 
JTriggerProcessor \
    -a ${DETECTORB}               \
    -f ${PIPE}                    \
    -@ ${PARAMETERS}              \
    -C ${DAQ_TIMESLICE}           \
    -o ${TRIGGER}                 \
    -d ${DEBUG}                   \
    --! 
 
CHECK_EXIT_CODE
 
JConvert \
    -f ${HEADER}                  \
    -f ${TRIGGER}                 \
    -o ${OUTPUT_FILE}             \
    -m
 
CHECK_EXIT_CODE
 
# check exit code background process
 
wait $BG
 
STATUS=$?
 
if (( $STATUS != 0 )); then
    error "JRandomTimesliceWriter exit status $STATUS"
    exit  $STATUS
fi
 
rm -rf ${DIR}
 
timer_stop
timer_print
 
JPrintTree \
    -f ${OUTPUT_FILE}
 
JTriggerMonitor \
    -f  ${OUTPUT_FILE}            \
    -o  /dev/null