JAcoustics.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#                   Auxiliary script for configuration of acoustics scripts.
#
# ------------------------------------------------------------------------------------------

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

set_variable  ACOUSTICS_DEBUG     ${ACOUSTICS_DEBUG:-2}
set_variable  ACOUSTICS_WORKDIR   ${ACOUSTICS_WORKDIR:-./}

if ( do_usage $* ); then
    usage "$script [<detector identifier>]"
fi

if (( $# >  1 )); then
    fatal "Wrong number of arguments."
fi

if (( $# == 1 )) && [[ "$1" != "--" ]] ; then

    let ID="$1"                                   # Detector identifier

    # Install input files.

    for KEY in tripod hydrophone; do
        if [[ ! -f $ACOUSTICS_WORKDIR/${KEY}.txt && -f  $JPP_LIB/${KEY}_${(l:8::0::0:)ID}.txt ]]; then
            cp  $JPP_LIB/${KEY}_${(l:8::0::0:)ID}.txt  $ACOUSTICS_WORKDIR/${KEY}.txt
        fi
    done

    typeset -A    TRIGGER                         # Event builder parameters.
    typeset -A    PARAMETERS                      # Position calibration parameters.

    case $ID in

        49) VELOCITY="1538.0 -17e-3 -2000.0";     # Sound velocity [m/s], depth dependence [s^-1] and depth [m].

            TRIGGER=(
                Q            0.0
                TMax_s       0.020
                numberOfHits 90);

            PARAMETERS=(
                Tmax_s     300.0
                Nmin         3
                sigma_s     50.0e-6
                stdev       10.0
                mestimator   1);;


        42) VELOCITY="1481.0 -17e-3 -3000.0";     # Sound velocity [m/s], depth dependence [s^-1] and depth [m].

            TRIGGER=(
                Q            0.0
                TMax_s       0.020
                numberOfHits 15);

            PARAMETERS=(
                Tmax_s     300.0
                Nmin         3
                sigma_s     50.0e-6
                stdev       10.0
                mestimator   1);;

        *)  fatal "Invalid argument $*."
    esac
fi


# Print sound velocity conform command line option.
#
function print_velocity()
{
    echo "\"$VELOCITY\""
}


# Print tripod data conform command line option.
#
function print_tripods()
{
    awk 'BEGIN { printf "\"" } END { printf "\"\n" } $1 !~ /^#/ { print $0 }'  $ACOUSTICS_WORKDIR/tripod.txt
}


# Get tripods. 
#
# \param  1      tripod file
# \param  2      associative array
#
function get_tripods()
{
    set_local_variable __FILE__        $1
    set_local_variable __ARRAY__       $2

    while read __line__; do

        if [[ -n "$__line__" && "$__line__" != \#* ]]; then

            echo $__line__ | read __id__ __x__ __y__ __z__

            eval ${__ARRAY__}\[${__id__}\]=\"$__x__ $__y__ $__z__\"
        fi

    done < $__FILE__
}