JTuneHV.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author bjung
#
version=1.0
script=${0##*/}

# ------------------------------------------------------------------------------------------------
#
#     Utility script for finding PMT supply voltages corresponding to the nominal gain setting.
#
# ------------------------------------------------------------------------------------------------


if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi


source $JPP_DIR/setenv.sh $JPP_DIR

set_variable     DEBUG            2 
set_variable     NPE              1
set_variable     FIT_RANGE        0.0 -1.0  # Invalid fit-range such that ToT-fit is conducted around histogram maximum (see JFitToT.hh)
set_variable     OUTPUT_DIR       /tmp
set_variable     OUTPUT_JSON      $OUTPUT_DIR/HVtuning.json
set_variable     OUTPUT_ROOT      $OUTPUT_DIR/HVtuning.root
set_variable     FIT_OPTIONS      "RME"
set_variable     PMT_DEFAULT      "%.gain=0.25"
set_variable     SELECTOR         "JDAQTimesliceL0"
set_variable     TESTTYPE         "HV-TUNING-SEA-GAIN-v1"
set_variable     TESTPRODUCT      ""


if ( do_usage $* ); then
    usage "$script <detector file> <input files> [output directory] [json output] [root output] [test type] [test product] [timeslice selector] [default PMT parameter file]"
fi

case $# in
    9) set_variable PMT_DEFAULT   $9;&
    8) set_variable SELECTOR      $8;&
    7) set_variable TESTPRODUCT   $7;&
    6) set_variable TESTTYPE      $6;&
    5) set_variable OUTPUT_ROOT   $5;&
    4) set_variable OUTPUT_JSON   $4;&
    3) set_variable OUTPUT_DIR    $3;&
    2) set_variable INPUT_FILES   $2;
       set_variable DETECTOR_FILE $1;;
    *) fatal "Wrong number of arguments.";;
esac


# Define directories
set_variable     PMT_DIR          $OUTPUT_DIR/PMTfiles
set_variable     K40_DIR          $OUTPUT_DIR/caldata
set_variable     TOT_DIR          $OUTPUT_DIR/fitdata
set_variable     FIG_DIR          $OUTPUT_DIR/figures
set_variable     FAILED_FIG_DIR   $FIG_DIR/failed
set_variable     EXTRAP_FIG_DIR   $FIG_DIR/extrapolations

# Create directories
OUTPUT_DIRS=( $PMT_DIR $K40_DIR $TOT_DIR $FIG_DIR $FAILED_FIG_DIR $EXTRAP_FIG_DIR)
for DIR in $OUTPUT_DIRS; do
    if [[ ! -d ${DIR} ]]; then
        echo "Creating output directory: ${DIR}"
        mkdir -p ${DIR}
    fi
done

