JCalibratePMT.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
# \author rgruiz, mdejong
#
script=${0##*/}
 
# ------------------------------------------------------------------------------------------
#
#                         Script to run complete PMT calibration.
#
# ------------------------------------------------------------------------------------------
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
set_variable:  WORKDIR           CALIBRATION_WORKDIR           ./
set_variable:  DEBUG             CALIBRATION_DEBUG             2
set_variable+  OPTION            CALIBRATION_OPTION            -A
set_variable+  ANGLE_DEPENDENCE  CALIBRATION_ANGLE_DEPENDENCE  -D
set_variable+  NOISE_DEPENDENCE  CALIBRATION_NOISE_DEPENDENCE  -B
set_variable:  TEROSTAT_R1       CALIBRATION_TEROSTAT_R1       1.0
set_variable:  BELL_SHAPE        CALIBRATION_BELL_SHAPE        1.55
set_variable:  QE_MAX            CALIBRATION_QEMAX             2.0
set_variable:  MU                CALIBRATION_MU                0.205644
set_variable:  TOT_MIN_NS        CALIBRATION_TOT_MIN_NS        0.0
set_variable:  TOT_MAX_NS        CALIBRATION_TOT_MAX_NS        35.0
set_variable:  NOMINAL_QE        CALIBRATION_NOMINAL_QE        0.93
 
if do_usage $*; then
    usage "$script <detector_file> (input file)+ <PMT parameters file>"
fi
 
if (( $# < 3 )); then
    fatal "Wrong number of arguments."
fi 
 
set_variable   DETECTOR          $argv[1]
set_array      INPUT_FILES       $argv[2,-2]
set_variable   PMT_FILE          $argv[-1]
 
if [[ ! -d $WORKDIR ]]; then     
    mkdir -p $WORKDIR
fi
 
JCookie.sh
 
eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`
eval `JPrintDetector -a $DETECTOR -O SUMMARY`
 
debug "$DETECTOR $DETECTOR_ID"
 
if [[ "$DETECTOR_ID" != [1-9][0-9]* ]]; then
    fatal "Invalid detector identifier \"$DETECTOR_ID\"."
fi
 
# evaluate inputs
 
set_variable   RUNSETUPID
typeset -a     RANGE
 
RANGE[1]=99999999
RANGE[2]=0
 
for INPUT_FILE in $INPUT_FILES[*]; do
 
    JPrintDAQHeader  -f $INPUT_FILE  |  read ID RUN FRAME_INDEX UTC    
 
    if (( $DETECTOR_ID != $ID )); then
            fatal "Inconsistent detector identifier $DETECTOR_ID != $ID."
    fi
 
    JRuns  -D $DETECTOR_ID  -@ "RUN = $RUN"  -F RUNSETUPID  |  read SETUP
 
    debug "Run $RUN -> $SETUP."
 
    if (( $RUN < $RANGE[1] )); then; RANGE[1]=$RUN; fi
    if (( $RUN > $RANGE[2] )); then; RANGE[2]=$RUN; fi
 
    if [[ -z "$SETUP" ]]; then
            fatal "Missing setup identifier for run $RUN."
    fi
    if [[ -n "$RUNSETUPID" && $RUNSETUPID != $SETUP ]]; then
            fatal "Inconsistent run setup identifiers $RUNSETUPID != $SETUP $RUN."
    fi
 
    set_variable   RUNSETUPID  $SETUP
done
 
 
# data selection
 
for DAQ_TIMESLICE in JDAQTimesliceL1 JDAQTimeslice; do
 
    VALUES=(`JPrintTree -f${^INPUT_FILES} -@ "type = ${DAQ_TIMESLICE}" -k number_of_entries`)
    
    if [[ -n "$VALUES" ]] && (( ${#VALUES} == ${#INPUT_FILES} )); then
            break
    fi
done
 
if [[ -z "$VALUES" ]] || (( ${#VALUES} != ${#INPUT_FILES} )); then
    fatal "No valid data in input file(s)."
fi
 
 
# PMT threshold
 
JPMTThreshold \
    -D $DETECTOR_ID        \
    -r $RANGE[1]           \
    -P $PMT_FILE           \
    --!
 
 
# PMT TTS function
 
JPMTTTS \
    -D $DETECTOR_ID        \
    -P $PMT_FILE           \
    --!
 
 
# PMT gain and gain spread
 
set_variable  OUTPUT_FILE  $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RANGE[1]}-${(l:8::0::0:)RANGE[2]}_%.root
 
JCalibrateToT \
    -a $DETECTOR                              \
    -f${^INPUT_FILES}                         \
    -o ${OUTPUT_FILE/\%/calibratetot}         \
    -C $DAQ_TIMESLICE                         \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
JMergeCalibrateToT \
    -f ${OUTPUT_FILE/\%/calibratetot}         \
    -o ${OUTPUT_FILE/\%/mergetot}             \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
JFitToT \
    -a $DETECTOR                              \
    -f ${OUTPUT_FILE/\%/mergetot}             \
    -o ${OUTPUT_FILE/\%/fittot}               \
    -P $PMT_FILE                              \
    -w                                        \
    -x "$TOT_MIN_NS $TOT_MAX_NS"              \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
 
# PMT QE
 
JCalibrateK40 \
    -a $DETECTOR                              \
    -f${^INPUT_FILES}                         \
    -o ${OUTPUT_FILE/\%/calibratek40}         \
    -C $DAQ_TIMESLICE                         \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
JMergeCalibrateK40 \
    -f ${OUTPUT_FILE/\%/calibratek40}         \
    -o ${OUTPUT_FILE/\%/mergek40}             \
    -d $DEBUG --!
 
CHECK_EXIT_CODE
 
for STRING in $STRINGS; do
 
    JEditDetector \
        -a $DETECTOR                          \
        -k $STRING                            \
        -o detector.$STRING.datx
 
    JSelectPMTParameters \
        -P $PMT_FILE                          \
        -a detector.$STRING.datx              \
        -o PMT.$STRING.txt
 
    nohup JFitK40 \
        -@ "TEROSTAT_R1 = $TEROSTAT_R1"       \
        -@ "BELL_SHAPE  = $BELL_SHAPE"        \
        -a detector.$STRING.datx              \
        -f ${OUTPUT_FILE/\%/mergek40}         \
        -o ${OUTPUT_FILE/\%/fitk40.$STRING}   \
        -P PMT.$STRING.txt                    \
        -T "A B C D E F"                      \
        -X TR.$STRING.txt                     \
        -Q ${NOMINAL_QE}                      \
        -w                                    \
        $OPTION                               \
        $ANGLE_DEPENDENCE                     \
        $NOISE_DEPENDENCE                     \
        -d $DEBUG --!                         >& detector.$STRING.log &
 
done
 
wait
 
CHECK_EXIT_CODE
 
for STRING in $STRINGS; do
    nohup JFitK40 \
        -@ "TEROSTAT_R1 = $TEROSTAT_R1"       \
        -@ "BELL_SHAPE  = $BELL_SHAPE"        \
        -a detector.$STRING.datx              \
        -f ${OUTPUT_FILE/\%/mergek40}         \
        -o ${OUTPUT_FILE/\%/fitk40.$STRING}   \
        -P PMT.$STRING.txt                    \
        -X TR.$STRING.txt                     \
        -w                                    \
        $OPTION                               \
        $ANGLE_DEPENDENCE                     \
        $NOISE_DEPENDENCE                     \
        -d $DEBUG --!                         >>& detector.$STRING.log &
done
 
wait
 
CHECK_EXIT_CODE
 
cat detector.${^STRINGS}.log
 
JMergeDetector \
    -adetector.${^STRINGS}.datx               \
    -o $DETECTOR
 
JMergePMTParameters \
    -PPMT.${^STRINGS}.txt                     \
    -o $PMT_FILE
 
rm -f detector.${^STRINGS}.datx  >& /dev/null
rm -f detector.${^STRINGS}.log   >& /dev/null
rm -f PMT.${^STRINGS}.txt        >& /dev/null
 
# final corrections.
 
JEditPMTParameters \
    -P $PMT_FILE                              \
    -E $MU                                    \
    -T "$TOT_MIN_NS $TOT_MAX_NS"              \
    -Q "0.0 $QE_MAX"                          \
    -o $PMT_FILE                              \
    -d $DEBUG --!