JRandomEventRunByRun.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author zaly
#
version=1.0
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#    Script to jointly run JRandomTimesliceWriter and JTriggerProcessor in run-by-run mode.
#
# ------------------------------------------------------------------------------------------

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR

set_variable:  DEBUG                 RANDOMEVENT_DEBUG                      1
set_variable:  WORKDIR               RANDOMEVENT_WORKDIR                    ./
set_variable:  BACKGROUND_HZ         RANDOMEVENT_BACKGROUND_HZ              `getK40Rates`
set_variable:  SEED                  RANDOMEVENT_SEED                       0
set_variable:  NUMBER_OF_SLICES      RANDOMEVENT_SLICES                     10
set_variable:  RECYCLING             RANDOMEVENT_RECYCLING                  "0 0"
set_variable:  FACTOR                RANDOMEVENT_FACTOR                     1.0
set_variable:  SAMPLER               RANDOMEVENT_SAMPLER                    "1 1000"

set_variable   DAQ_TIMESLICE         JDAQTimesliceL0

if do_usage $*; then
    usage "$script <detector file> <output file> <DAQ file> <PMT parameters file>"\
          "\nAuxiliary script to produce random event data."
fi

if (( $# == 4 )); then
    set_variable  PMT_FILE     $4
    set_variable  DAQ_FILE     $3
    set_variable  OUTPUT_FILE  $2
    set_variable  DETECTOR     $1
else
    fatal "Wrong number of arguments."
fi

JPrintTree -f $DAQ_FILE | awk '/KM3NETDAQ::JDAQSummaryslice/ {print $3}'  |  read N

set_variable   RUNBYRUN             "file=$DAQ_FILE; sampler=${SAMPLER%% *} $(($N / 2))"

#################################################################################################
#
# The sampler values correspond to N_on N_off, respectively (note that sampler calls JSampler),
# where:
# N_on   =  number of time slices to read;
# N_off  =  number of time slices to skip.
#
# The sampler option works as follows.
# It will
# read -on average- N_on  consecutive time slices and  
# skip -on average- N_off time slices
# modulo the number of time slices in the file.
#
# The larger N_on, the faster the reading, because this reduces the random accesses 
# of the data taking file to pick up a next time slice.
# The smaller N_off, the less time slices are skipped.
# So, N_on = 0 guarantees that all time slices are sampled.
# Note that if the number of time slices to be produced is small, then too small a value of N_off
# could create a bias because only the first time slices of the data taking file are then sampled.
#################################################################################################

set_variable   PIPE                 `mktemp -d $WORKDIR/XXXXXX`/pipe.dat
set_variable   TRIGGER              `mktemp $WORKDIR/trigger_XXXXXX.txt`

mkfifo $PIPE

if [[ -p $PIPE ]]; then

    timer_start
    
    JRandomTimesliceWriter \
        -a ${DETECTOR}                \
        -o ${PIPE}                    \
        -n ${NUMBER_OF_SLICES}        \
        -P ${PMT_FILE}                \
        -P "QE=${FACTOR}"             \
        -S ${SEED}                    \
        -B "$BACKGROUND_HZ"           \
        -N "$RECYCLING"               \
        -r "${RUNBYRUN}"              \
        -d ${DEBUG}                   \
        --! &

    JPrintTriggerParameters \
        -f ${DAQ_FILE}                > $TRIGGER

    JTriggerProcessor \
        -a ${DETECTOR}                \
        -f ${PIPE}                    \
        -@ ${TRIGGER}                 \
        -C ${DAQ_TIMESLICE}           \
        -o ${OUTPUT_FILE}             \
        -d ${DEBUG}                   \
        --! 
        
    rm -rf ${PIPE:h}
    rm -f  ${TRIGGER}
     
    timer_stop
    timer_print

    JPrintTree \
        -f ${OUTPUT_FILE}

    JTriggerMonitor \
        -f  ${OUTPUT_FILE}            \
        -o  /dev/null

else

    fatal "Error opening $PIPE."
fi