plot-Tuna.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}
 
# ------------------------------------------------------------------------------------------
#
#                Auxiliary script to plot slow control data from database.
#
# ------------------------------------------------------------------------------------------

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

set_variable  DEBUG               ${DATABASE_DEBUG:-2}
set_variable  WORKDIR             ${DATABASE_WORKDIR:-/tmp/}
set_variable  CANVAS              ${DATABASE_CANVAS:-1200x600}
set_variable  TIMEAXIS            ${DATABASE_TIMESAXIS:-%d:%m:%y%F1970-01-01 00:00:00}
set_variable  GRAPHICS            ${DATABASE_GRAPHICS:-gif}
set_variable  WILDCARD            ${DATABASE_WILDCARD:-%}

if ( do_usage $* ); then
    usage "$script <input file> <parameters file> [working directory]"
fi

case $# in
    3) set_variable WORKDIR           $3;&
    2) set_variable PARAMETERS_FILE   $2;
       set_variable INPUT_FILE        $1;;
    *) fatal "Wrong number of arguments."
esac

if [[ ! -f $INPUT_FILE ]]; then
    fatal "File $INPUT_FILE not found."
fi

if [[ ! -f $PARAMETERS_FILE ]]; then
    echo         $PARAMETERS_FILE > $WORKDIR/.parameters.txt                # temporary file
    set_variable  PARAMETERS_FILE   $WORKDIR/.parameters.txt
fi

mkdir -p $WORKDIR

exec 3< $PARAMETERS_FILE

while read -u 3 QUANTITY YMIN YMAX; do

    if [[ -n "${QUANTITY}" && ! ${QUANTITY} =~ "^#" ]]; then

        # set environment variables:
        #   STRINGS
        #   FIRST_FLOOR
        #   LAST_FLOOR

        eval `JPrintTitle -f ${INPUT_FILE}:TUNA`

        echo $QUANTITY  |  sed -n "s/\([^\.]*\)\.\([^\.]*\)\.\(.*\)/\1 \2 \3/p"  |  read string floor QUANTITY

        debug "Parsed: <${string}> <${floor}> <${QUANTITY}>"

        if [[ ${string} != $WILDCARD ]]; then
            set_array    STRINGS      $string
        fi

        if [[ ${floor}  != $WILDCARD ]]; then
            set_variable FIRST_FLOOR  ${floor/-*}
            set_variable LAST_FLOOR   ${floor/*-}
        fi

        if [[ -n "${YMIN}" &&  -n "${YMAX}" ]]; then
            set_variable Y_RANGE  -y "$YMIN $YMAX"
        else
            set_variable Y_RANGE
        fi

        set_variable  quantity  `echo $QUANTITY | sed 's/\[/\\\[/g;s/\]/\\\]/g'`

        typeset -Z 3 STRING
        typeset -Z 2 FLOOR

        for STRING in $STRINGS[*]; do

            for (( FLOOR = $FIRST_FLOOR; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do

                notice "Creating graphics ${WORKDIR}/${STRING}_${FLOOR}_${QUANTITY}.${GRAPHICS}"
            
                JPlot1D \
                    -w "$CANVAS"                                               \
                    -f "${INPUT_FILE}:${STRING}.${FLOOR}.${quantity}$"         \
                    ${Y_RANGE}                                                 \
                    -L LT                                                      \
                    -T "(${STRING},${FLOOR})"                                  \
                    -t "$TIMEAXIS"                                             \
                    -o ${WORKDIR}/${STRING}_${FLOOR}_${QUANTITY}.${GRAPHICS}   \
                    -d 0 -B
            done

            if (( ${LAST_FLOOR} - ${FIRST_FLOOR} + 1 == 18 )); then

                notice "Creating graphics ${WORKDIR}/${STRING}_${QUANTITY}.${GRAPHICS}"

                montage \
                    -tile 6x3                                         \
                    -geometry +0+0                                    \
                    ${WORKDIR}/${STRING}_*_${QUANTITY}.${GRAPHICS}    \
                    ${WORKDIR}/${STRING}_${QUANTITY}.${GRAPHICS}

                rm -f ${WORKDIR}/${STRING}_*_${QUANTITY}.${GRAPHICS}
            fi
        done
    fi
done

rm -f $WORKDIR/.parameters.txt