examples/JCompass/JAHRSMonitor.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
#
# \author mdejong
#
version=1.0
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
zmodload zsh/mathfunc
 
set_variable:  DEBUG       COMPASS_DEBUG                2
set_variable:  WORKDIR     COMPASS_WORKDIR              ./
set_variable:  ZMIN        COMPASS_ZMIN                 1000
set_variable:  ZMAX        COMPASS_ZMAX                 0
set_variable   DIR         $JPP_DIR/examples/JCompass/
set_variable:  FORMAT      GRAPHICS_FORMAT        gif
set_variable+  BATCH       GRAPHICS_BATCH         -B
 
if do_usage $*; then
    usage "$script <detector file> (run[-run])+"\
          "\nAuxiliary script to download acoustic data from database and to process them through the event builder."
fi
 
if (( $# > 1 )); then
    set_variable  DETECTOR        $argv[1]
    set_array     RUNS            $argv[2,-1]
else
    fatal "Wrong number of arguments."
fi
 
set_variable     AHRS_CALIBRATION_FILE   $WORKDIR/ahrs_calibration.txt
 
eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`
 
 
if [[ ! -f $AHRS_CALIBRATION_FILE ]]; then
 
    JAHRSCalibration \
        -D $DETECTOR_ID                \
        -o $AHRS_CALIBRATION_FILE      \
        -d $DEBUG
fi
 
expand_array  RUNS
 
for RUN in $RUNS[*]; do
 
    set_variable  INPUT_FILE   $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_ahrs.root
 
    if [[ ! -f $INPUT_FILE ]]; then
 
        echo -n "Writing $INPUT_FILE... "
    
        JConvertDB \
            -q "ahrs"                      \
            -@ "detid  = $DETECTOR_ID"     \
            -@ "minrun = $RUN"             \
            -@ "maxrun = $RUN"             \
            -o $INPUT_FILE                 \
            -d $DEBUG --!
 
        if (( $? == 0 )); then
            echo "OK"
        else
            echo "no data"
        fi
    fi
 
    $DIR/JAHRSMonitor \
        -a $DETECTOR                                \
        -c $AHRS_CALIBRATION_FILE                   \
        -f $INPUT_FILE                              \
        -o $WORKDIR/monitor.root                    \
        -d $DEBUG --!
 
    JPlot2D \
        -f $WORKDIR/monitor.root:detector           \
        -> "string"                                \
        -< "floor"                                 \
        -z "$ZMIN $ZMAX"                            \
        -O COLZ                                     \
        -T "$RUN"                                   \
        -o  ${TMPDIR:-/tmp}/AHRS_$RUN.$FORMAT       $BATCH
done
 
INPUT_FILES=(${TMPDIR:-/tmp}/AHRS_${^RUNS}.$FORMAT)
 
typeset -i NX
typeset -i NY
 
let "NY = sqrt(${#INPUT_FILES}) * 0.75 + 0.25"
let "NX = (${#INPUT_FILES} + $NY - 1)/ $NY"
 
montage \
    -tile ${NX}x${NY}           \
    -geometry +0+0              \
    $INPUT_FILES                \
    $WORKDIR/AHRS.$FORMAT       >& /dev/null