examples/JDataFilter/JDataFilter.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
# \author rbruijn
#
script=${0##*/}
 
# ------------------------------------------------------------------------------------------
#
#         Example script to run JDataFilter and JDataWriter using JDQSimulator(s)
#
# ------------------------------------------------------------------------------------------
 
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
set_variable   DEBUG             2                                
set_variable   WORKDIR           ${TMPDIR:-/tmp}/                            
set_variable   IP_ADDRESS        `get_ip_address`                 
 
set_variable   MESSAGE_SERVER    localhost                        
set_variable   MESSAGE_LOGGER    localhost                        
 
set_variable   TIMEOUT_S         10                               
set_variable   RUNTIME_S         30                               
set_variable   PORT              5551                             
set_array      SOURCE_HOST       $IP_ADDRESS                      $IP_ADDRESS  $IP_ADDRESS
set_variable   FILTER_HOST       $IP_ADDRESS                      
set_variable   WRITER_HOST       $IP_ADDRESS                      
set_variable   DATAFILTER        F001/F001                        
set_variable   DATAWRITER        W000/W000                        
set_variable   SINGLESRATE_HZ    0e3                              
set_variable   DOUBLESRATE_HZ    2e3                              
set_variable   NUMBER_OF_SLICES  10                               
 
set_variable   DETECTOR          $JPP_DATA/km3net_reference.detx  
set_variable   LOGGER_OUTPUT     $WORKDIR/logger.txt              
 
if do_usage $*; then
    usage "$script [detector file [logger file [working directory]]]"
fi
 
case $# in
    3) set_variable WORKDIR       $3;&
    2) set_variable LOGGER_OUTPUT $2;&
    1) set_variable DETECTOR      $1;;
    0) ;;
    *) fatal "Wrong number of arguments."
esac
 
set_variable  ID                   `JPrintDetector -a $JPP_DATA/km3net_reference.detx -O identifier | sed 's/Detector//'`
set_variable  RUN                  1001
 
typeset -Z 8  ID
typeset -Z 8  RUN
 
set_variable  INPUT_FILE           $WORKDIR/timeslice.root
set_variable  OUTPUT_FILE          $WORKDIR/KM3NeT_${ID}_${RUN}.root
 
 
# Create detector
 
if [[ ! -f $DETECTOR ]]; then
    JDetector.sh $DETECTOR
fi
 
 
# Create input data
 
if ( ! reuse_file $INPUT_FILE ); then
 
    JRandomTimesliceWriter \
        -a $DETECTOR                           \
        -o $INPUT_FILE                         \
        -B "$SINGLESRATE_HZ $DOUBLESRATE_HZ"   \
        -n $NUMBER_OF_SLICES                   \
        -d1 --!
fi
 
 
# Remove output data
 
if [[ -f $OUTPUT_FILE ]]; then;
    rm -i $OUTPUT_FILE
