module-Z:fit.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable:  DEBUG       ACOUSTICS_DEBUG        2
set_variable:  WORKDIR     ACOUSTICS_WORKDIR      ./
#set_variable   FORMULA     "[0] + [1] * log(1.0 + 0.5*(x-[2])*(x-[2])/([3]*[3]))"  
set_variable   FORMULA     "[0] + [1] * ((x-[2])*(x-[2])/([3]*[3]))"
set_variable   MINIMAL_DZ  0.01                   
set_variable:  FORMAT      GRAPHICS_FORMAT        gif
set_variable+  BATCH       GRAPHICS_BATCH         -B
 
if do_usage $*; then
    usage "$script <string identifier> <floor[-floor]> [<detector file>]"
fi
 
if (( $# < 2 || $# > 3 )); then
    fatal "Wrong number of arguments."
fi
 
set_variable  STRING              $argv[1]
set_variable  FLOORS              $argv[2]
 
for (( FLOOR = ${FLOORS%%-*}; $FLOOR <= ${FLOORS##*-}; FLOOR += 1 )); do
 
    typeset -Z 0 STRING
    typeset -Z 0 FLOOR
 
    set_variable  MODULE_TXT          $WORKDIR/modulez_${STRING}_${FLOOR}.txt
    set_variable  MODULE_ROOT         $WORKDIR/modulez_${STRING}_${FLOOR}.root
    set_variable  G1_TXT              $WORKDIR/g1.txt
    set_variable  G1_ROOT             $WORKDIR/g1.root
 
    if [[ ! -f $MODULE_TXT ]] then
        fatal "No file $MODULE_TXT."
    fi
 
    JGraph \
        -f $MODULE_TXT                            \
        -o $MODULE_ROOT
 
    sort -g  -k 2,2 $MODULE_TXT | tail -1 | read X ZMAX RMS
    sort -gr -k 2,2 $MODULE_TXT | tail -1 | read X ZMIN RMS
 
    echo $X $ZMIN > $G1_TXT; 
 
    JGraph \
        -f $G1_TXT                                \
        -o $G1_ROOT
 
    awk '
        BEGIN {
        XMIN = +1e3
        XMAX = -1e3
        }
        END { print XMIN, XMAX }
        {
        if ( $1 < XMIN ) { XMIN = $1 }
        if ( $1 > XMAX ) { XMAX = $1 }
        }
        ' $MODULE_TXT | read XMIN XMAX
 
    if (( $X > $XMIN && $X < $XMAX )); then
 
        let "DZ = 0.5*($ZMAX - $ZMIN)"
 
        if (( $ZMAX - $ZMIN < $MINIMAL_DZ )); then
            set_variable OPTION "-= p1 = 0.0; p2 = 0.0; p3 = 1.0"
        else
            set_variable OPTION 
        fi
 
        JFit \
            -f ${MODULE_ROOT}:\.\*                    \
            -o $WORKDIR/fit.root                      \
            -F "$FORMULA"                             \
            -@ "p0 =  $ZMIN"                          \
            -@ "p1 =  $DZ"                            \
            -@ "p2 =  $X"                             \
            -@ "p3 =  0.15"                           \
            "$OPTION"                                 \
            -d $DEBUG
 
        set_array    P2   `JPrintFit -f $WORKDIR/fit.root:\.\* -@p2`
 
        set_variable X  $P2[1]
 
        printf "nominal %4d %2d %7.3f %7.3f\n" $STRING $FLOOR 0.0 `JPrintFit -f $WORKDIR/fit.root:\.\* -x "0.0"`
        printf "optimal %4d %2d %7.3f %7.3f\n" $STRING $FLOOR $X  `JPrintFit -f $WORKDIR/fit.root:\.\* -x "$X"`
 
        mv $WORKDIR/fit.root $MODULE_ROOT
 
    else
 
        echo   "Optimum value at limit; -> no fit."
        printf "nominal %4d %2d %7.3f %7.3f\n" $STRING $FLOOR 0.0 `awk -v X=0.0 '{ if ($1 == X) { print $2 }}' $MODULE_TXT`
        printf "optimal %4d %2d %7.3f %7.3f\n" $STRING $FLOOR $X  $ZMIN
 
    fi
    
    if (( $# == 3 )); then
 
        set_variable  DETECTOR        $argv[3]
 
        if (( $ZMAX - $ZMIN >= $MINIMAL_DZ )); then
            
            set_variable  MODULE          `getModule -a $DETECTOR -L "$STRING $FLOOR"`
 
            JEditDetector -a $DETECTOR -M "$MODULE add 0.0 0.0 $X" -o $DETECTOR
 
        else
            echo "No update of detector $DETECTOR; z-range ($ZMAX-$ZMIN) < $MINIMAL_DZ."
        fi
    fi
 
    typeset -Z 4 STRING
    typeset -Z 2 FLOOR
 
    JPlot1D \
        -f ${MODULE_ROOT}:\.\*                            \
        -f ${G1_ROOT}:\.\*                                \
        -> "#Deltaz [m]"                                 \
        -\^ "#chi^{2}/NDF"                                \
        -N "X 505"                                        \
        -T "($STRING,$FLOOR)"                             \
        -o $WORKDIR/modulez_${STRING}_${FLOOR}.$FORMAT    $BATCH
 
    rm -f  $MODULE_ROOT $G1_TXT $G1_ROOT
 
done
 
if [[ "$FLOORS" == "1-18" ]]; then
 
    echo -n "Creating graphics for string $STRING.."
 
    montage \
        -tile 6x3                               \
        -geometry +0+0                          \
        $WORKDIR/modulez_${STRING}_*.$FORMAT    \
        $WORKDIR/modulez_${STRING}.$FORMAT      >& /dev/null
 
    echo " -> $WORKDIR/modulez_${STRING}.$FORMAT"
 
    rm -f $WORKDIR/modulez_${STRING}_*.$FORMAT
 
fi