hydrophone-XY:run.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

zmodload zsh/mathfunc

set_variable:  DEBUG           ACOUSTICS_DEBUG          2
set_variable:  WORKDIR         ACOUSTICS_WORKDIR        ./
set_variable:  QUALITY_FACTOR  ACOUSTICS_QUALITYFACTOR  2.0e3

if do_usage $*; then
    usage "$script <string identifier> <detector file> (input file)+"
fi

if (( ${#} < 3 )); then
    fatal "Wrong number of arguments."
fi

set_variable  STRING              $argv[1]
set_variable  DETECTOR            $argv[2]
set_array     INPUT_FILES         $argv[3,-1]

eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`
eval `JPrintDetector -a $DETECTOR -O SUMMARY`

JAcoustics.sh   $DETECTOR_ID

source JAcousticsToolkit.sh

CHECK_EXIT_CODE

typeset -A TRIPODS

get_tripods $WORKDIR/tripod.txt TRIPODS

if (( ${#TRIPODS} < 2 )); then
    fatal "Not enough tripods " ${#TRIPODS}
fi

if [[ -z "${STRINGS[(r)$STRING]}" ]]; then
    fatal "Invalid string $STRING; "\
          "possible values: ${STRINGS[*]}"
fi

set_variable  MODULE              `getModule -a $DETECTOR -L "$STRING 0"`
set_variable  HYDROPHONE_TXT      $WORKDIR/hydrophonexy_${STRING}.txt
set_array     QUANTILES           0.333 0.666
set_variable  TMPDIR              $WORKDIR/.$$
mkdir -p     $TMPDIR

JKatoomba.sh  $DETECTOR  $INPUT_FILES[*]  $TMPDIR/katoomba.root

for (( X = -2.0; $X <= +2.0; X += 0.1 )); do
    for (( Y = -2.0; $Y <= +2.0; Y += 0.1 )); do

        JEditHydrophone -f $WORKDIR/hydrophone.txt -S "$STRING set $X $Y 0.0" -o $TMPDIR/hydrophone.txt

        $JPP_DIR/examples/JAcoustics/JHydrophone \
            -a $DETECTOR                                    \
            -f $TMPDIR/katoomba.root                        \
            -o $TMPDIR/hydrophone.root                      \
            -H $TMPDIR/hydrophone.txt                       \
            -T $WORKDIR/tripod.txt                          \
            -V $WORKDIR/sound_velocity.txt                  \
            -W $WORKDIR/waveform.txt                        \
            -Q $QUALITY_FACTOR                              \
            -d $DEBUG --!

        XMEAN=(0.0 0.0)
        STDEV=(0.0 0.0)
        TOTAL=0.0

        for TRIPOD in ${(@k)TRIPODS}; do

            JPrintQuantiles \
                -f "$TMPDIR/hydrophone.root:${MODULE}\.${TRIPOD}"   \
                -Q "$QUANTILES[*]"                                  \
                -d 0                                                | read -A RESULT

            if (( ${#RESULT} == ${#QUANTILES} )); then
            
                VALUE=$((0.5e3 * ($RESULT[-1] + $RESULT[1])))           # average [ms]
                TOTAL=$(($TOTAL + 1.0))

                if (( $TOTAL == 1.0 )); then
                    XMEAN[1]=$VALUE
                    STDEV[1]=0.0
                else
                    XMEAN[2]=$(($XMEAN[1] + ($VALUE - $XMEAN[1]) / $TOTAL))
                    STDEV[2]=$(($STDEV[1] + ($VALUE - $XMEAN[1]) * ($VALUE - $XMEAN[2])))
                    XMEAN[1]=$XMEAN[2]
                    STDEV[1]=$STDEV[2]
                fi
            fi
        done

        printf "%7.3f %7.3f %9.5f\n" $X $Y $((sqrt($TOTAL * $STDEV[1] / ($TOTAL * ($TOTAL - 1.0))))) >> $HYDROPHONE_TXT
    done
done

rm -rf $TMPDIR