plot-PMTParameters1D.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
#
# \author mdejong
#
version=1.0
script=${0##*/}
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
zmodload zsh/mathfunc
 
set_variable   DEBUG           3                             
set_variable   WORKDIR         `pwd`                         
set_variable   OUTPUT_FILE     $WORKDIR/pmt_parameters.root  
set_variable   DIR             $JPP_DIR/examples/JDetector/  
set_variable:  FORMAT          GRAPHICS_FORMAT        gif
set_variable+  BATCH           GRAPHICS_BATCH         -B
 
if do_usage $*; then
    usage "$script <detector file> (PMT parameters file)+"
fi
 
if (( $# < 2 )); then
    fatal "Wrong number of parameters."
fi
 
set_variable     DETECTOR                $argv[1]
set_array        INPUT_FILES             $argv[2,-1]
 
$DIR/JPlotPMTParameters2D \
    -a  $DETECTOR       \
    -P "$INPUT_FILES"   \
    -o  $OUTPUT_FILE    \
    -d  $DEBUG -A --!
 
# parameters and plot ranges
 
typeset -A Y_RANGE
 
Y_RANGE+=(EFFICIENCY   " 0.0   1.5") 
Y_RANGE+=(QE           " 0.0   1.5") 
Y_RANGE+=(gain         " 0.0   1.5") 
Y_RANGE+=(gainSpread   " 0.0   1.0") 
Y_RANGE+=(riseTime_ns  " 0.0  15.0") 
Y_RANGE+=(TTS_ns       "-5.0  +5.0") 
Y_RANGE+=(threshold    " 0.0   1.0") 
Y_RANGE+=(slope        " 0.0  15.0") 
Y_RANGE+=(saturation   " 0.0 250.0") 
Y_RANGE+=(slewing      " 0.0   1.5") 
 
eval `JPrintDetector -a $DETECTOR -O SUMMARY`
 
set_variable  FIRST_FLOOR  1
 
typeset -Z 4 STRING
typeset -Z 2 FLOOR
 
PMT_RANGE="0-30"
 
for STRING in $STRINGS[*]; do
 
    for KEY in ${(k)Y_RANGE}; do
 
        unset HISTOGRAMS
 
        typeset -a HISTOGRAMS
 
        for (( FLOOR = $FIRST_FLOOR; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do
 
            eval MODULE=\${STRING_${(l:4::0::0:)STRING}\[$(($FLOOR))\]:--1}
 
            debug "($STRING,$FLOOR) $KEY"
 
            HISTOGRAMS+=${OUTPUT_FILE}:${MODULE}\.${KEY}\$
        done
 
        let "YMIN = ${PMT_RANGE%%-*} - 0.5"
        let "YMAX = ${PMT_RANGE##*-} + 0.5"
 
        JProject2D \
            -f "${HISTOGRAMS[*]}"                                    \
            -P X -y "$YMIN $YMAX"                                    \
            -o ${TMPDIR:-/tmp}/project.root                          
 
        JScale1D \
            -f ${TMPDIR:-/tmp}/project.root:\.\*                     \
            -o ${TMPDIR:-/tmp}/scale.root                            \
            -F "1.0 / ($YMAX - $YMIN)"                               \
            -O "nosw2"                                               
        
        JPlot1D \
            -f ${TMPDIR:-/tmp}/scale.root:\.\*                       \
            -y $Y_RANGE[${KEY}]                                      \
            -> "index"                                              \
            -\^ "<$KEY>"                                             \
        -G Y                                                     \
            -T "(${STRING})"                                         \
            -o P_${KEY}_${STRING}.$FORMAT                            $BATCH
    done
done
 
typeset -i NX
typeset -i NY
 
let "NY = sqrt(${#STRINGS}) * 0.75 + 0.25"
let "NX = (${#STRINGS} + $NY - 1)/ $NY"
 
for KEY in ${(k)Y_RANGE}; do
 
    montage \
        -tile ${NX}x${NY}                                        \
        -geometry +0+0                                           \
        P_${KEY}_${^${(l:4::0::0:)STRINGS}}.$FORMAT              \
        P_${KEY}.$FORMAT                                         #>& /dev/null
done