tripod-XY:fit.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable:  DEBUG       ACOUSTICS_DEBUG        2
set_variable:  WORKDIR     ACOUSTICS_WORKDIR      ./
#set_variable   FORMULA     "[0] + [1] * (sqrt(1.0 + 0.5*(x-[2])*(x-[2])/([5]*[5]) + 0.5*(y-[3])*(y-[3])/([6]*[6]) + [4]*(x-[2])*(y-[3])/([5]*[6])) - 1.0)"  
set_variable   FORMULA     "[0] + [1] * ((x-[2])*(x-[2])/([5]*[5]) + (y-[3])*(y-[3])/([6]*[6]) + [4]*(x-[2])*(y-[3])/([5]*[6]))"
set_variable:  FORMAT      GRAPHICS_FORMAT        gif
set_variable+  BATCH       GRAPHICS_BATCH         -B
 
if do_usage $*; then
    usage "$script <tripod identifier> [<tripod file>]"
fi
 
if (( $# == 0 || $# > 2 )); then
    fatal "Wrong number of arguments."
fi
 
set_variable  TRIPOD              $argv[1]
 
source JAcousticsToolkit.sh
 
CHECK_EXIT_CODE
 
set_variable  TRIPOD_TXT          $WORKDIR/tripodxy_${TRIPOD}.txt
set_variable  TRIPOD_ROOT         $WORKDIR/tripodxy_${TRIPOD}.root
set_variable  G1_TXT              $WORKDIR/g1.txt
set_variable  G1_ROOT             $WORKDIR/g1.root
 
if [[ ! -f $TRIPOD_TXT ]] then
    fatal "No tripod data file $TRIPOD_TXT."
fi
 
JGraph2D \
    -f $TRIPOD_TXT                            \
    -o $TRIPOD_ROOT
 
sort -gr -k 3,3 $TRIPOD_TXT | tail -1 | read X Y Z RMS
 
echo $X $Y > $G1_TXT
 
JGraph \
    -f $G1_TXT                                \
    -o $G1_ROOT
 
awk '
    BEGIN {
    XMIN = +1e3
    XMAX = -1e3
    YMIN = +1e3
    YMAX = -1e3
    }
    END { print XMIN, XMAX, YMIN, YMAX }
    $1 !~ /^#/ {
    if ( $1 < XMIN ) { XMIN = $1 }
    if ( $1 > XMAX ) { XMAX = $1 }
    if ( $2 < YMIN ) { YMIN = $2 }
    if ( $2 > YMAX ) { YMAX = $2 }
    }
    ' $TRIPOD_TXT | read XMIN XMAX YMIN YMAX
 
if (( $X > $XMIN && $X < $XMAX && $Y > $YMIN && $Y < $YMAX )); then
 
    let "XMIN = $X - 0.5"
    let "XMAX = $X + 0.5"
    let "YMIN = $Y - 0.5"
    let "YMAX = $Y + 0.5"
 
    JFit2D \
        -f ${TRIPOD_ROOT}:\.\*                    \
        -o $WORKDIR/fit.root                      \
        -F "$FORMULA"                             \
        -x "$XMIN $XMAX"                          \
        -y "$YMIN $YMAX"                          \
        -@ "p0 = $Z"                              \
        -@ "p1 = 2.0"                             \
        -@ "p2 = $X"                              \
        -@ "p3 = $Y"                              \
        -@ "p4 = 1.0"                             \
        -@ "p5 = 5.0"                             \
        -@ "p6 = 5.0"                             \
        -R "p2 = $XMIN $XMAX"                     \
        -R "p3 = $YMIN $YMAX"                     \
        -d $DEBUG
 
    set_array P2 `JPrintFit -f $WORKDIR/fit.root:user -@p2`
    set_array P3 `JPrintFit -f $WORKDIR/fit.root:user -@p3`
 
    set_variable X  $P2[1]
    set_variable Y  $P3[1]
 
    printf "nominal %2d %7.3f %7.3f %7.3f\n" $TRIPOD 0.0 0.0 `JPrintFit -f $WORKDIR/fit.root:user -x "0.0 0.0"`
    printf "optimal %2d %7.3f %7.3f %7.3f\n" $TRIPOD $X  $Y  `JPrintFit -f $WORKDIR/fit.root:user -x "$X  $Y"`
 
    mv $WORKDIR/fit.root $TRIPOD_ROOT
 
else
 
    echo   "Optimum value at limit; -> no fit."
    printf "nominal %2d %7.3f %7.3f %7.3f\n" $TRIPOD 0.0 0.0 `awk -v X=0.0 -v Y=0.0 '{ if ($1 == X && $2 == Y) { print $3 }}' $TRIPOD_TXT`
    printf "optimal %2d %7.3f %7.3f %7.3f\n" $TRIPOD $X  $Y  $Z
 
fi
    
if (( $# == 2 )); then
    JEditTripod -f $argv[2] -T "$TRIPOD add $X $Y 0.0" -o $argv[2]
fi
 
JPlot2D \
    -f $TRIPOD_ROOT:\.\*                      \
    -f ${G1_ROOT}:\.\*                        \
    -> "#Deltax [m]"                         \
    -< "#Deltay [m]"                         \
    -\^ "#chi^{2}/NDF"                        \
    -O CONT3                                  \
    -T "[$TRIPOD]"                            \
    -o $WORKDIR/tripodxy_${TRIPOD}.$FORMAT    $BATCH
 
rm -f  $TRIPOD_ROOT $G1_TXT $G1_ROOT