JAHRS.sh

Go to the documentation of this file.

#!/bin/zsh
#
#
# \author mdejong
#
version=1.0
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR

set_variable:  DEBUG    COMPASS_DEBUG    2
set_variable:  WORKDIR  COMPASS_WORKDIR  ./

if do_usage $*; then
    usage "$script <detector file> (run[-run])+"
fi

if (( $# > 1 )); then
    set_variable  DETECTOR_ID     $argv[1]
    set_array     RUNS            $argv[2,-1]
else
    fatal "Wrong number of arguments."
fi

JCookie.sh

let NUMBER_OF_ERRORS="0"

for RANGE in $RUNS[*]; do

    for (( RUN = ${RANGE%%-*}; $RUN <= ${RANGE##*-}; RUN += 1 )); do

        set_variable  AHRS_FILE  $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_ahrs.root

        if [[ ! -f $AHRS_FILE ]]; then

            echo -n "Writing $AHRS_FILE... "
    
            JConvertDB \
                -q "ahrs"                      \
                -@ "detid  = $DETECTOR_ID"     \
                -@ "minrun = $RUN"             \
                -@ "maxrun = $RUN"             \
                -o $AHRS_FILE                  \
                -d $DEBUG --

            if (( $? == 0 )); then
                echo "OK"
            else
                echo "no data"
                let NUMBER_OF_ERRORS="$NUMBER_OF_ERRORS + 1"
            fi
        fi
    done
done

if (( $NUMBER_OF_ERRORS != 0 )); then
    fatal "Number of errors $NUMBER_OF_ERRORS"
fi