plot-gradient.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
zmodload zsh/mathfunc
 
set_variable   DEBUG       2
set_variable   WORKDIR     ${TMPDIR:-/tmp}/
set_variable   OPTION      chi2
set_variable:  PRECISION   RECONSTRUCTION_PRECISION    0.1
set_variable:  PALETTE     GRAPHICS_PALETTE            57
set_variable:  FORMAT      GRAPHICS_FORMAT             gif
set_variable+  BATCH       GRAPHICS_BATCH              -B
 
if do_usage $*; then
    usage "$script <input file> [option]"\
          "\nThe input file corresponds to the log file of JGradient."\
          "\nThe option can be \"chi2\" or \"likelihood\"."
fi
 
case $# in
    2) set_variable  OPTION      $2;&
    1) set_variable  INPUT_FILE  $1;;
    *) fatal "Wrong number of arguments."
esac
 
typeset -A FACTOR
typeset -A LABEL
 
FACTOR[chi2]=1.0
FACTOR[likelihood]=-1.0
 
LABEL[chi2]="#chi^{2}"
LABEL[likelihood]="likelihood"
 
if [[ "$FACTOR[$OPTION]" == "" ]]; then
    fatal "Invalid option $OPTION."
fi
 
# gradient descent
 
grep "\‍(chi2\[.\]\|gradient\‍)" $INPUT_FILE  >  $WORKDIR/gradient.txt
 
if (( $? == 0 )); then
 
    awk -v UFO=$FACTOR[$OPTION] '/chi2\[.\]/ { printf "%5d %9.5f\n", NR, (UFO * $3) }'  $WORKDIR/gradient.txt  >  $WORKDIR/g1.txt
    awk -v UFO=$FACTOR[$OPTION] '/gradient/  { printf "%5d %9.5f\n", NR, (1.0 * $2) }'  $WORKDIR/gradient.txt  >  $WORKDIR/g2.txt
 
    JGraph \
            -f $WORKDIR/g1.txt                       \
            -o $WORKDIR/g1.root                      \
            -T $TITLE
 
    awk '\
    BEGIN { XMIN = +1.0e10; XMAX = -1.0e10; YMIN = +1.0e10; YMAX = -1.0e10 }   \
    END   { printf "%9.5f %9.5f %9.5f %9.5f", XMIN, XMAX, YMIN, YMAX }         \
    {                               \
    if ($1 < XMIN) { XMIN = $1 };   \
    if ($1 > XMAX) { XMAX = $1 };   \
    if ($2 < YMIN) { YMIN = $2 };   \
    if ($2 > YMAX) { YMAX = $2 };   \
    }'  $WORKDIR/g1.txt  |  read XMIN XMAX YMIN YMAX
 
    let "XMIN -= 1.0"
    let "XMAX += 1.0"
 
    let "Y    = $YMAX - $YMIN"
    let "YMAX = floor(($YMAX + 0.1 * ($Y)) / $PRECISION + 1.0) * $PRECISION"
    let "YMIN = floor(($YMIN - 0.1 * ($Y)) / $PRECISION - 0.0) * $PRECISION"
 
    awk \
            -v YMIN=$YMIN \
            -v YMAX=$YMAX \
            '/gradient/  { printf "%5d %9.5f %5d %9.5f\n", NR, YMIN, NR, YMAX }'  $WORKDIR/gradient.txt  >  $WORKDIR/L1.txt  
 
    JLine \
            -p $WORKDIR/L1.txt                       \
            -o $WORKDIR/L1.root                      \
            -@ "width = 1"                           \
            -@ "style = 2"                           
 
    JPlot1D \
            -w 1200x600                              \
            -f $WORKDIR/g1.root:\.\*                 \
            -f $WORKDIR/L1.root:\.\*                 \
            -> "step"                               \
            -\^ "$LABEL[$OPTION]"                    \
            -x "$XMIN $XMAX"                         \
            -y "$YMIN $YMAX"                         \
            -N "X 505"                               \
            -G Y                                     \
            -S 0.5                                   \
            -T "${${INPUT_FILE:t}:r}"                \
            -o $OPTION.$FORMAT                       $BATCH
 
    JGraph \
            -f $WORKDIR/g2.txt                       \
            -o $WORKDIR/g2.root                      \
            -T $TITLE
 
    awk 'BEGIN { YMAX = -1.0e10; YMIN = +1.0e10 } END { printf "%9.5f %9.5f", YMIN, YMAX} { if ($2 < YMIN) { YMIN = $2 }; if ($2 > YMAX) { YMAX = $2 }}'  $WORKDIR/g2.txt  |  read YMIN YMAX
 
    let "Y    = $YMAX - $YMIN"
    let "YMAX = floor(($YMAX + 0.1 * ($Y)) / $PRECISION + 1.0) * $PRECISION"
 
    if (( $YMIN > 0.0 )); then
        let "YMIN = 0.0"
    fi
 
    JPlot1D \
            -w 1200x600                              \
            -f $WORKDIR/g2.root:\.\*                 \
            -> "step"                               \
            -\^ "|gradient|"                         \
            -x "$XMIN $XMAX"                         \
            -y "$YMIN $YMAX"                         \
            -N "X 505"                               \
            -G Y                                     \
            -S 0.5                                   \
            -T "${${INPUT_FILE:t}:r}"                \
            -o  gradient.$FORMAT                     $BATCH
 
    rm -f $WORKDIR/gradient.txt $WORKDIR/{g1,g2,L1}.{txt,root}
 
fi
 
 
# 2D scans
 
COLS=(`sed -n 's/scan://p' $INPUT_FILE`)
 
if (( ${#COLS} != 0 )); then
 
    # minimal chi2
 
    awk 'BEGIN { ZMIN = 1.0e10 } END { printf "%9.5f", ZMIN } /scan:/,EOF { if ($NF < ZMIN) { ZMIN= $NF } }'  $INPUT_FILE  |  read  ZMIN
 
    #
    # plot 2D-histogram
    #
    # \param 1   first  column
    # \param 2   second column
    #
    function plot()
    {
        C1=$1
        C2=$2
 
        awk \
            -v C1=$C1                    \
            -v C2=$C2                    \
            -v ZMIN=$ZMIN                \
            '\
    \
    function ufo()                                    \
    {                                                 \
      for (i = 1; i != NF; ++i) {                     \
         if (i != C1 && i != C2 && $i != 0.0) {       \
            return 0                                  \
         }                                            \
      }                                               \
      return 1                                        \
    }                                                 \
    \
    /scan:/,EOF { if (ufo()) { printf "%9.5f %9.5f %9.5f\n", $C1, $C2, $NF - ZMIN } }'  $INPUT_FILE   >  g2.txt
 
        JGraph2D \
            -f g2.txt                    \
            -o g2.root
 
         JPlot2D \
            -f  g2.root:\.\*             \
            -O  colz                     \
            -> "$COLS[$1]"              \
            -< "$COLS[$2]"              \
            -\^ "#Delta#chi^{2}"         \
            -N  "X 505"                  \
            -N  "Y 505"                  \
            -p  $PALETTE                 \
            -T  ""                       \
            -o $COLS[$1]-$COLS[$2].gif
 
        rm -f g2.{txt,root}
    }
 
    # column pairs
 
    for (( C1 = 1; $C1 != ${#COLS}; C1 += 1 )); do
        for (( C2 = 1; $C2 != $C1; C2 += 1 )); do
            plot $C1 $C2
        done
    done
fi