JMonitorHV.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable:  DEBUG       DATABASE_DEBUG         1
set_variable:  WORKDIR     DATABASE_WORKDIR       ./
set_variable:  FORMAT      GRAPHICS_FORMAT        gif
set_variable+  BATCH       GRAPHICS_BATCH         -B
set_variable   DIR         $JPP_DIR/examples/JDB/
set_variable   YMIN        -1400                  # V
set_variable   YMAX         -700                  # V
set_variable   POSITION     ".*"
#set_variable   POSITION    22
 
if do_usage $*; then
    usage "$script (input file)+"\
          "Auxiliary script to monitor HV for a set of data taking files."
fi
 
if (( $# < 1 )); then
    fatal "Wrong number of arguments."
fi
 
set_array     INPUT_FILES   $argv[1,-1]
 
JCookie.sh
 
typeset -Z 4  STRING
typeset -Z 2  FLOOR
if [[ "$POSITION" != ".*" ]]; then
    typeset -Z 2  POSITION
fi
 
RUNS=()
 
for INPUT_FILE in $INPUT_FILES[*]; do
 
    echo "Processing $INPUT_FILE"
 
    JPrintDAQHeader  -f $INPUT_FILE  |  read DETECTOR_ID RUN FRAME_INDEX UTC
    getUTC           -f $INPUT_FILE  |  read -A UTC
 
    RUNS+=($RUN)
    
    set_variable  DETECTOR      $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}.detx
 
    if ( ! reuse_file $DETECTOR ); then
        JDetectorDB  -D $DETECTOR_ID  -r $RUN  -o $DETECTOR
    fi
 
    eval `JPrintDetector -a $DETECTOR -O SUMMARY`
  
    let "X = 0.5*($UTC[1] + $UTC[2])"
 
    JText \
        -p "$X $(($YMAX - 0.05*($YMAX - $YMIN))) $RUN"            \
        -@ "align = 22"                                           \
        -@ "size  = 20"                                           \
        -o ${TMPDIR:-/tmp}/text_${RUN}.root
 
    for (( i = 1; $i <= 2; ++i )); do
        JLine \
            -p "$UTC[${i}] $YMIN $UTC[${i}] $YMAX"                \
            -@ "width =  2"                                       \
            -o ${TMPDIR:-/tmp}/utc${i}_${RUN}.root
    done
done
 
 
if ( ! reuse_file $WORKDIR/hv_${RUNS[1]}-${RUNS[-1]}.root ); then
 
    $DIR/JCheckHV \
        -D $DETECTOR_ID                                       \
        -R "$RUNS[*]"                                         \
        -o $WORKDIR/hv_${RUNS[1]}-${RUNS[-1]}.root            >& hv.log
fi
 
getUTC -f "$INPUT_FILES[*]"  |  read -A UTC
 
for STRING in $STRINGS; do
 
    echo -n "Creating graphics for string $STRING.."
 
    for (( FLOOR = 1; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do
    
        JPlot1D \
            -w 1200x600                                                                         \
            -f "$WORKDIR/hv_${RUNS[1]}-${RUNS[-1]}.root:G\[${STRING}.${FLOOR}.${POSITION}].hv"  \
            -f${TMPDIR:-/tmp}/utc1_${^RUNS}".root:.*"                                                      \
            -f${TMPDIR:-/tmp}/utc2_${^RUNS}".root:.*"                                                      \
            -f${TMPDIR:-/tmp}/text_${^RUNS}".root:.*"                                                      \
            -x "$(($UTC[1] - 500))  $(($UTC[2] + 500))"                                         \
            -y "$YMIN $YMAX"                                                                    \
            -S 0.5                                                                              \
            -T "${STRING}.${FLOOR}.${POSITION}"                                                 \
            -N "X 505"                                                                          \
            -t utc                                                                              \
            -o ${TMPDIR:-/tmp}/hv_${STRING}_${FLOOR}.$FORMAT                                               $BATCH
    done
 
    montage \
        -tile 6x3                                                       \
        -geometry +0+0                                                  \
        ${TMPDIR:-/tmp}/hv_${STRING}_*.$FORMAT                                     \
        $WORKDIR/hv_${RUNS[1]}-${RUNS[-1]}_${STRING}.$FORMAT            >&  /dev/null
 
    echo " -> $WORKDIR/hv_${RUNS[1]}-${RUNS[-1]}_${STRING}.$FORMAT"
 
done