hydrophone-t0:fit.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

zmodload zsh/mathfunc

set_variable:  DEBUG       ACOUSTICS_DEBUG        2
set_variable:  WORKDIR     ACOUSTICS_WORKDIR      ./
set_variable:  FORMAT      GRAPHICS_FORMAT        gif
set_variable+  BATCH       GRAPHICS_BATCH         -B

if do_usage $*; then
    usage "$script <detector file> <string identifier> [<detector file>]"
fi

if (( $# == 0 || $# > 3 )); then
    fatal "Wrong number of arguments."
fi

set_variable  DETECTOR            $argv[1]
set_variable  STRING              $argv[2]
set_array     QUANTILES           0.333 0.666
set_variable  FORMULA             "[0] * exp(-0.5 * (x-[1])*(x-[1]) / ([2]*[2]))"
set_variable  MODULE              `getModule -a $DETECTOR -L "$STRING 0"`

typeset -Z 4 STRING

JOpera1D \
    -f hydrophone.root:$MODULE                   \
    -o /tmp/H\[${STRING}\].root                  \
    -u Add -d 0

JPrintQuantiles \
    -f /tmp/H\[${STRING}\].root:Add              \
    -Q "$QUANTILES[*]"                           \
    -d 0                                         | read -A RESULT

P1=$((0.5*($RESULT[-1] + $RESULT[1])))           # average
P2=$((1.5*($RESULT[-1] - $RESULT[1])))           # width

JFit \
    -f /tmp/H\[${STRING}\].root:Add              \
    -o /tmp/F\[${STRING}\].root                  \
    -F "$FORMULA"                                \
    -@"p0 = GetMaximum * 0.8"                    \
    -@"p1 = $P1"                                 \
    -@"p2 = $P2"                                 \
    -d $DEBUG

printf "string %4d %9.6f +/- %9.6f\n" $STRING `JPrintFit -f  /tmp/F\[${STRING}\].root:Add -@p1`

if (( ${#} == 3 )); then

    set_variable  DETECTOR            $argv[3]

    eval `JPrintDetector -a $DETECTOR -O SUMMARY`

    set_array P1  `JPrintFit -f  /tmp/F\[${STRING}\].root:Add -@p1`

    let TIME_OFFSET_NS="$P1[1] * 1.0e9"

    printf "Add time offset %12.6d to hydrophone.\n" $TIME_OFFSET_NS
    
    JEditDetector \
        -a $DETECTOR                         \
        -o $DETECTOR                         \
        -M "$MODULE SUB $TIME_OFFSET_NS"     \
        -d $DEBUG
fi

JPlot1D \
    -f /tmp/F\[${STRING}\].root:Add              \
    -x "-0.002 +0.002"                           \
    -\> "#Deltat [s]"                            \
    -\^ "number of events [a.u.]"                \
    -N "X 505"                                   \
    -T "$STRING"                                 \
    -o hydrophonet0_${STRING}.$FORMAT            $BATCH