plot-compass.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
#
# \author mdejong
#
version=1.0
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
set_variable:  DEBUG       COMPASS_DEBUG          2
set_variable:  WORKDIR     COMPASS_WORKDIR        ./
set_variable:  FORMAT      GRAPHICS_FORMAT        gif
set_variable+  BATCH       GRAPHICS_BATCH         -B
 
if do_usage $*; then
    usage "$script <detector file> (input file)+"
fi
 
if (( $# < 2 )); then
    fatal "Wrong number of parameters."
fi
 
set_variable     DETECTOR                $argv[1]
set_array        INPUT_FILES             $argv[2,-1]
 
eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`
eval `JPrintDetector -a $DETECTOR -O SUMMARY`
 
 
 
typeset -Z 4 STRING
typeset -Z 2 FLOOR
 
typeset -A X_LABEL
typeset -A YMAX
 
X_LABEL[twist]="#Delta#theta [deg]"
X_LABEL[swing]="#Delta#theta [deg]"
X_LABEL[count]="number of hits"
 
YMAX[twist]=2.0
YMAX[swing]=0.5
YMAX[count]=100
 
if (( ${#INPUT_FILES} == 1 )); then
    set_variable     OPTION                 -s 110110
else
    set_variable     OPTION                 -L TR
fi
 
for key value in "${(@kv)X_LABEL}"; do
 
    for STRING in $STRINGS[*]; do
 
        echo -n "Creating $key graphics for string $STRING.."
 
        rm -f ${TMPDIR:-/tmp}/${key}_${STRING}_*.$FORMAT
 
        set_variable  FIRST_FLOOR  1
 
        for (( FLOOR = $FIRST_FLOOR; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do
 
            eval MODULE=\${STRING_${(l:4::0::0:)STRING}\[$(($FLOOR))\]:--1}
 
            JPlot1D \
                -f "${INPUT_FILES//\.root/.root:${MODULE}.${key}}" \
                -> "${value}"                                     \
                -\^ "number of events [a.u.]"                      \
                `echo $OPTION`                                     \
                -T "(${STRING},${FLOOR})"                          \
                -o ${TMPDIR:-/tmp}/${key}_${STRING}_${FLOOR}.$FORMAT          $BATCH
        done
 
        montage \
            -tile 6x3                                   \
            -geometry +0+0                              \
            ${TMPDIR:-/tmp}/${key}_${STRING}_{01..18}.$FORMAT      \
            $WORKDIR/${key}_${STRING}.$FORMAT           >& /dev/null
 
        echo " -> $WORKDIR/${key}_${STRING}.$FORMAT"
    done
done
 
if (( ${#INPUT_FILES} == 1 )); then
 
    JPlot2D \
        -f "${INPUT_FILES[1]}:h2"                  \
        -> "string"                               \
        -< "floor"                                \
        -z "1.0e-8 1.0" -Z                         \
        -O COLZ                                    \
        -T "outliers"                              \
        -o $WORKDIR/out.$FORMAT                    $BATCH
 
    for key value in "${(@kv)X_LABEL}"; do
 
        echo -n "Creating summary graphics for $key.."
 
        HISTOGRAMS=()
    
        for STRING in $STRINGS[*]; do
 
            set_variable  STRING_TXT          $WORKDIR/string_${STRING}.${key}.txt
            set_variable  STRING_ROOT         $WORKDIR/string_${STRING}.${key}.root
 
            rm -f $STRING_TXT
 
            for (( FLOOR = $FIRST_FLOOR; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do
 
                eval MODULE=\${STRING_${(l:4::0::0:)STRING}\[$(($FLOOR))\]:--1}
            
                set_variable X `JPrintResult -f "${INPUT_FILES[1]}:${MODULE}.${key}" -F GetMean`
            
                printf "%2d %9.6f\n" $FLOOR $X >> $STRING_TXT
            
            done
 
            JGraph \
                -f $STRING_TXT                            \
                -o $STRING_ROOT                           \
                -T "[${STRING}]" -d0
 
            HISTOGRAMS+="${STRING_ROOT}:.*"
 
            rm -f $STRING_TXT
        done
    
        JPlot1D \
            -f "$HISTOGRAMS[*]"                            \
            -w 800x400                                     \
            -x "0.5 18.5"                                  \
            -y "0.0 $YMAX[${key}]"                         \
            -> "floor"                                    \
            -\^ "${value}"                                 \
            -N "X 505"                                     \
            -L TR                                          \
            -T "[$key]"                                    \
            -o $WORKDIR/summary_${key}.$FORMAT             $BATCH
 
        rm -f  ${HISTOGRAMS[*]//:*/}
 
        echo " -> $WORKDIR/summary_${key}.$FORMAT"
    done        
fi