software/JTrigger/JTriggerEfficiencyRunByRun.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author mdejong
#
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#                Example script to run JTriggerEfficiency in run-by-run mode.
#
# ------------------------------------------------------------------------------------------

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR

set_variable:  DEBUG                 TRIGGEREFFICIENCY_DEBUG                    1
set_variable   WORKDIR               ./                                         
set_variable   INPUT_FILE            $WORKDIR/sirene.root                       
set_variable   OUTPUT_FILE           $WORKDIR/trigger_efficiency+runbyrun.root  
set_variable   DETECTORA             $JPP_DATA/km3net_reference.detx            
set_variable   DETECTORB             $JPP_DATA/km3net_reference.detx            
set_variable   DAQ_FILE              $WORKDIR/summary.root                      
set_variable   PMT_FILE              $JPP_DATA/PMT_parameters.txt               
set_variable:  BACKGROUND_HZ         TRIGGEREFFICIENCY_BACKGROUND_HZ            ${BACKGROUND_HZ:-5e3 500 50 5 0.5}
set_variable:  SEED                  TRIGGEREFFICIENCY_SEED                     0
set_variable:  TURBOT                TRIGGEREFFICIENCY_TURBOT                   
set_variable:  NUMBER_OF_TIMESLICES  TRIGGEREFFICIENCY_NUMBER_OF_TIMESLICES     0
set_variable:  FACTOR                TRIGGEREFFICIENCY_FACTOR                   ${FACTOR:-1.0}
set_variable+  OPTION                TRIGGEREFFICIENCY_TRIGGERED_EVENTS_ONLY    -O

if do_usage $*; then
    usage "$script <detector file> <detector file> (input file)+ <output file> <DAQ file> [PMT parameters file]"\
          "\nNote that if more than one input file is specified, all other arguments must be provided."
fi

case $# in
    6)  set_variable PMT_FILE     $6;&
    5)  set_variable DAQ_FILE     $5;
        set_variable OUTPUT_FILE  $4;
        set_variable INPUT_FILE   $3;
        set_variable DETECTORB    $2;
        set_variable DETECTORA    $1;;
    4)  fatal "Wrong number of arguments.";;
    3)  fatal "Wrong number of arguments.";;
    2)  fatal "Wrong number of arguments.";;
    1)  fatal "Wrong number of arguments.";;
    0)  fatal "Wrong number of arguments.";;
    *)  set_variable DETECTORA    $argv[1]
        set_variable DETECTORB    $argv[2]
        set_variable INPUT_FILE   $argv[3,-4]
        set_variable OUTPUT_FILE  $argv[-3]
        set_variable DAQ_FILE     $argv[-2]
        set_variable PMT_FILE     $argv[-1];;
esac

RUNBYRUN="file=$DAQ_FILE; sampler=25 250"

print_variable     DETECTORA DETECTORB INPUT_FILE OUTPUT_FILE RUNBYRUN PMT_FILE 
check_input_file   $DETECTORA $DETECTORB $INPUT_FILE $DAQ_FILE $PMT_FILE
check_output_file  $OUTPUT_FILE

if [[ -n $TURBOT ]]; then

    JConvertDetectorFormat -a ${DETECTORA} -o ${TURBOT}
        
    if (( $? != 0 )); then
        fatal "Invalid detector file $TURBOT"
    fi

    timer_start

    JTurbot \
        -f ${DAQ_FILE}              \
        -a ${TURBOT}                \
        -A                          \
        -d ${DEBUG}                 \
        -N ${NUMBER_OF_TIMESLICES}  \
        --!

    timer_stop
    timer_print

    set_variable  DETECTOR  $TURBOT
else
    set_variable  DETECTOR  $DETECTORA
fi

timer_start

JTriggerEfficiency \
    -a ${DETECTOR}                \
    -b ${DETECTORB}               \
    -f ${INPUT_FILE}              \
    -o ${OUTPUT_FILE}             \
    -P ${PMT_FILE}                \
    -P "QE=${FACTOR}"             \
    ${OPTION}                     \
    -S ${SEED}                    \
    -B "$BACKGROUND_HZ"           \
    -r "${RUNBYRUN}"              \
    -d ${DEBUG}                   \
    --!

timer_stop
timer_print

JPrintMeta \
    -f  ${OUTPUT_FILE}

JPrintTree \
    -f  ${OUTPUT_FILE}

JTriggerMonitor \
    -o  $WORKDIR/monitor.root \
    -f  ${OUTPUT_FILE}