plot-PMTParameters2D.sh

Go to the documentation of this file.

#!/bin/zsh
#
#
# \author mdejong
#
version=1.0
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR


set_variable     DEBUG                  3
set_variable     WORKDIR                `pwd`
set_variable     OUTPUT_FILE            $WORKDIR/pmt_parameters.root
set_variable     DIR                    $JPP_DIR/examples/JDetector/
set_variable     NUMBER_OF_PMTS         31

if ( do_usage $* ); then
    usage "$script <detector file> (PMT parameters file)+"
fi

if (( $# < 2 )); then
    fatal "Wrong number of parameters."
fi

set_variable     DETECTOR                $argv[1]

INPUT_FILES=($argv[2,-1])

$DIR/JPlotPMTParameters2D \
    -a  $DETECTOR       \
    -P "$INPUT_FILES"   \
    -o  $OUTPUT_FILE    \
    -d  $DEBUG --!

# parameters and plot ranges

typeset -A Y_RANGE

Y_RANGE+=(EFFICIENCY   " 0.0   1.5") 
Y_RANGE+=(QE           " 0.0   1.5") 
Y_RANGE+=(gain         " 0.0   1.5") 
Y_RANGE+=(gainSpread   " 0.0   1.0") 
Y_RANGE+=(riseTime_ns  " 0.0  15.0") 
Y_RANGE+=(TTS_ns       "-5.0  +5.0") 
Y_RANGE+=(threshold    " 0.0   1.0") 
Y_RANGE+=(slope        " 0.0  15.0") 
Y_RANGE+=(saturation   " 0.0 250.0") 
Y_RANGE+=(slewing      " 0.0   1.5") 


eval `JPrintDetector -a $DETECTOR -O SUMMARY`

attach getModule -a $DETECTOR

typeset -Z 3 STRING
typeset -Z 2 FLOOR

let XMIN=-0.5
let XMAX=${NUMBER_OF_PMTS}-0.5

for STRING in $STRINGS[*]; do

    for (( FLOOR = $FIRST_FLOOR; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do

        print -u $FD_O "$STRING $FLOOR"

        read MODULE <& $FD_I

        for KEY in ${(k)Y_RANGE}; do

            debug "($STRING,$FLOOR) $KEY"

            JPlot2D \
                -f ${OUTPUT_FILE}:${MODULE}\.${KEY}\$      \
                -z $Y_RANGE[${KEY}]                        \
                -O COLZ                                    \
                -\> "index"                                \
                -\< "PMT"                                  \
                -\^ "$KEY"                                 \
                -T "(${STRING},${FLOOR})"                  \
                -o /tmp/${KEY}_${STRING}_${FLOOR}.gif -B

            JProject2D \
                -f ${OUTPUT_FILE}:${MODULE}\.${KEY}\$      \
                -P X -y "$XMIN $XMAX"                      \
                -o /tmp/project.root

            JScale1D \
                -f /tmp/project.root:\.\*                  \
                -o /tmp/scale.root                         \
                -F "1.0/${NUMBER_OF_PMTS}"

            JPlot1D \
                -f /tmp/scale.root:\.\*                    \
                -y $Y_RANGE[${KEY}]                        \
                -\> "index"                                \
                -\^ "<$KEY>"                               \
                -T "(${STRING},${FLOOR})"                  \
                -o /tmp/P_${KEY}_${STRING}_${FLOOR}.gif -B


        done
    done

    for KEY in ${(k)Y_RANGE}; do

        montage \
            -tile 6x3                       \
            -geometry +0+0                  \
            /tmp/${KEY}_${STRING}_*.gif     \
            $WORKDIR/${KEY}_${STRING}.gif
    done

    for KEY in ${(k)Y_RANGE}; do

        montage \
            -tile 6x3                       \
            -geometry +0+0                  \
            /tmp/P_${KEY}_${STRING}_*.gif   \
            $WORKDIR/P_${KEY}_${STRING}.gif
    done
done

detach