pre-calibration_D0ORCA018.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
script=${0##*/}
 
# --------------------------------------------------------------------------------------------
#
# Steering script for the global-fit-of-global-fits procedure of the D0ORCA018 (148) detector.
#
# --------------------------------------------------------------------------------------------
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable  DETECTOR_ID            148
set_array     RUNS                   16662-16668
set_variable: THREADS                ACOUSTICS_THREADS       5
set_variable  SINGULARITY            -
set_variable  WORKDIR                `pwd`
set_variable  HOMEDIR                $WORKDIR
 
if do_usage $*; then
    usage "$script <source directory> [user directory]"\
              "\nThe source directory corresponds to a pre-calibrated D1ORCA015 detector."\
          "\nThe user directory should be specified when this script is submitted in a batch queue."
fi
 
case $# in
    2)  set_variable HOMEDIR              $2;&
    1)  set_variable DIR                  ${1:a};;
    *)  fatal "Wrong number of arguments."
esac
 
source JAcousticsToolkit.sh
 
set_variable  DETECTOR               $DIR/detector.datx
set_variable  TRIPOD                 $DIR/tripod.txt
set_variable  DETECTOR_INITIAL       detector_initial.datx
set_variable  TRIPOD_INITIAL         tripod_initial.txt
expand_array  RUNS
 
 
# Run in HOMEDIR
 
mkdir -p $HOMEDIR
cd       $HOMEDIR
 
JDetectorDB \
    -D $DETECTOR_ID       \
    -r $RUNS[1]           \
    -WW                   \
    -o $DETECTOR_INITIAL
 
cat>$TRIPOD_INITIAL<<EOF
# position of emitter 5 taken from https://elog.km3net.de/Operations+FR/8271 (RAB1v2)
# position of emitter 6 taken from https://elog.km3net.de/Operations+FR/8731 (RAB2)
# position of emitter 8 taken from https://elog.km3net.de/Operations+FR/9603 (RAB3)
5  +257040.800 +4743317.600 -2439.900 
6  +256807.500 +4743636.500 -2442.500
8  +257118.100 +4743781.100 -2440.300
EOF
 
JEditDetector \
    -a $DETECTOR           \
    -o detector_tmp.datx --!
 
eval `JPrintDetector -a $DETECTOR_INITIAL -O SUMMARY`;  FINAL_STRINGS=($STRINGS[*])
eval `JPrintDetector -a detector_tmp.datx -O SUMMARY`;  FIXED_STRINGS=($STRINGS[*])
 
# Apply modifications.
 
JEditDetector \
    -a $DETECTOR_INITIAL     \
    -o detector.datx --!
 
eval `JPrintDetector -a detector.datx -O SUMMARY`
 
for STRING in ${STRINGS[*]}; do
 
    set_variable  MODULE  `getModule -a detector.datx -L "$STRING 0"`
 
    JEditDetector \
            -a detector.datx         \
            -M "$MODULE setz -2.9"   \
            -o detector.datx --!
done
 
JEditDetector   -a detector.datx  -r "$FIXED_STRINGS[*]"  -o detector.datx --!
JMergeDetector  -a detector.datx  -a detector_tmp.datx    -o detector.datx --!
JEditDetector   -a detector.datx  -k "$FINAL_STRINGS[*]"  -o detector.datx --!
 
REMOVE_STRINGS=(27 28)
 
FINAL_STRINGS=(${FINAL_STRINGS:|REMOVE_STRINGS})
FIXED_STRINGS=(${FIXED_STRINGS:|REMOVE_STRINGS})
 
JEditDetector   -a detector.datx  -r "$REMOVE_STRINGS[*]"  -o detector.datx --!
 
typeset -A TRIPODS
 
get_tripods  $TRIPOD_INITIAL  TRIPODS;  FINAL_TRIPODS=(${(k)TRIPODS[*]})
get_tripods  $TRIPOD          TRIPODS;  FIXED_TRIPODS=(${(k)TRIPODS[*]})
 
cp -p  $TRIPOD_INITIAL  tripod.txt
 
JEditTripod   -f tripod.txt  -r "${FIXED_TRIPODS}" -o tripod.txt
JMergeTripod  -f tripod.txt  -f $TRIPOD            -o tripod.txt
JEditTripod   -f tripod.txt  -k "${FINAL_TRIPODS}" -o tripod.txt
 
