JCompareDetector.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
# \author mdejong
#
script=${0##*/}
 
# ------------------------------------------------------------------------------------------
#
#          Utility script to compare two detectors and to create graphics output.
#
# ------------------------------------------------------------------------------------------
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null
 
set_variable   WORKDIR        ${TMPDIR:-/tmp}
set_variable   DEBUG          1
set_variable:  TIME           PRECISION_TIME          0.01    # [ns]
set_variable:  ANGLE          PRECISION_ANGLE         0.01    # [deg]
set_variable:  POSITION       PRECISION_POSITION      0.01    # [m]
set_variable:  ORIENTATION    PRECISION_ORIENTATION   0.01    # [rad]
set_variable:  FORMAT         GRAPHICS_FORMAT         gif
set_variable+  BATCH          GRAPHICS_BATCH          -B
 
if do_usage $*; then
    usage "$script <detector file>  <detector file> [<lower floor>-<upper floor>]"\
          "\nIf the range of floors is specified, the first detector file is aligned to the second before the comparison."\
          "\nIn this, only modules within the given range of floors are used."
fi
 
case $# in
    3) set_variable  RANGE          $argv[3];&
    2) set_array     DETECTOR       $argv[1] $argv[2];;
    *) fatal "Wrong number of arguments."
esac
 
if [[ "$RANGE" == [0-9]*"-"[0-9]* ]]; then
 
    JConvertDetectorFormat \
            -a $DETECTOR[1]                       \
            -o ${TMPDIR:-/tmp}/detector.datx      \
            -d $DEBUG
 
    echo "" > ${TMPDIR:-/tmp}/tripod.txt 
 
    JAlignDetector \
            -a ${TMPDIR:-/tmp}/detector.datx      \
            -b $DETECTOR[2]                       \
            -AO                                   \
            -r "${RANGE%%-*} ${RANGE##*-}"        \
            -T ${TMPDIR:-/tmp}/tripod.txt         \
            -d $DEBUG --!
 
    DETECTOR[1]=${TMPDIR:-/tmp}/detector.datx
 
    rm -f ${TMPDIR:-/tmp}/tripod.txt 
fi
 
JCompareDetector \
    -a $DETECTOR[1]                       \
    -b $DETECTOR[2]                       \
    -p "time        = $TIME"              \
    -p "angle       = $ANGLE"             \
    -p "position    = $POSITION"          \
    -p "orientation = $ORIENTATION"       \
    -o $WORKDIR/detector.root             \
    -d $DEBUG --!
 
typeset -A HISTOGRAMS
 
HISTOGRAMS[X2]="#Deltax [m]"
HISTOGRAMS[Y2]="#Deltay [m]"
HISTOGRAMS[Z2]="#Deltaz [m]"
HISTOGRAMS[T2]="#Deltat [ns]"
HISTOGRAMS[RMS]="RMS [ns]"
HISTOGRAMS[R2]="angle [rad]"
 
eval `JPrintDetector -a $DETECTOR[1] -O SUMMARY`
 
if (( ${#STRINGS} <= 15 )); then
    let "X = 600"
    let "Y = 600"
else
    let "X = 600 + 6 * (${#STRINGS} - 15)"
    let "Y = 600"
fi
 
for KEY VALUE in ${(@kv)HISTOGRAMS}; do
 
    JPlot2D \
        -w ${X}x${Y}                      \
            -f $WORKDIR/detector.root:${KEY}  \
            -> "string"                      \
            -< "floor"                       \
            -\^ "$VALUE"                      \
            -O COLZ                           \
            -T "$KEY"                         \
            -o ${KEY}.$FORMAT                 $BATCH
 
done
 
for KEY in Z X Y; do
 
    for (( i = 1; $i <= ${#STRINGS}; ++i )); do
 
            set_variable STRING  $STRINGS[$i] 
 
            echo "Processing string $STRING $KEY"
 
            let "XMIN = $i - 1 - 0.5"
            let "XMAX = $i - 1 + 0.5"
 
            JProject2D \
                -f $WORKDIR/detector.root:${KEY}2            \
                -P Y                                         \
                -x "$XMIN $XMAX"                             \
                -o ${TMPDIR:-/tmp}/py_\[${STRING}\].root     \
                -d 0
    done
 
    JPlot1D \
            -f${TMPDIR:-/tmp}/py_\[${^STRINGS}\].root:\.\*   \
            -> "floor"                                      \
            -\^ "#Delta${(L)KEY} [m]"                        \
            -x  "0.5 18.5"                                   \
            -y  "-10.0 +10.0"                                \
            -O "HIST ]["                                     \
            -CC                                              \
            -T  ""                                           \
            -L TR                                            \
            -o ${KEY}1.$FORMAT --!                           $BATCH
done