hydrophone-XY:run.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

zmodload zsh/mathfunc

set_variable:  DEBUG           ACOUSTICS_DEBUG          2
set_variable:  WORKDIR         ACOUSTICS_WORKDIR        ./
set_variable:  QUALITY_FACTOR  ACOUSTICS_QUALITYFACTOR  2.0e3

if do_usage $*; then
    usage "$script <string identifier> <detector file> (event file)+ (toashort file)+"\
          "\nNote that the event files and toashort files should be one-to-one related."
fi

if (( ${#} < 4 || ${#}%2 != 0 )); then
    fatal "Wrong number of arguments."
fi

let N="(${#} - 2) / 2"

set_variable  STRING              $argv[1]
set_variable  DETECTOR            $argv[2]
set_array     INPUT_FILES         $argv[3,2+$N]
set_array     TOASHORT_FILES      $argv[-$N,-1]

eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`
eval `JPrintDetector -a $DETECTOR -O SUMMARY`

source JAcoustics.sh   $DETECTOR_ID

CHECK_EXIT_CODE

typeset -A TRIPODS

get_tripods $WORKDIR/tripod.txt TRIPODS

if (( ${#TRIPODS} < 2 )); then
    fatal "Not enough tripods " ${#TRIPODS}
fi

getModule -a $DETECTOR -L "$STRINGS[1] 0" >& /dev/null

if (( $? != 0 )); then

    JCookie.sh

    JDetectorDB \
        -a $DETECTOR                \
        -o $DETECTOR                \
        -W --!
fi

if [[ -z "${STRINGS[(r)$STRING]}" ]]; then
    fatal "Invalid string $STRING; "\
          "possible values: ${STRINGS[*]}"
fi

set_variable  MODULE              `getModule -a $DETECTOR -L "$STRING 0"`
set_variable  HYDROPHONE_TXT      $WORKDIR/hydrophonexy_${STRING}.txt
set_array     QUANTILES           0.333 0.666
set_variable  TMPDIR              $WORKDIR/.$$
mkdir -p     $TMPDIR

for (( i = 1; i <= ${#INPUT_FILES}; ++i )); do

    set_variable  OUTPUT_FILE  $TMPDIR/katoomba_${i}.root

    JKatoomba.sh  $DETECTOR  $INPUT_FILES[${i}]  $OUTPUT_FILE

    INPUT_FILES[${i}]=$OUTPUT_FILE
done

cp hydrophone.txt  $TMPDIR/.

for (( X = -2.0; $X <= +2.0; X += 0.1 )); do
    for (( Y = -2.0; $Y <= +2.0; Y += 0.1 )); do

        JEditHydrophone -f $TMPDIR/hydrophone.txt -S "$STRING set $X $Y 0.0"

        $JPP_DIR/examples/JAcoustics/JHydrophone \
            -a $DETECTOR                                    \
            -f "$INPUT_FILES[*]"                            \
            -i "$TOASHORT_FILES[*]"                         \
            -o $TMPDIR/hydrophone.root                      \
            -H $TMPDIR/hydrophone.txt                       \
            -T $WORKDIR/tripod.txt                          \
            -V $WORKDIR/sound_velocity.txt                  \
            -W $WORKDIR/waveform.txt                        \
            -Q $QUALITY_FACTOR                              \
            -d $DEBUG --!

        XMEAN=(0.0 0.0)
        STDEV=(0.0 0.0)
        TOTAL=0.0

        for TRIPOD in ${(@k)TRIPODS}; do

            JPrintQuantiles \
                -f "$TMPDIR/hydrophone.root:${MODULE}\.${TRIPOD}"   \
                -Q "$QUANTILES[*]"                                  \
                -d 0                                                | read -A RESULT

            if (( ${#RESULT} == ${#QUANTILES} )); then
            
                VALUE=$((0.5e3 * ($RESULT[-1] + $RESULT[1])))           # average [ms]
                TOTAL=$(($TOTAL + 1.0))

                if (( $TOTAL == 1.0 )); then
                    XMEAN[1]=$VALUE
                    STDEV[1]=0.0
                else
                    XMEAN[2]=$(($XMEAN[1] + ($VALUE - $XMEAN[1]) / $TOTAL))
                    STDEV[2]=$(($STDEV[1] + ($VALUE - $XMEAN[1]) * ($VALUE - $XMEAN[2])))
                    XMEAN[1]=$XMEAN[2]
                    STDEV[1]=$STDEV[2]
                fi
            fi
        done

        printf "%7.3f %7.3f %9.5f\n" $X $Y $((sqrt($TOTAL * $STDEV[1] / ($TOTAL * ($TOTAL - 1.0))))) >> $HYDROPHONE_TXT
    done
done

rm -rf $TMPDIR