hydrophone-phi:run.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

set_variable  DEBUG               ${ACOUSTICS_DEBUG:-2}
set_variable  WORKDIR             ${ACOUSTICS_WORKDIR:-./}

if ( do_usage $* ); then
    usage "$script <string identifier> <detector file> (input file)+ (toashort file)+"\
          "\nNote that the input files and toashort files should be one-to-one related."
fi

if (( ${#} < 4 || ${#}%2 != 0 )); then
    fatal "Wrong number of arguments."
fi

let N="(${#} - 2) / 2"

set_variable  STRING              $argv[1]
set_variable  DETECTOR            $argv[2]
set_array     INPUT_FILES         $argv[3,2+$N]
set_array     TOASHORT_FILES      $argv[-$N,-1]

eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`
eval `JPrintDetector -a $DETECTOR -O SUMMARY`

source JAcoustics.sh   $DETECTOR_ID

CHECK_EXIT_CODE

getModule -a $DETECTOR -L "$STRINGS[1] 0" >& /dev/null

if (( $? != 0 )); then

    JCookie.sh

    JDetectorDB \
        -a $DETECTOR                \
        -o $DETECTOR                \
        -W --!
fi

if [[ -z "${STRINGS[(r)$STRING]}" ]]; then
    fatal "Invalid string $STRING; "\
          "possible values: ${STRINGS[*]}"
fi

set_variable  MODULE              `getModule -a $DETECTOR -L "$STRING 0"`
set_variable  HYDROPHONE_TXT      $WORKDIR/hydrophonephi_${STRING}.txt
set_variable  TMPDIR              $WORKDIR/.$$
set_variable  PI                  3.1415927
mkdir -p     $TMPDIR

for (( PHI = -$PI; $PHI <= +$PI; PHI += 0.05 )); do

    cp hydrophone.txt  $TMPDIR/.

    JEditHydrophone -f $TMPDIR/hydrophone.txt -S "$STRING rot $PHI"

    $JPP_DIR/examples/JAcoustics/JHydrophone \
        -a $DETECTOR                                    \
        -f "$INPUT_FILES[*]"                            \
        -i "$TOASHORT_FILES[*]"                         \
        -o $TMPDIR/hydrophone.root                      \
        -H $TMPDIR/hydrophone.txt                       \
        -T $WORKDIR/tripod.txt                          \
        -V $WORKDIR/sound_velocity.txt                  \
        -W $WORKDIR/waveform.txt                        \
        -d $DEBUG --!

    JOpera1D \
        -f "$TMPDIR/hydrophone.root:\[${MODULE}\..*\]"  \
        -o  $TMPDIR/opera.root                          \
        -u  Add

    set_array RESULT `JPrintResult -f "$TMPDIR/opera.root:Add" -F "GetRMS * 1.0e3"`

    if (( ${#RESULT} == 1 )); then
        printf "%7.3f %12.8f\n" $PHI $RESULT[*] >> $HYDROPHONE_TXT
    else
        error "No result."
    fi
done

rm -rf $TMPDIR