cat>waveform.txt<<EOF
# waveform identifier; emitter identifier
 23   5
-24   5
 28   6
-29   6
 16   8
-17   8
 31   9
-32   9
EOF
 
cat>acoustics_trigger_parameters.txt<<EOF
Q             = 0.0;
TMax_s        = 0.015;
numberOfHits  = 210;
EOF
 
cat>disable.txt<<EOF
# disable transmissions
# $20fac36a-495b-4b25-b814-9f297c3db1da$
# GIT 18.3.0-305-g4e82b04f4-D
# ROOT 6.30/02
# application JEditDisable
# command /data1/dejong/km3net/GIT/Jpp/out//Linux/bin//JEditDisable -f disable.log -o disable.log -a detector.datx -q -d 2 --!
# namespace KM3NET
# system Linux verster.lorentz.leidenuniv.nl 6.6.8-200.fc39.x86_64 #1 SMP PREEMPT_DYNAMIC Thu Dec 21 04:01:49 UTC 2023 x86_64
1 809521500
2 808472260
2 808966194
2 808977319
3 808966194
3 813553576
5 806487231
5 808978694
6 817329086
8 806483369
8 806487231
8 808964883
8 817338744
EOF
 
cat>transmitter.txt<<EOF
# Data from D0ORCA018_baseAcousticBeacon.csv
 9   27  0  -0.74  -0.64   0.71
EOF
 
cat>hydrophone.txt<<EOF
# Data from D0ORCA018_hydrophones.csv
   1 -1  -0.93   0.46   0.55
   2  0   0.02   1.04   0.55
   3  0   0.46   0.93   0.55
   9  0  -0.75  -0.72   0.55
  10 -1   0.11   1.04   0.55
  12  0   0.46   0.93   0.55
   4  0   0.20   1.02   0.55
  18  0   0.61   0.84   0.55
  28  0   0.69   0.78   0.55
  11  0  -0.07   1.04   0.55
  19  0   0.46   0.93   0.55
  20  0   0.61   0.84   0.55
  29  0   0.46   0.93   0.55
  30  0   0.46   0.93   0.55
  21  0   0.11   1.04   0.55
  17  0   0.46   0.93   0.55
  27  0   1.04   0.07   0.55
  31  0   0.75   0.72   0.55
EOF
 
JAcousticsEventBuilder.sh  detector.datx  $RUNS[*]
 
INPUT_FILES=(`ls KM3NeT_${(l:8::0::0:)DETECTOR_ID}_0*${^RUNS}_event.root`)
 
 
# Run in WORKDIR
 
cd  $WORKDIR
 
if [ ! $HOMEDIR -ef $WORKDIR ]; then
    cp -p $HOMEDIR/$ACOUSTICS_DETECTOR     $WORKDIR
    cp -p $HOMEDIR/${^ACOUSTICS_KEYS}.txt  $WORKDIR
    cp -p $HOMEDIR/${^ACOUSTICS_AUXS}.txt  $WORKDIR
    cp -p $HOMEDIR/${^INPUT_FILES}         $WORKDIR
fi
 
cat>script.txt<<EOF
 
fix  string  $FIXED_STRINGS[*]
fix  tripod  $FIXED_TRIPODS[*]
 
stage  1B  ${SINGULARITY}1  0  100.0e-6  10.0   0  0.001  0.1
stage  2A  ${SINGULARITY}1  0  100.0e-6  10.0  20  0.2    0.5
stage  2C  ${SINGULARITY}1  0  100.0e-6  10.0  20  0.2       
 
initialise
 
stage  2a  ${SINGULARITY}1  0  100.0e-6  10.0  20  0.2    0.5
stage  2c  ${SINGULARITY}1  0  100.0e-6  10.0  20  0.2       
stage  3a  ${SINGULARITY}1  0   50.0e-6  10.0  20  0.2    0.5
stage  3c  ${SINGULARITY}1  0   50.0e-6  10.0  20  0.2       
EOF
 
JSydney.sh  detector.datx  $INPUT_FILES[*]  script.txt
 
if [ ! $HOMEDIR -ef $WORKDIR ]; then
    cp -vru * $HOMEDIR
fi