JARCAMuonReconstruction.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author bofearraigh
#
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#                         Script to run the JPP Track Reconstruction Chain for ARCA.
#
# ------------------------------------------------------------------------------------------

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
source $JPP_DIR/setenv.sh $JPP_DIR

set_variable:  DEBUG             JARCAREC_DEBUG                1
set_variable:  PDF               JARCAREC_PDF                  $JPP_DATA/J%p.dat
set_variable   PMT               $JPP_DATA/PMT_parameters.txt  
set_variable:  SUF               JARCAREC_SUF                  jchain.arca
set_variable:  ENERGY_CORRECTION JARCAREC_ENERGY_CORRECTION    energy_correction_arca.txt
set_variable:  NUMBER_OF_EVENTS  JARCAREC_NUMBER_OF_EVENTS     $((2**31))

if do_usage $*; then
    usage "$script <detector file> <input file> <output file> [PDF file descriptor [PMT parameters file]]"
fi

case $# in
    5) set_variable PMT             $5;&
    4) set_variable PDF             $4;&
    3) set_variable OUTPUT_FILE     $3; 
       set_variable INPUT_FILE      $2; 
       set_variable DETECTOR        $1;;
    *) fatal "Wrong number of arguments.";;
esac

if [[ ! "$OUTPUT_FILE" == *"%"* ]]; then
  fatal "The output file must have the wildcard % in the name, e.g. %.root"
fi


# ------------------------------------------------------------------------------------------
#                                       JMuonPrefit
# ------------------------------------------------------------------------------------------

PARAMETERS=(
    sigma_ns           5
    gridAngle_deg      1
    useL0              0
    numberOfOutliers   3
    numberOfPrefits    12
    DZMax              0.0
    numberOfDZMax      1
    TMaxLocal_ns       18
    ctMin              0.0
    roadWidth_m        200.0)

timer_start

eval JMuonPrefit \
    -a $DETECTOR                   \
    -f $INPUT_FILE                 \
    -o ${OUTPUT_FILE/\%/jprefit}   \
    -n ${NUMBER_OF_EVENTS}        \
    -@ `make_equation PARAMETERS`  \
    -d $DEBUG --!

CHECK_EXIT_CODE

timer_stop
timer_print


# ------------------------------------------------------------------------------------------
#                                       JMuonSimplex
# ------------------------------------------------------------------------------------------

PARAMETERS=(
    sigma_ns         3
    TMaxLocal_ns     15.0
    ctMin            0.0
    roadWidth_m      200.0
    numberOfPrefits  0)

timer_start

eval JMuonSimplex \
    -a $DETECTOR                   \
    -f ${OUTPUT_FILE/\%/jprefit}   \
    -o ${OUTPUT_FILE/\%/jsimplex}  \
    -@ `make_equation PARAMETERS`  \
    -d ${DEBUG} --!

CHECK_EXIT_CODE

timer_stop
timer_print


# ------------------------------------------------------------------------------------------
#                                       JMuonGandalf
# ------------------------------------------------------------------------------------------

PARAMETERS=(
    TTS_ns            2
    E_GeV             1.0e3
    TMin_ns            -50.0
    TMax_ns           +450.0
    R_Hz              6.0e3
    roadWidth_m       175.0
    numberOfPrefits   0)

timer_start

eval JMuonGandalf \
    -a $DETECTOR                   \
    -f ${OUTPUT_FILE/\%/jsimplex}  \
    -o ${OUTPUT_FILE/\%/jgandalf}  \
    -P $PDF                        \
    -@ `make_equation PARAMETERS`  \
    -d $DEBUG --!

CHECK_EXIT_CODE

timer_stop
timer_print


# ------------------------------------------------------------------------------------------
#                                       JMuonStart
# ------------------------------------------------------------------------------------------

PARAMETERS=(
    roadWidth_m      160.0
    R_Hz             6.0e3
    TMin_ns          -25.0
    TMax_ns          +75.0
    Pmin1            1.0e-3
    Pmin2            1.0e-2
    numberOfPrefits  1)

timer_start

eval JMuonStart \
    -a $DETECTOR                   \
    -f ${OUTPUT_FILE/\%/jgandalf}  \
    -o ${OUTPUT_FILE/\%/jstart}    \
    -P $PDF                        \
    -@ `make_equation PARAMETERS`  \
    -d $DEBUG --!

CHECK_EXIT_CODE

timer_stop
timer_print


# ------------------------------------------------------------------------------------------
#                                       JMuonEnergy
# ------------------------------------------------------------------------------------------

PARAMETERS=(
    roadWidth_m      200.0
    R_Hz             6.0e3
    EMin_log         0.0
    EMax_log         8.0
    TMin_ns           -50.0
    TMax_ns          +450.0
    mestimator       1
    numberOfPrefits  1)

timer_start

eval JMuonEnergy \
    -a $DETECTOR                   \
    -f ${OUTPUT_FILE/\%/jstart}    \
    -o ${OUTPUT_FILE/\%/jenergy}   \
    -P $PDF                        \
    -E $ENERGY_CORRECTION          \
    -@ `make_equation PARAMETERS`  \
    -d $DEBUG --!

CHECK_EXIT_CODE

timer_stop
timer_print


# ------------------------------------------------------------------------------------------
#                   rename outputfile and remove intermediate files
# ------------------------------------------------------------------------------------------

timer_start

mv \
    ${OUTPUT_FILE/\%/jenergy}  \
    ${OUTPUT_FILE/\%/${SUF}}   \
    -v

rm \
    ${OUTPUT_FILE/\%/jprefit}  \
    ${OUTPUT_FILE/\%/jsimplex} \
    ${OUTPUT_FILE/\%/jgandalf} \
    ${OUTPUT_FILE/\%/jstart}   \
    -v

timer_stop
timer_print


# ------------------------------------------------------------------------------------------
#                                       JConvertEvt
# ------------------------------------------------------------------------------------------

timer_start

JConvertEvt \
    -f ${OUTPUT_FILE/\%/${SUF}}        \
    -o ${OUTPUT_FILE/\%/${SUF}.aanet}  \
    -a $DETECTOR                       \
    -P $PMT                            \
    -d $DEBUG --!

timer_stop
timer_print