detector-Zmul:run.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

set_variable:  DEBUG    ACOUSTICS_DEBUG    2
set_variable:  WORKDIR  ACOUSTICS_WORKDIR  ./
set_variable:  FIT      ACOUSTICS_FIT      2

if do_usage $*; then
    usage "$script <string identifier> <detector file> (input file)+"
fi

if (( $# < 3 )); then
    fatal "Wrong number of arguments."
fi

set_variable  STRING              $argv[1]
set_variable  DETECTOR            $argv[2]
set_array     INPUT_FILES         $argv[3,-1]

eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`
eval `JPrintDetector -a $DETECTOR -O SUMMARY`

set_variable  MODULE              `getModule -a $DETECTOR -L "$STRING 0"`

source JAcoustics.sh   $DETECTOR_ID

CHECK_EXIT_CODE

if [[ -z "${STRINGS[(r)$STRING]}" ]]; then
    fatal "Invalid string $STRING; "\
          "possible values: ${STRINGS[*]}"
fi

set_variable  DETECTOR_TXT        $WORKDIR/detectorzmul_${STRING}.txt
set_variable  TMPDIR              $WORKDIR/.$$
mkdir -p     $TMPDIR

for (( Z = -9.0; $Z <= +1.0; Z += 0.1 )); do
    for (( MUL = -0.01; $MUL <= 0.03; MUL += 0.001 )); do

        rm -f $TMPDIR/detector.detx

        JEditDetector \
            -a $DETECTOR                              \
            -k "$STRING"                              \
            -s "$STRING add 0.0 0.0 $Z"               \
            -s "$STRING mul $MUL"                     \
            -o $TMPDIR/detector.detx
        
        rm -f $TMPDIR/katoomba.root
            
        JKatoomba \
            -a $TMPDIR/detector.detx                  \
            -f "$INPUT_FILES[*]"                      \
            -o $TMPDIR/katoomba.root                  \
            -T $WORKDIR/tripod.txt                    \
            -V $WORKDIR/sound_velocity.txt            \
            -M $WORKDIR/mechanics.txt                 \
            -@ $WORKDIR/acoustics_fit_parameters.txt  \
            -F $FIT                                   \
            -u                                        \
            -d $DEBUG --!

        set_array RESULT `JPrintResult -f $TMPDIR/katoomba.root:chi2 -F "GetMean" -F "GetRMS / sqrt(GetEntries)"`

        if (( ${#RESULT} == 2 )); then
            printf "%7.3f %7.3f %7.3f %7.4f\n" $Z $MUL $RESULT[*] >> $DETECTOR_TXT
        else
            error "No result."
        fi
    done
done

rm -rf $TMPDIR