JQAQC.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author mdejong
#
version=1.0
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

# Auxiliary script to produce QA/QC data.
# By default, data are written to terminal but these can be redirected to an ASCII formatted file.
# The stored data can then be uploaded to the database with a tool that is part of the km3pipe package.
# Once uploaded, the data can be viewed with application/scripts JDataMonitor[.sh] and JDataQuality[.sh].
# Note that if the list of values is extended, the include file JRunQuality.hh should accordingly be updated.

set_variable:  DEBUG              QAQC_DEBUG  0
set_variable:  WORKDIR            WORKDIR     ${TMPDIR:-/tmp}
set_variable   ACOUSTICS_WORKDIR  ${WORKDIR}  
set_variable   COMPASS_WORKDIR    ${WORKDIR}  

TRIGGER_PARAMETERS=(
    trigger3DMuon.enabled
    trigger3DShower.enabled
    triggerMXShower.enabled
    writeL0.prescale
    writeL1.prescale
    writeL2.prescale
    writeSN.prescale)

TRIGGERS=(`JPrintTriggerBits`)

DAQ=(
    JDAQTimeslice
    JDAQTimesliceL0
    JDAQTimesliceL1
    JDAQTimesliceL2
    JDAQTimesliceSN
    JDAQSummaryslice
    JDAQEvent)


if do_usage $*; then
    usage \
        "$script <detector file> (input file)+" \
        "\nGIT detector run livetime_s UTCMin_s UTCMax_s ${TRIGGER_PARAMETERS[*]}" \
        " ${DAQ[*]} ${TRIGGERS[*]} in-sync out-sync DAQ WR HRV FIFO PMTs MEAN_Rate_Hz RMS_Rate_Hz Acoustics AHRS"
fi

if (( $# < 2 )); then
    fatal "Wrong number of arguments."
fi 


set_variable  DETECTOR         $argv[1]
set_array     INPUT_FILES      $argv[2,-1]


eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`

source JAcoustics.sh    $DETECTOR_ID

CHECK_EXIT_CODE


for INPUT_FILE in ${INPUT_FILES[*]}; do

    set_variable  FILE_NAME      ${INPUT_FILE##*/}
    set_variable  TURBOT_FILE    $WORKDIR/${FILE_NAME/.root/_turbot.root}

    JTriggerMonitor -v |& awk '/version/ { print $2 }'            | read     GIT_VERSION
    CHECK_EXIT_CODE

    JPrintDAQHeader -f ${INPUT_FILE} -d 0                         | read -A  DAQ_HEADER
    CHECK_EXIT_CODE

    getLivetime     -f ${INPUT_FILE} -d 0                         | read -A  LIVETIME_S
    CHECK_EXIT_CODE

    getUTC          -f ${INPUT_FILE} -d 0                         | read -A  UTC_S
    CHECK_EXIT_CODE

    JPrintTriggerParameters -f ${INPUT_FILE} -d 0 >& /dev/null
    CHECK_EXIT_CODE

    JTriggerMonitor -f ${INPUT_FILE} -d 0 -Q 3 3>&1 >& /dev/null  | read -A  TRIGGER_MONITOR
    CHECK_EXIT_CODE

    JTurbot \
        -f ${INPUT_FILE}                \
        -a ${DETECTOR}                  \
        -o ${TURBOT_FILE}               \
        -d ${DEBUG}                     \
        -Q 3 3>&1 >& ${TURBOT_FILE/.root/.log}                    | read -A  TURBOT
    CHECK_EXIT_CODE

    JSummaryMonitor -f ${INPUT_FILE} -d 0 -Q 3 3>&1 >& /dev/null  | read -A  SUMMARY_MONITOR
    CHECK_EXIT_CODE

    set_variable  RUN            $DAQ_HEADER[2]

    JAcousticsEventBuilder.sh    $DETECTOR     $RUN               >& /dev/null

    if (( $? == 0 )); then

        set_variable  OUTPUT_FILE    $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_event.root

        JPrintResult -f ${OUTPUT_FILE}:'^ACOUSTICS$' -F GetEntries    | read -A  NUMBER_OF_ACOUSTICS_EVENTS  
    else
        NUMBER_OF_ACOUSTICS_EVENTS=(0)
    fi

    JAHRS.sh                     $DETECTOR_ID  $RUN               >& /dev/null
    JAHRSCalibration.sh          $DETECTOR_ID                     >& /dev/null

    set_variable  OUTPUT_FILE    $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_ahrs.root

    JAHRSMonitor \
        -a ${DETECTOR}                      \
        -f ${OUTPUT_FILE}                   \
        -c ${WORKDIR}/ahrs_calibration.txt  \
        -q 0.2                              \
        -d ${DEBUG}                         \
        -Q 3 3>&1 >& /dev/null                                    | read -A  NUMBER_OF_AHRS_EVENTS  

    printf " %32s"   ${GIT_VERSION}
    printf " %8d"    ${DAQ_HEADER[1,2]}
    printf " %9.1f"  ${LIVETIME_S[1]}
    printf " %12.1f" ${UTC_S[*]}

    for KEY in ${TRIGGER_PARAMETERS[*]}; do

        JPrintTriggerParameters -f ${INPUT_FILE} -k $KEY -d 0                   | read VALUE

        printf " %4d" ${VALUE-0}
    done

    for KEY in ${DAQ[*]}; do

        JPrintTree -f ${INPUT_FILE} |& eval awk \'/${KEY}/ \{ print \$3\; \}\'  | read VALUE

        printf " %8d" ${VALUE-0}
    done

    printf " %8d"   ${TRIGGER_MONITOR[*]}
    printf " %2d"   ${TURBOT[1,2]}
    printf " %7.5f" ${SUMMARY_MONITOR[1,4]}
    printf " %8.1f" ${SUMMARY_MONITOR[5]}
    printf " %7.0f" ${SUMMARY_MONITOR[6,7]}
    printf " %4d"   ${NUMBER_OF_ACOUSTICS_EVENTS[1]}
    printf " %8.3f" ${NUMBER_OF_AHRS_EVENTS[1]}
    printf "\n"

done