software/JCalibrate/JHobbit.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
# \author mdejong
#
script=${0##*/}
 
# ------------------------------------------------------------------------------------------
#
#                         Script to run JHobbit and plot results.
#
# ------------------------------------------------------------------------------------------
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
zmodload zsh/mathfunc
 
set_variable   DEBUG        2
set_variable   WORKDIR      ./
set_variable:  OPTION       CALIBRATION_OPTION      module  # string
set_variable:  FITRANGE     CALIBRATION_FITRANGE    -7.5 +5.0
set_variable:  FUNCTION     CALIBRATION_FUNCTION    Gauss
set_variable:  PALETTE      GRAPHICS_PALETTE        57
set_variable:  FORMAT       GRAPHICS_FORMAT         gif
set_variable+  BATCH        GRAPHICS_BATCH          -B
 
if do_usage $*; then
    usage "$script <detector file> (input file)+"
fi
 
if (( $# < 2 )); then
    fatal "Wrong number of arguments."
fi
 
set_variable DETECTOR        $argv[1]
set_variable INPUT_FILES     $argv[2,-1]
 
JHobbit \
    -a $DETECTOR                       \
    -f${^INPUT_FILES}                  \
    -o $WORKDIR/hobbit_${OPTION}.root  \
    -F $FUNCTION                       \
    -O L                               \
    -E "0.0 1.0"                       \
    -T "$FITRANGE"                     \
    -R $OPTION                         \
    -d $DEBUG --!
 
eval `JPrintDetector -a $DETECTOR -O SUMMARY`
 
if (( ${#STRINGS} <= 15 )); then
    let "X = 600"
    let "Y = 600"
else
    let "X = 600 + 6 * (${#STRINGS} - 15)"
    let "Y = 600"
fi
 
JPlot1D \
    -w ${X}x${Y}                                \
    -f $WORKDIR/hobbit_${OPTION}.root:hc        \
    -> "index"                                 \
    -\^ "\chi^{2}/NDF"                          \
    -T ""                                       \
    -o chi2.$FORMAT                             $BATCH    
 
JPlot2D \
    -w ${X}x${Y}                                \
    -f $WORKDIR/hobbit_${OPTION}.root:detector  \
    -> "string"                                \
    -< "floor"                                 \
    -\^ "#Deltat [ns]"                          \
    -T ""                                       \
    -O COLZ                                     \
    -p $PALETTE                                 \
    -o detector.$FORMAT                         $BATCH
 
if [[ "$OPTION" == module ]]; then
 
    typeset -Z 4 STRING
    typeset -Z 2 FLOOR
 
    set_variable  FIRST_FLOOR  1
 
    for STRING in $STRINGS[*]; do
 
            echo -n "Creating graphics for string $STRING.."
 
            for (( FLOOR = $FIRST_FLOOR; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do
 
            eval MODULE=\${STRING_${(l:4::0::0:)STRING}\[$(($FLOOR))\]:--1}
 
            JPlot1D \
                        -f $WORKDIR/hobbit_${OPTION}.root:${MODULE}.1D      \
                        -> "#Deltat [s]"                                   \
                        -\^ "number of events [a.u.]"                       \
                        -T "${STRING}.${FLOOR}"                             \
                        -o ${TMPDIR:-/tmp}/h1_${STRING}_${FLOOR}.$FORMAT    $BATCH
            done
 
            montage \
            -tile 6x3                                               \
            -geometry +0+0                                          \
            ${TMPDIR:-/tmp}/h1_${STRING}_{01..18}.$FORMAT           \
            $WORKDIR/${STRING}.$FORMAT                              >& /dev/null
 
            echo " -> $WORKDIR/${STRING}.$FORMAT"
 
            rm -f ${TMPDIR:-/tmp}/h1_${STRING}_*.$FORMAT
    done
fi
 
if [[ "$OPTION" == string ]]; then
 
    for STRING in $STRINGS[*]; do
 
            echo -n "Creating graphics for string $STRING.."
 
        JPlot1D \
                -f $WORKDIR/hobbit_${OPTION}.root:\^${STRING}.1D    \
                -> "#Deltat [s]"                                   \
                -\^ "number of events [a.u.]"                       \
                -T "${STRING}"                                      \
                -o $WORKDIR/${STRING}.$FORMAT                       $BATCH
 
            echo " -> $WORKDIR/${STRING}.$FORMAT"
    done
 
    typeset -i NX
    typeset -i NY
 
    let "NY = sqrt(${#STRINGS}) * 0.75 + 0.25"
    let "NX = (${#STRINGS} + $NY - 1)/ $NY"
 
    montage \
        -tile ${NX}x${NY}                        \
        -geometry +0+0                           \
        $WORKDIR/${^STRINGS}.$FORMAT             \
        $WORKDIR/strings.$FORMAT                 >& /dev/null
fi