fi
 
 
set_variable  DQ_SIMULATOR               JDQSimulator
set_variable  NUMBER_OF_DQ_SIMULATORS    ${#SOURCE_HOST}
set_variable  NUMBER_OF_FRAMES           `JPrintDetector -a $DETECTOR -O modules | awk '/Module/ {if ($4 != 0) {print $0}}' | wc -l`
 
 
# JDataFilter configure data
 
cat>$WORKDIR/ev_configure_datafilter.txt<<EOF
logger_s               = 5;
update_s               = 10;
dataWriter             = ${WRITER_HOST};
numberOfFramesPerSlice = ${NUMBER_OF_FRAMES};
detector               = %<${DETECTOR}>%;
triggerParameters      = trigger3DMuon.enabled   = 1;
triggerParameters      = trigger3DShower.enabled = 1;
triggerParameters      = writeSummary            = 1;
triggerParameters      = writeSN                 = 1;
triggerParameters      = SN.numberOfHits = 4; SN.TMaxLocal_ns = 10.0; SN.ctMin = 0.0;
c_sizeL1               = 10;
queueSize              = 100000000;
path                   = $WORKDIR;
JDataFilter            = ${DATAFILTER} ${FILTER_HOST}:${PORT};
JDataWriter            = ${DATAWRITER} ${WRITER_HOST};
EOF
 
# JDQSimulator configure data.
 
cat>$WORKDIR/ev_configure_dqsimulator.txt<<EOF
numberOfFrames         = ${NUMBER_OF_FRAMES};
numberOfEvents         = 1;
inputFile              = ${INPUT_FILE};
target                 = 0 ${FILTER_HOST}:${PORT};
EOF
 
 
# Driver input.
 
rm -f $WORKDIR/driver.txt
 
for (( i = 1; $i <= $NUMBER_OF_DQ_SIMULATORS ; ++i )); do
 
    let "index = ${#SOURCE_HOST}  -  $i % ${#SOURCE_HOST}"
 
    echo "source = 0 $DQ_SIMULATOR/$i;"                           >> $WORKDIR/ev_configure_dqsimulator.txt
    
    echo "process  $DQ_SIMULATOR/$i  $SOURCE_HOST[$index]         \
        (setenv ROOTSYS $ROOTSYS && source $JPP_DIR/setenv.csh $JPP_DIR && ($DQ_SIMULATOR     \
        -u \$NAME\$     \
        -H \$SERVER\$   \
        -M \$LOGGER\$   \
        -d $DEBUG       \
        </dev/null >&/dev/null &));"                               >> $WORKDIR/driver.txt
done
 
let "HALF_RUNTIME_S = ${RUNTIME_S} / 2 + 1"
 
cat>>$WORKDIR/driver.txt<<EOF
 
process  ${DATAFILTER}  $FILTER_HOST  ssh $FILTER_HOST  "(setenv ROOTSYS $ROOTSYS && source $JPP_DIR/setenv.csh $JPP_DIR && (JDataFilter  -H \$SERVER\$  -M \$LOGGER\$  -d $DEBUG  -u ${DATAFILTER}  -P $PORT  </dev/null >&/dev/null &))";
process  ${DATAWRITER}  $WRITER_HOST  ssh $FILTER_HOST  "(setenv ROOTSYS $ROOTSYS && source $JPP_DIR/setenv.csh $JPP_DIR && (JDataWriter  -H \$SERVER\$  -M \$LOGGER\$  -d $DEBUG  -u ${DATAWRITER}            </dev/null >&/dev/null &))";
 
print
 
enter
 
event ev_init      { RC_CMD }
 
event ev_configure { 
    RC_DFLTR  %<$WORKDIR/ev_configure_datafilter.txt>%
    RC_DQSIM  %<$WORKDIR/ev_configure_dqsimulator.txt>% 
    RC_DWRT   path=$WORKDIR;  update_s=10;  logger_s=5;
}
 
event ev_start     { RC_CMD  $RUN  $ID }
 
sleep $HALF_RUNTIME_S
message RC_ALRT Test;
sleep $HALF_RUNTIME_S
 
event ev_pause     { RC_CMD }
event ev_stop      { RC_CMD }
event ev_reset     { RC_CMD }
event ev_off       { RC_CMD }
 
EOF
 
 
JLigier.sh $MESSAGE_SERVER continue
JLigier.sh $MESSAGE_LOGGER continue
JLigier.sh $WRITER_HOST    continue
 
 
if [[ -n "$LOGGER_OUTPUT" ]]; then
    JLogger.sh $MESSAGE_LOGGER $LOGGER_OUTPUT
fi
 
 
# Go!
 
JDAQDriver \
    -H $MESSAGE_SERVER        \
    -M $MESSAGE_LOGGER        \
    -t $TIMEOUT_S             \
    -f $WORKDIR/driver.txt    \
    -d $DEBUG                 \
    -c
 
 
# Tests
 
JPrintTree \
    -f $OUTPUT_FILE
 
 
# Clean
 
JStopDAQ.sh $MESSAGE_SERVER $MESSAGE_LOGGER
 
 
ssh $WRITER_HOST "killall JDataWriter"
ssh $FILTER_HOST "killall JDataFilter"
killall JDQSimulator