archive-put-offline-detectors.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable:  DEBUG           ARCHIVE_DEBUG          2
set_variable:  WORKDIR         ARCHIVE_WORKDIR        ${TMPDIR:-/tmp}/
set_variable   TYPE            offline
 
if do_usage $*; then
    usage "$script <archive> <version> <detector identifier> (run[-run])+"\
          "\nAuxiliary script to download online detector files from database and to store these in archive."
fi
 
if (( $# > 3 )); then
    set_variable  ARCHIVE         $argv[1]
    set_variable  VERSION         $argv[2]
    set_variable  DETECTOR_ID     $argv[3]
    set_array     RUNS            $argv[4,-1]
else
    fatal "Wrong number of arguments."
fi
 
JCookie.sh
 
set_variable  DETECTOR_ID     $(getDetector -D $DETECTOR_ID -O int)
set_variable  DETECTOR        $WORKDIR/detector.detx
 
for RANGE in $RUNS[*]; do
 
    let "MINRUN = ${RANGE%%-*}"
    let "MAXRUN = ${RANGE##*-}"
 
    for (( i0 = $MINRUN; $i0 <= $MAXRUN; )); do
 
        JRunCalibration \
            -D $DETECTOR_ID              \
            -r $i0                       \
            -R 1                         \
            -F PMT_T0_CALIBRATION        \
            -F DOM_POSITION_CALIBRATION  \
            -F DOM_ROTATION_CALIBRATION  \
            -F ACOUSTIC_T0_CALIBRATION   \
            -F COMPASS_CALIBRATION       \
            -F STATUS_CALIBRATION        \
            -F RUN                       |  read TCAL_0 PCAL_0 RCAL_0 ACAL_0 CCAL_0 SCAL_0 RUN_0
 
        if (( $? != 0 )) || [[ "$RUN_0" == "" ]] || (( $RUN_0 != $i0 )); then
 
            let "i0 = $i0 + 1"
            
            continue
        fi
 
        notice "Run $RUN_0 $TCAL_0 $PCAL_0 $RCAL_0 $ACAL_0 $CCAL_0 $SCAL_0"
 
        for (( i1 = $i0 + 1; $i1 <= $MAXRUN; i1 += 1 )); do
 
            JRunCalibration \
                -D $DETECTOR_ID              \
                -r $i1                       \
                -R 1                         \
                -F PMT_T0_CALIBRATION        \
                -F DOM_POSITION_CALIBRATION  \
                -F DOM_ROTATION_CALIBRATION  \
                -F ACOUSTIC_T0_CALIBRATION   \
                -F COMPASS_CALIBRATION       \
                -F STATUS_CALIBRATION        \
                -F RUN                       |  read TCAL_1 PCAL_1 RCAL_1 ACAL_1 CCAL_1 SCAL_1 RUN_1
 
            if (( $? != 0 )) || [[ "$RUN_1" == "" ]] || (( $RUN_1 != $i1 )); then
                break
            fi
 
            notice "Run $RUN_1 $TCAL_1 $PCAL_1 $RCAL_1 $ACAL_1 $CCAL_1 $SCAL_1"
 
            if [[ "$TCAL_0" != "$TCAL_1" || "$PCAL_0" != "$PCAL_1" || "$RCAL_0" != "$RCAL_1" || "$ACAL_0" != "$ACAL_1" || "$CCAL_0" != "$CCAL_1" || "$SCAL_0" != "$SCAL_1" ]] then
                break
            fi
        done
 
        JDetectorDB \
            -D $DETECTOR_ID      \
            -@ "tcal = $TCAL_0"  \
            -@ "pcal = $PCAL_0"  \
            -@ "rcal = $RCAL_0"  \
            -@ "acal = $ACAL_0"  \
            -@ "ccal = $CCAL_0"  \
            -@ "scal = $SCAL_0"  \
            -o $DETECTOR --!
 
        putFile.sh  $DETECTOR  $ARCHIVE  $DETECTOR_ID  $i0  $(($i1 - 1))  $TYPE  $VERSION
 
        if (( $? == 0 )); then
            rm -f  $DETECTOR
        else
            fatal "$DETECTOR not stored in archive $ARCHIVE."
        fi
 
        let "i0 = $i1"
    done
done