# Fit gain-values
HVTUNING_INPUT=""
FILEPATHS=($(echo $INPUT_FILES))
for FILEPATH in "${FILEPATHS[@]}"; do

    set_variable         FILENAME        ${FILEPATH##*/}
    set_variable         PREFIX          ${FILENAME%.*}
    set_variable         DETID           ${${PREFIX#*_}%_*}
    set_variable         RUNID           ${PREFIX##*_}
    if [ -z $PREFIX ] || [ -z $DETID ] || [ -z $RUNID ]; then
        echo "WARNING: $FILEPATH does not contain correct prefix (i.e. KM3NeT_{DETID}_{RUNID}); skip."
        continue;
    fi
    
    set_variable         OUTPUT_PMT      $PMT_DIR/${PREFIX}_PMT.txt
    set_variable         OUTPUT_CALTOT   $K40_DIR/${PREFIX}_calToT.root
    set_variable         OUTPUT_FITTOT   $TOT_DIR/${PREFIX}_fitToT.root

    if ( ! reuse_file $OUTPUT_PMT ); then

        echo "Removing ${OUTPUT_PMT}"
        rm $OUTPUT_PMT

        if [ ! -z $PMT_DEFAULT ]; then
            if [ -f $PMT_DEFAULT ]; then
                cp $PMT_DEFAULT $OUTPUT_PMT
            else
                echo $PMT_DEFAULT > $OUTPUT_PMT
            fi
        fi
    fi

    if (( 1 )); then

        JCalibrateToT \
            -a ${DETECTOR_FILE}         \
            -f ${FILEPATH}              \
            -C ${SELECTOR}              \
            -o ${OUTPUT_CALTOT} --!

    fi


    if (( 1 )); then

        JFitToT \
            -w                          \
            -a ${DETECTOR_FILE}         \
            -f ${OUTPUT_CALTOT}         \
            -o ${OUTPUT_FITTOT}         \
            -P ${OUTPUT_PMT}            \
            -x ${FIT_RANGE}             \
            -O "${FIT_OPTIONS}"         \
            -d ${DEBUG} --!
    fi

    HVTUNING_INPUT+="$RUNID $OUTPUT_FITTOT "
done


# Fit high-voltage values
if (( 1 )); then
    
    set_variable OUTPUT_LOG       "${OUTPUT_DIR}/${OUTPUT_JSON%.*}.log"
    
    JTuneHV \
        -f ${HVTUNING_INPUT}              \
        -O "${OUTPUT_DIR}/${OUTPUT_JSON}" \
        -o "${OUTPUT_DIR}/${OUTPUT_ROOT}" \
        -D ${DETID}                       \
        -T "${TESTTYPE}"                  \
        -P "${TESTPRODUCT}"               \
        -d ${DEBUG} --! 2>&1 | tee ${OUTPUT_LOG}
fi


# Summarize warnings
if (( 1 )); then 
    echo "Summarizing output..."
    
    set_variable OUTPUT_LOG       "${OUTPUT_DIR}/${OUTPUT_JSON%.*}.log"
    set_variable SUMMARY_LOG      "${OUTPUT_DIR}/${OUTPUT_JSON%.*}_summary.log"

    if ( ! reuse_file $SUMMARY_LOG ); then

        if [ -f $SUMMARY_LOG ]; then
            rm $SUMMARY_LOG
        fi
        
        set_variable N_TOTAL          $(grep -c "HAMA" ${OUTPUT_LOG})
        set_variable N_FAILED         $(grep -c "Setting closest values\!" ${OUTPUT_LOG})
        set_variable N_SUCCESS        $(( N_TOTAL - N_FAILED ))
        
        echo "##### Summary log-file                   #####"   >> ${SUMMARY_LOG}
        echo "###   Statistics                           ###"   >> ${SUMMARY_LOG}
        echo "Number of evaluated PMTs:         ${N_TOTAL}"     >> ${SUMMARY_LOG}
        echo "Number of failed evaluations:     ${N_FAILED}"    >> ${SUMMARY_LOG}
        echo "Number of successful evaluations: ${N_SUCCESS}\n" >> ${SUMMARY_LOG}

        set_variable FAILED           ""
        set_variable FAILED_EXTRAP    ""
        set_variable SUCCESS_EXTRAP   ""

        FAILED_SERIAL=()
        FAILED_LOCATION=()
        EXTRAP_SERIAL=()
        EXTRAP_LOCATION=()
        
        while read LINE; do
            if [[ $LINE =~ "WARNING" ]]; then
                if   [[ $LINE =~ "Setting closest values\!" ]];   then
                    FAILED+="$PREVIOUS\n"
                    FAILED_SERIAL+=("${${PREVIOUS##*a.k.a. }% /*}")
                    FAILED_LOCATION+=("${${PREVIOUS##*/ }%)*}")
                elif [[ $LINE =~ "Extrapolation failed" ]]; then
                    FAILED_EXTRAP+="${PREVIOUS}\n"
                    EXTRAP_SERIAL+=("${${PREVIOUS##*a.k.a. }% /*}")
                    EXTRAP_LOCATION+=("${${PREVIOUS##*/ }%)*}")
                elif [[ $LINE =~ "Extrapolation successful" ]]; then
                    read NEXT
                    SUCCESS_EXTRAP+="${PREVIOUS} (HV,G) = (${NEXT})\n"
                    EXTRAP_SERIAL+=("${${PREVIOUS##*a.k.a. }% /*}")
                    EXTRAP_LOCATION+=("${${PREVIOUS##*/ }%)*}")
                fi
            fi

            set_variable PREVIOUS     ${LINE}
        done < $OUTPUT_LOG
        
        echo "###   List of failed evaluations           ###"   >> ${SUMMARY_LOG}
        echo "${FAILED}\n"                                      >> ${SUMMARY_LOG}
        echo "###   List of failed extrapolations        ###"   >> ${SUMMARY_LOG}
        echo "${FAILED_EXTRAP}\n"                               >> ${SUMMARY_LOG}
        echo "###   List of successful extrapolations    ###"   >> ${SUMMARY_LOG}
        echo "${SUCCESS_EXTRAP}\n"                              >> ${SUMMARY_LOG}
    fi

    # Plot (log10|HV|, log10(G))-diagrams for failed evaluations
    if (( 1 )); then
        for INDEX in `seq 1 "${#FAILED_SERIAL[@]}"`; do

            set_variable SERIALID   ${FAILED_SERIAL[$INDEX]}
            set_variable LOCATION   ${FAILED_LOCATION[$INDEX]}

            JPlot1D \
                -f  "${OUTPUT_DIR}/${OUTPUT_ROOT}:${SERIALID}"  \
                -o  "${FAILED_FIG_DIR}/HVxG_${SERIALID}.png"    \
                -x  "2.85 3.18"                                 \
                -y  "-1.0 +0.3"                                 \
                -\> "Log_{10}(|HV| / 1V)"                       \
                -\^ "Log_{10}(G)"                               \
                -T  "${SERIALID} / ${LOCATION}"                 \
                -B -d ${DEBUG} --!
        done

        for INDEX in `seq 1 "${#EXTRAP_SERIAL[@]}"`; do

            set_variable SERIALID   ${EXTRAP_SERIAL[$INDEX]}
            set_variable LOCATION   ${EXTRAP_LOCATION[$INDEX]}

            JPlot1D \
                -f  "${OUTPUT_DIR}/${OUTPUT_ROOT}:${SERIALID}"  \
                -o  "${EXTRAP_FIG_DIR}/HVxG_${SERIALID}.png"    \
                -x  "2.85 3.18"                                 \
                -y  "-1.0 +0.3"                                 \
                -\> "Log_{10}(|HV| / 1V)"                       \
                -\^ "Log_{10}(G)"                               \
                -T  "${SERIALID} / ${LOCATION}"                 \
                -B -d ${DEBUG} --!
        done
    fi
fi

    

# Create transfer file
if (( 0 )); then

    echo "Creating transfer file..."
    set_variable OUTPUT_TRANSFER  "${OUTPUT_DIR}/${OUTPUT_JSON%.*}.transfer"
    
    if ( ! reuse_file $OUTPUT_TRANSFER ); then

        if [ -f $OUTPUT_TRANSFER ]; then
            rm $OUTPUT_TRANSFER
        fi
        
        set_variable CONTENT_STRING   "Content-Disposition: form-data; name="
        set_variable SEPARATOR        "--BLOBLO123"
        
        echo "Username:"
        read USRNAME
        
        echo "Password:"
        read PASSWRD
        
        echo "${SEPARATOR}\n${CONTENT_STRING}\"usr\"\n\n${USRNAME}"                  >> $OUTPUT_TRANSFER
        echo "${SEPARATOR}\n${CONTENT_STRING}\"pwd\"\n\n${PASSWRD}"                  >> $OUTPUT_TRANSFER
        echo "${SEPARATOR}\n${CONTENT_STRING}\"mode\"\n\nsrv"                        >> $OUTPUT_TRANSFER
        echo "${SEPARATOR}\n${CONTENT_STRING}\"jsonfile\"; filename=\"data.json\"\n" >> $OUTPUT_TRANSFER
        
        cat "${OUTPUT_DIR}/${OUTPUT_JSON}" >> $OUTPUT_TRANSFER
        echo "\n${SEPARATOR}"              >> $OUTPUT_TRANSFER
        
        unix2dos $OUTPUT_TRANSFER
    fi
fi