pre-calibration_D_ORCA006.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
script=${0##*/}
 
# --------------------------------------------------------------------------------------------
#
# Steering script for the global-fit-of-global-fits procedure of the D_ORCA006 (49) detector.
#
# --------------------------------------------------------------------------------------------
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable  DETECTOR_ID            49
set_array     RUNS                   7600 7700 7800 7900 8000 8100 8200
set_variable: THREADS                ACOUSTICS_THREADS       5
set_variable  SINGULARITY            -
set_variable  WORKDIR                `pwd`
set_variable  HOMEDIR                $WORKDIR
 
if do_usage $*; then
    usage "$script [user directory]"\
          "\nThe user directory should be specified when this script is submitted in a batch queue."
fi
 
case $# in
    1)  set_variable HOMEDIR              $1;;
    0)  ;;
    *)  fatal "Wrong number of arguments."
esac
 
source JAcousticsToolkit.sh
 
set_variable  DETECTOR_INITIAL       detector_initial.datx
set_variable  TRIPOD_INITIAL         tripod_initial.txt
expand_array  RUNS
 
 
# Run in HOMEDIR
 
mkdir -p $HOMEDIR
cd       $HOMEDIR
 
JDetectorDB \
    -D $DETECTOR_ID       \
    -r $RUNS[1]           \
    -WW                   \
    -o $DETECTOR_INITIAL
 
cat>$TRIPOD_INITIAL<<EOF
# Data are from V. Bertin, private communications.
1  256877.5  4743716.7  -2438.4
2  256815.5  4743395.0  -2435.5
3  257096.2  4743636.0  -2439.5
EOF
 
# Apply modifications.
 
JEditDetector \
    -a $DETECTOR_INITIAL     \
    -s "-1 addz -6.9"        \
    -o detector.datx --!
 
eval `JPrintDetector -a detector.datx -O SUMMARY`
 
for STRING in ${STRINGS[*]}; do
 
    set_variable  MODULE  `getModule -a detector.datx -L "$STRING 0"`
 
    JEditDetector \
            -a detector.datx         \
            -M "$MODULE setz -2.9"   \
            -o detector.datx --!
done
 
cp -p  $TRIPOD_INITIAL  tripod.txt
 
cat>waveform.txt<<EOF
# waveform identifier; emitter identifier
 12   1
-13   1
 14   2
-15   2
 16   3
-17   3
EOF
 
cat>acoustics_trigger_parameters.txt<<EOF
Q             = 0.0;
TMax_s        = 0.020;
numberOfHits  = 90;
EOF
 
cat>disable.txt<<EOF
# disable transmissions
# $214a44c8-fb8c-490a-920e-41897730822a$
# GIT 18.3.0-305-g4e82b04f4-D
# ROOT 6.30/02
# application JEditDisable
# command /data1/dejong/km3net/GIT/Jpp/out//Linux/bin//JEditDisable -f disable.log -o disable.log -a detector.datx -q -d 2 --!
# namespace KM3NET
# system Linux verster.lorentz.leidenuniv.nl 6.6.8-200.fc39.x86_64 #1 SMP PREEMPT_DYNAMIC Thu Dec 21 04:01:49 UTC 2023 x86_64
1 808971812
1 809521500
2 808472260
2 808966194
2 808976219
2 808977319
2 808978694
3 808966194
EOF
 
cat>transmitter.txt<<EOF
# $script
EOF
 
cat>hydrophone.txt<<EOF
# Data from D_ORCA006_hydrophones.csv
   1 -1  -0.93   0.46   0.55
   2  0   0.02   1.04   0.55
   3  0   0.46   0.93   0.55
   9  0  -0.75  -0.72   0.55
  10 -1   0.11   1.04   0.55
  11 -1   0.54   0.89   0.55
EOF
 
JAcousticsEventBuilder.sh  detector.datx  $RUNS[*]
 
INPUT_FILES=(`ls KM3NeT_${(l:8::0::0:)DETECTOR_ID}_0*${^RUNS}_event.root`)
 
 
# Run in WORKDIR
 
cd  $WORKDIR
 
if [ ! $HOMEDIR -ef $WORKDIR ]; then
    cp -p $HOMEDIR/$ACOUSTICS_DETECTOR     $WORKDIR
    cp -p $HOMEDIR/${^ACOUSTICS_KEYS}.txt  $WORKDIR
    cp -p $HOMEDIR/${^ACOUSTICS_AUXS}.txt  $WORKDIR
    cp -p $HOMEDIR/${^INPUT_FILES}         $WORKDIR
fi
 
cat>script.txt<<EOF
stage  1b  ${SINGULARITY}1  0  100.0e-6  10.0   0  0.001  0.1
stage  2a  ${SINGULARITY}1  0  100.0e-6  10.0  20  0.2    0.5
stage  2c  ${SINGULARITY}1  0  100.0e-6  10.0  20  0.2       
stage  3a  ${SINGULARITY}1  0   50.0e-6  10.0  20  0.2    0.5
stage  3c  ${SINGULARITY}1  0   50.0e-6  10.0  20  0.2       
EOF
 
JSydney.sh  detector.datx  $INPUT_FILES[*]  script.txt
 
if [ ! $HOMEDIR -ef $WORKDIR ]; then
    cp -vru * $HOMEDIR
fi