JShowerPostfit.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
# \author adomi
#
script=${0##*/}
 
# ------------------------------------------------------------------------------------------
#
#                         Utility script to plot fit results.
#
# ------------------------------------------------------------------------------------------
 
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
 
# list of applications in the processing chain
 
APPLICATIONS=(prefit pointsimplex positionfit directionprefit completefit)
 
set_variable:  DEBUG               RECONSTRUCTION_DEBUG               1
set_variable:  NUMBER_OF_EVENTS    RECONSTRUCTION_NUMBER_OF_EVENTS    $((2**31))
 
set_variable:  PALETTE             GRAPHICS_PALETTE                   57
set_variable:  FORMAT              GRAPHICS_FORMAT                    gif
set_variable+  BATCH               GRAPHICS_BATCH                     -B
 
set_variable   OPTION                                                 E
set_variable   MUONS                                                  ""
set_variable   WORKDIR                                                ./
     
if do_usage $*; then
    usage "$script <input file> [option [muons [working directory]]]\n" \
          "Where option can be N, E, LINE, LOGE.\n"                     \
          "Note that if more than one input file is specified, all other arguments must be provided."
fi
 
case $# in
    4) set_variable WORKDIR     $4;&
    3) set_variable MUONS       $3;&
    2) set_variable OPTION      $2;&
    1) set_array    INPUT_FILES $1;;
    0)  fatal "Wrong number of arguments";;    
    *) set_array    INPUT_FILES ${argv[1,-4]}
       set_variable OPTION      ${argv[-3]}
       set_variable MUONS       ${argv[-2]}
       set_variable WORKDIR     ${argv[-1]}
esac
 
 
# Number of prefits as a function of application (0 = all)
 
typeset -A NUMBER_OF_FIT
 
NUMBER_OF_FIT=(
    prefit            0
    pointsimplex      100 
    positionfit       1
    directionprefit   4
    completefit       1)
 
# Fit application identifier
 
typeset -A ENUMERATION
 
ENUMERATION=(
    prefit            101
    pointsimplex      106
    positionfit       102
    directionprefit   107
    completefit       103)
 
# user interaction
 
for APP in $APPLICATIONS[*]; do
 
    set_variable  OUTPUT_FILE    $WORKDIR/jshowerpostfit\[${APP}\].root
 
    if [[ -f $OUTPUT_FILE ]]; then
        rm -i $OUTPUT_FILE
    fi
done
 
 
# processing
 
for APP in $APPLICATIONS[*]; do
 
    set_variable  OUTPUT_FILE    $WORKDIR/jshowerpostfit\[${APP}\].root
 
    if [[ ! -f $OUTPUT_FILE ]]; then
 
        JShowerPostfit \
            -f "${INPUT_FILES[*]}"        \
            -o $OUTPUT_FILE               \
            -n ${NUMBER_OF_EVENTS}        \
            -N ${NUMBER_OF_FIT[${APP}]}   \
            -A ${ENUMERATION[${APP}]}     \
            -O ${OPTION}                  \
            ${${MUONS:+-I}:--w}           \
            -d ${DEBUG} --!
    fi 
done
 
 
if (( 1 )); then
 
    JPlot1D \
        -f $WORKDIR/jshowerpostfit\[prefit\].root:hd \
        -f $WORKDIR/jshowerpostfit\[pointsimplex\].root:hd     \
        -f $WORKDIR/jshowerpostfit\[positionfit\].root:hd     \
        -> "position wrt selected fermion [m]"                \
        -\^ "number of events [a.u.]"                         \
        -L TR -T ""                                           \
        -o $WORKDIR/position.$FORMAT                             $BATCH
 
    JPlot1D \
        -f $WORKDIR/jshowerpostfit\[directionprefit\].root:ha \
        -f $WORKDIR/jshowerpostfit\[completefit\].root:ha     \
        -> "angle wrt selected fermion [deg]"                \
        -\^ "number of events [a.u.]"                         \
        -L TR -T ""                                           \
        -o $WORKDIR/angle.$FORMAT                           $BATCH
 
    
fi
 
 
if (( 1 )); then
 
    QUANTILES="0.33 0.5 0.66"
    
    for APP in prefit pointsimplex positionfit; do
        JQuantiles2D \
            -f $WORKDIR/jshowerpostfit\[${APP}\].root:h3  \
            -Q "$QUANTILES"                               \
            -o $WORKDIR/jshowerquantiles\[${APP}\].root
    done
    
    for APP in directionprefit completefit; do
 
        JQuantiles2D \
            -f $WORKDIR/jshowerpostfit\[${APP}\].root:h2  \
            -Q "$QUANTILES"                               \
            -o $WORKDIR/jshowerquantiles\[${APP}\].root
    done
 
    JPlot1D \
        -f $WORKDIR/jshowerquantiles\[prefit\].root:h31       \
        -f $WORKDIR/jshowerquantiles\[pointsimplex\].root:31 \
        -f $WORKDIR/jshowerquantiles\[positionfit\].root:h31  \
        -> "E[GeV]"                                \
        -\^ "resolution (reco jshower) [deg]"             \
        -y "1 1e2"                                  \
        -XX                                          \
        -Y                                             \
        -L TR -T ""                                    \
        -o $WORKDIR/resolution_pos.$FORMAT                 $BATCH
     
    JPlot1D \
        -f $WORKDIR/jshowerquantiles\[directionprefit\].root:h21       \
        -f $WORKDIR/jshowerquantiles\[completefit\].root:h21      \
        -> "E[GeV]"                               \
        -\^ "resolution (reco jshower) [deg]"             \
        -y "1 1e2"                                  \
        -Y                                             \
        -XX                                            \
        -L TR -T ""                                    \
        -o $WORKDIR/resolution_angle.$FORMAT                 $BATCH
fi
 
 
if (( 1 )); then
 
    if [[ $OPTION =~ "LOG" ]]; then
        set_variable LOGX   -XX
        set_variable LOGY   -YY
    fi
 
    JPlot2D \
        -f $WORKDIR/jshowerpostfit\[completefit\].root:ee  \
        -O COLZ -p $PALETTE                                \
        $LOGX $LOGY -Z -T ""                               \
        -> "log E_{true} [GeV]"                               \
        -< "log E_{fit} [GeV]"                                \
        -o $WORKDIR/jshoweree.$FORMAT                      $BATCH
        
fi