software/JTrigger/JTriggerEfficiencyRunByRun.sh

Go to the documentation of this file.

#!/usr/bin/env zsh
#
# \author mdejong
#
script=${0##*/}
 
# ------------------------------------------------------------------------------------------
#
#                Script to run JTriggerEfficiency in run-by-run mode.
#
# ------------------------------------------------------------------------------------------
 
if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
 
source $JPP_DIR/setenv.sh $JPP_DIR
 
set_variable:  DEBUG                 TRIGGEREFFICIENCY_DEBUG                    1
set_variable:  WORKDIR               TRIGGEREFFICIENCY_WORKDIR                  ./
set_variable:  BACKGROUND_HZ         TRIGGEREFFICIENCY_BACKGROUND_HZ            `getK40Rates`
set_variable:  SEED                  TRIGGEREFFICIENCY_SEED                     0
set_variable:  NUMBER_OF_TIMESLICES  TRIGGEREFFICIENCY_NUMBER_OF_TIMESLICES     0
set_variable:  FACTOR                TRIGGEREFFICIENCY_FACTOR                   1.0
set_variable:  SAMPLER               TRIGGEREFFICIENCY_SAMPLER                  "100 1000"
set_variable+  OPTION                TRIGGEREFFICIENCY_TRIGGERED_EVENTS_ONLY    -O
set_variable+  DISABLE_TURBOT        TRIGGEREFFICIENCY_DISABLE_TURBOT            Y
 
if do_usage $*; then
    usage "$script <detector file> <detector file> (input file)+ <output file> <DAQ file> <PMT parameters file>"\
          "\nAuxiliary script to trigger Monte Carlo events."
fi
 
if (( $# >= 6 )); then
    set_variable  PMT_FILE     $argv[-1]
    set_variable  DAQ_FILE     $argv[-2]
    set_variable  OUTPUT_FILE  $argv[-3]
    set_array     INPUT_FILES  $argv[3,-4]
    set_variable  DETECTORB    $argv[2]
    set_variable  DETECTORA    $argv[1]
else
    fatal "Wrong number of arguments."
fi
 
timer_start
 
JPrintTree -f $DAQ_FILE -@ "type = JDAQSummaryslice" -k number_of_entries  |  read N
 
set_variable   RUNBYRUN             "file=$DAQ_FILE; sampler=${SAMPLER%% *} $(($N / 2))"
 
set_variable   DETECTORA_2          `mktemp $WORKDIR/${${DETECTORA:t}:r}_XXXXXX.datx`
set_variable   DETECTORB_2          `mktemp $WORKDIR/${${DETECTORB:t}:r}_XXXXXX.datx`
set_variable   PMT_FILE_2           `mktemp $WORKDIR/PMT_XXXXXX.txt`
 
JConvertDetectorFormat  -a ${DETECTORA}  -o ${DETECTORA_2}
JConvertDetectorFormat  -a ${DETECTORB}  -o ${DETECTORB_2}
 
 
# Procedure to determine optical modules with out-sync-problem.
# The given detector file is accordingly updated.
 
if [[ "$DISABLE_TURBOT" != "Y" ]]; then
 
    JTurbot \
        -f ${DAQ_FILE}                \
        -a ${DETECTORA_2}             \
        -A                            \
        -d ${DEBUG}                   \
        -N ${NUMBER_OF_TIMESLICES}    \
        --!
 
    CHECK_EXIT_CODE
 
    timer_lap
fi
 
 
# Procedure to determine Jpp version used during data taking as default handling of UDP packet losses has changed.
# The given detector file is accordingly updated.
 
JPrintMeta -f ${DAQ_FILE} -k GIT                                     | read     DAQ_VERSION
 
echo ${(s/./)DAQ_VERSION}                                            | read     DAQ_MAJOR DAQ_MINOR DAQ_PATCH
 
if [[ "$DAQ_MAJOR" != [0-9][0-9]* ]] || (( $DAQ_MAJOR <= 12 )); then # Jpp-version dependence
 
    notice "Set UDP counter and trailer disable."
 
    JEditDetector \
        -a ${DETECTORB_2}                   \
        -P "-1 -1 set UDP_COUNTER_DISABLE"  \
        -P "-1 -1 set UDP_TRAILER_DISABLE"  \
        -o ${DETECTORB_2}
 
    CHECK_EXIT_CODE
fi
 
 
JEditPMTParameters \
    -P ${PMT_FILE}                \
    -o ${PMT_FILE_2}              \
    -Q "0 $((1.0 / $FACTOR))"     \
    -d ${DEBUG}                   \
    --!
 
 
JTriggerEfficiency \
    -a ${DETECTORA_2}             \
    -b ${DETECTORB_2}             \
    -f"${INPUT_FILES[*]}"         \
    -o ${OUTPUT_FILE}             \
    -P ${PMT_FILE_2}              \
    -P "QE=${FACTOR}"             \
    ${OPTION}                     \
    -S ${SEED}                    \
    -B "$BACKGROUND_HZ"           \
    -r "${RUNBYRUN}"              \
    -d ${DEBUG}                   \
    --!
 
CHECK_EXIT_CODE
 
timer_lap
 
 
JPrintMeta \
    -f  ${OUTPUT_FILE}
 
JPrintTree \
    -f  ${OUTPUT_FILE}
 
JTriggerMonitor \
    -f  ${OUTPUT_FILE}            \
    -o  /dev/null
 
 
rm -f ${DETECTORA_2}
rm -f ${DETECTORB_2}
rm -f ${PMT_FILE_2}