qaqc.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author mdejong
#
version=1.0
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable:  DEBUG              QAQC_DEBUG    0
set_variable:  WORKDIR            QAQC_WORKDIR  ${TMPDIR:-/tmp}/.$$
 
typeset -a PARAMETERS
 
PARAMETERS=(
    detector run 
    in-usync out-usync
    event_duration)
 
 
if do_usage $*; then
    usage \
        "$script (input file)+ <QA/QC file>"      \
        "\nAuxiliary script to produce the following QA/QC data:" \
        "\n$PARAMETERS[*]"
fi
 
if (( $# < 2 )); then
    fatal "Wrong number of arguments."
fi
 
set_array      INPUT_FILES        $argv[1,-2]
set_variable   QAQC_FILE          $argv[-1]
 
 
mkdir -p $WORKDIR
 
set_variable   DETECTOR           ${WORKDIR}/detector.detx
 
JCookie.sh
CHECK_EXIT_CODE
 
if [[ ! -s $QAQC_FILE ]]; then
    echo $PARAMETERS[*]                                                  >  $QAQC_FILE
fi
 
for INPUT_FILE in ${INPUT_FILES[*]}; do
 
    # determine values
 
    JPrintDAQHeader -f ${INPUT_FILE} -d 0                                | read -A  DAQ_HEADER
 
    if (( $? != 0 )); then
        continue
    fi
 
    set_variable  DETECTOR_ID    ${DAQ_HEADER[1]}
    set_variable  RUN            ${DAQ_HEADER[2]}
 
    JDetectorDB -D ${DETECTOR_ID} -r ${RUN} -o ${DETECTOR}               # install detector file as-is for JTriggerReprocessor
    CHECK_EXIT_CODE
 
    set_variable  OUTPUT_FILE    ${WORKDIR}/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_trigger.root
 
    JTriggerProcessor \
        -a ${DETECTOR}                                    \
        -f ${INPUT_FILE}                                  \
        -C JDAQTimesliceSN                                \
        -@ "trigger3DMuon.enabled         =  1"           \
        -@ "trigger3DMuon.numberOfHits    =  3"           \
        -@ "trigger3DMuon.numberOfModules =  3"           \
        -@ "trigger3DMuon.gridAngle_deg   = 10"           \
        -@ "trigger3DMuon.TMaxExtra_ns    = 500.0e3"      \
        -@ "TMaxEvent_ns    = 500.0e3"                    \
        -@ "TMaxLocal_ns    = 20.0"                       \
        -@ "L2.numberOfHits = 4"                          \
        -@ "L2.TMaxLocal_ns = 20.0"                       \
        -@ "L2.ctMin        = 0.0"                        \
        -o ${OUTPUT_FILE}                                 \
        -d ${DEBUG}
 
    { $JPP_DIR/examples/JDataQuality/JSquid \
        -a ${DETECTOR}                                        \
        -f ${OUTPUT_FILE}                                     \
        -o /dev/null                                          \
        -d ${DEBUG}                                           \
        -Q 3 3>&1 1>&4                                                   | read -A  SQUID } 4>&1
 
    { $JPP_DIR/examples/JDataQuality/JMermaid \
        -a ${DETECTOR}                                        \
        -f ${INPUT_FILE}                                      \
        -o /dev/null                                          \
        -d ${DEBUG}                                           \
        -Q 3 3>&1 1>&4                                                   | read -A  MERMAID } 4>&1
 
    # print values
 
    printf " %8d"    ${DAQ_HEADER[1,2]}                                  >> $QAQC_FILE
    printf " %4d"    ${SQUID[1,2]}                                       >> $QAQC_FILE
    printf " %8d"    ${MERMAID[*]}                                       >> $QAQC_FILE
    printf "\n"                                                          >> $QAQC_FILE
done
 
rm -rf $WORKDIR