tripod-3Z:run.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

set_variable  DEBUG               ${ACOUSTICS_DEBUG:-2}
set_variable  WORKDIR             ${ACOUSTICS_WORKDIR:-./}
set_variable  FIT                 ${ACOUSTICS_FIT:-2}

if ( do_usage $* ); then
    usage "$script <detector file> (input file)+"
fi

if (( $# < 2 )); then
    fatal "Wrong number of arguments."
fi

set_variable  DETECTOR            $argv[1]
set_array     INPUT_FILES         $argv[2,-1]

eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`

source JAcoustics.sh   $DETECTOR_ID

CHECK_EXIT_CODE

typeset -A TRIPODS

get_tripods $WORKDIR/tripod.txt TRIPODS

if (( ${#${(@k)TRIPODS}} != 3 )); then
    fatal "Number of tripods ${#${(@k)TRIPODS}} != 3."
fi

set_variable  A                   ${${(@k)TRIPODS}[1]}
set_variable  B                   ${${(@k)TRIPODS}[2]}
set_variable  C                   ${${(@k)TRIPODS}[3]}

set_variable  TRIPOD_TXT          $WORKDIR/tripod3z.txt
set_variable  TMPDIR              $WORKDIR/.$$
mkdir -p     $TMPDIR

echo "# $A $B $C"  >  $TRIPOD_TXT # write header

typeset -a Z

for (( Z[$A] = -2.0; $Z[$A] <= 2.0; Z[$A] += 0.2 )); do
    for (( Z[$B] = -2.0; $Z[$B] <= 2.0; Z[$B] += 0.2 )); do
        for (( Z[$C] = -2.0; $Z[$C] <= 2.0; Z[$C] += 0.2 )); do

            cp $WORKDIR/tripod.txt $TMPDIR/tripod.txt

            for key in "${(@k)TRIPODS}"; do
                JEditTripod -f $TMPDIR/tripod.txt -T "$key add 0.0 0.0 ${Z[$key]}"
            done
            
            rm -f $TMPDIR/katoomba.root

            JKatoomba \
                -a $DETECTOR                              \
                -f "$INPUT_FILES[*]"                      \
                -o $TMPDIR/katoomba.root                  \
                -T $TMPDIR/tripod.txt                     \
                -V $WORKDIR/sound_velocity.txt            \
                -M $WORKDIR/mechanics.txt                 \
                -@ $WORKDIR/acoustics_fit_parameters.txt  \
                -@ "stdev      = 50"                      \
                -@ "mestimator = 1"                       \
                -F $FIT                                   \
                -u                                        \
                -d $DEBUG --!

            set_array RESULT `JPrintResult -f $TMPDIR/katoomba.root:chi2 -F "GetMean" -F "GetRMS / sqrt(GetEntries)"`

            if (( ${#RESULT} == 2 )); then
                printf "%7.3f %7.3f %7.3f %7.3f %7.3f\n" $Z[$A] $Z[$B] $Z[$C] $RESULT[*] >> $TRIPOD_TXT
            else
                error "No result."
            fi
        done
    done
done

rm -rf $TMPDIR