JRecalibrateK40.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#                      Script to run K40 time calibration following HV tuning.
#
# ------------------------------------------------------------------------------------------

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

set_variable:  DEBUG              CALIBRATION_DEBUG          1
set_variable:  WORKDIR            CALIBRATION_WORKDIR        `pwd`
set_variable:  DAQ_TIMESLICE      CALIBRATION_TIMESLICE      JDAQTimesliceL1
set_variable+  DATABASE_OPTION    CALIBRATION_USEPMTID       -U
set_variable+  MODEL              CALIBRATION_MODEL          -D

if do_usage $*; then
    usage "$script <detector file> <input file> <input file> <input file>"\
          "\nThe 1st and 3rd input file should correspond to a data taking run in which the HV settings are complete (e.g. \"vendor\" or \"tuned\")."\
          "\nThe 2nd input file should correspond to a run with so-called hybrid HV settings."\
          "\nIn this, half of the PMTs should have the same HV settings as either the 1st or 3rd input file."
fi

if (( $# == 4 )); then
    set_variable  DETECTOR      $argv[1]
    set_array     INPUT_FILES   $argv[2,-1]
else
    fatal "Wrong number of arguments."
fi

JCookie.sh

#
# Get background option for given input file.
#
# \param   1     input file
# \return        option
#
function get_option()
{
    if (( `JPrintTree -f $1 |  awk '/JDAQSummaryslice/ { print $3 } '` > 0 )); then
        echo  rates
    else
        echo  counts
    fi
}
    

#
# Standard calibration.
#
# \param   1     detector
# \param   2     input file
#
function calibrate()
{
    JPrintDAQHeader -f $2  |  read  ID  RUN  FRAME_INDEX  UTC

    JCalibrateK40 \
        -a $1                                        \
        -f $2                                        \
        -C $DAQ_TIMESLICE                            \
        -o $ODIR/monitor_${RUN}.root                 \
        -b `get_option $2`                           \
        -d $DEBUG

    JMergeCalibrateK40 \
        -f $ODIR/monitor_${RUN}.root                 \
        -o $ODIR/merge_${RUN}.root                   \
        -d $DEBUG

    JConvertDetectorFormat \
        -a $1                                        \
        -o $ODIR/detector_${RUN}.datx

    JFitK40 \
        -a $ODIR/detector_${RUN}.datx                \
        -f $ODIR/merge_${RUN}.root                   \
        -o $ODIR/fit_${RUN}.root                     \
        $MODEL                                       \
        -A                                           \
        -w                                           \
        -d $DEBUG
}


#
# Hybrid calibration.
#
# \param   1     detector
# \param   2     reference run
# \param   3     input file
#
function hybrid()
{
    JPrintDAQHeader -f $3  |  read  ID  RUN  FRAME_INDEX  UTC

    JTDC  \
        -D $DETECTOR_ID                              \
        -r "$2 $RUN"                                 \
        $DATABASE_OPTION                             \
        -o "$ODIR/TDC_${2}_${RUN}.txt"

    JCalibrateK40 \
        -a $1                                        \
        -f $3                                        \
        -C $DAQ_TIMESLICE                            \
        -o $ODIR/monitor_${RUN}.root                 \
        -b `get_option $3`                           \
        -d $DEBUG

    JMergeCalibrateK40 \
        -f $ODIR/monitor_${RUN}.root                 \
        -o $ODIR/merge_${RUN}.root                   \
        -d $DEBUG

    JConvertDetectorFormat \
        -a $1                                        \
        -o $ODIR/detector_${RUN}.datx

    JFitK40 \
        -a $ODIR/detector_${RUN}.datx                \
        -f $ODIR/merge_${RUN}.root                   \
        -o $ODIR/fit_${RUN}.root                     \
        $MODEL                                       \
        -A                                           \
        -w                                           \
        -! $ODIR/TDC_${2}_${RUN}.txt                 \
        -d $DEBUG                                    
}


# Get run numbers

eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`

RUNS=()

for INPUT_FILE in $INPUT_FILES[*]; do

    JPrintDAQHeader -f $INPUT_FILE  |  read  ID  RUN  FRAME_INDEX  UTC

    if (( $ID != $DETECTOR_ID )); then
        fatal "Detector identifier from $INPUT_FILE $ID != $DETECTOR_ID"
    fi
    
    RUNS+=($RUN)

done


# Process string-by-string

eval `JPrintDetector -a $DETECTOR -O SUMMARY`

for STRING in $STRINGS[*]; do

    echo "Processing string $STRING"

    set_variable  ODIR  $WORKDIR/$STRING
    mkdir -p     $ODIR

    JEditDetector -a $DETECTOR -k $STRING -o $ODIR/detector.datx

    calibrate  $ODIR/detector.datx                          ${INPUT_FILES[1]}  >&  $ODIR/calibrate.log

    hybrid     $ODIR/detector_${RUNS[1]}.datx  ${RUNS[1]}   ${INPUT_FILES[2]}  >&  $ODIR/hybrid_${RUNS[1]}.log

    hybrid     $ODIR/detector_${RUNS[2]}.datx  ${RUNS[2]}   ${INPUT_FILES[3]}  >&  $ODIR/hybrid_${RUNS[2]}.log
done

for (( i = 1; $i <= 3; ++i )); do
    JMergeDetector "-a $WORKDIR/"${^STRINGS}"/detector_${RUNS[${i}]}.datx" -o $WORKDIR/detector_${RUNS[${i}]}.datx
done


# cleanup

#rm -rf "$WORKDIR/"${^STRINGS}

---

Generated by   1.8.5