JTuneHV.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author bjung
#
version=1.0
script=${0##*/}

# ------------------------------------------------------------------------------------------------
#
#     Utility script for finding PMT supply voltages corresponding to the nominal gain setting.
#
# ------------------------------------------------------------------------------------------------


if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi


source $JPP_DIR/setenv.sh $JPP_DIR

set_variable     DEBUG                 ${TUNEHV_DEBUG:-2}
set_variable     FIT_OPTIONS           ${TUNEHV_GAINFIT_OPTIONS:-"RME"}
set_variable     FIT_RANGE             ${TUNEHV_GAINFIT_RANGE:-"0.0 -1.0"}  # Invalid fit-range such that ToT-fit is conducted around histogram maximum (see JFitToT.hh)
set_variable     OUTPUT_FILE           ${TUNEHV_OUTPUT_FILE:-"HVtuning%"}
set_variable     DB_APIVERSION         ${TUNEHV_DB_APIVERSION:-"2.0.0"}
set_variable     DB_TESTTYPE           ${TUNEHV_DB_TESTTYPE:-"HV-TUNING-GAIN-v3"}
set_variable     TIMESLICE_SELECTOR    ${TUNEHV_TIMESLICE_SELECTOR:-"JDAQTimesliceL0"}

set_variable     WORKDIR               /tmp
set_variable     PMT_PARAMETER_FILE    ""

if ( do_usage $* ); then
    usage "$script <detector file> <input files> [output directory] [PMT parameter file]\n"\
          "Note that if more than one input file is specified, all other arguments must be provided."
fi

case $# in
    4) set_variable PMT_PARAMETER_FILE $4;&
    3) set_variable WORKDIR            $3;&
    2) set_array    INPUT_FILES        $2;
       set_variable DETECTOR_FILE      $1;;
    *) set_variable DETECTOR_FILE      $1
       set_array    INPUT_FILES        $argv[2,-3]
       set_variable WORKDIR            $argv[-2]
       set_variable PMT_PARAMETER_FILE $argv[-1]
esac

timer_start


# Define directories

set_variable     PMT_DIR               $WORKDIR/PMTfiles
set_variable     CAL_DIR               $WORKDIR/caldata
set_variable     TOT_DIR               $WORKDIR/fitdata

# Create directories

for DIR in $PMT_DIR $CAL_DIR $TOT_DIR; do

    if [[ ! -d ${DIR} ]]; then
        echo "Creating output directory:\t${DIR}"
        mkdir -p ${DIR}
    fi
done


# Retrieve cookie

JCookie.sh

set_variable             COOKIE          $(cat ~/.km3netdb_cookie)
set_variable             LOGIN           ${${COOKIE#*_}%%_*}
set_variable             LOCATIONID      $(getLocationID -L ${LOGIN})

# Fit gain-values

set_array                RUN_NUMBERS     ""
set_array                OUTPUT_FITS     ""

for INPUT_FILE in ${INPUT_FILES[@]}; do

    set_array            DAQHEADER       $(JPrintDAQHeader -f ${INPUT_FILE})
    set_variable         DETID           ${DAQHEADER[1]}
    set_variable         RUNID           ${DAQHEADER[2]}
    
    if [ -z $RUNID ]; then
        echo "WARNING: header of ${INPUT_FILE}\n"
        echo "does not contain run number; skip."
        continue;
    fi

    set_array            RUN_NUMBERS     ${RUN_NUMBERS[@]} ${RUNID}    
    
    set_variable         FILENAME        ${${INPUT_FILE##*/}%.*}
    set_variable         OUTPUT_PMT      $PMT_DIR/${FILENAME}_PMT.txt
    set_variable         OUTPUT_CALTOT   $CAL_DIR/${FILENAME}_calToT.root
    set_variable         OUTPUT_FITTOT   $TOT_DIR/${FILENAME}_fitToT.root
    set_variable         LOG_FITTOT      $TOT_DIR/${FILENAME}_fitToT.log    
    
    
    if [ ! -z $PMT_PARAMETER_FILE ]; then
        if [ -f $PMT_PARAMETER_FILE ]; then
            cp   $PMT_PARAMETER_FILE   $OUTPUT_PMT
        else
            echo $PMT_PARAMETER_FILE > $OUTPUT_PMT
        fi
    fi
    
    
    if (( 1 )); then

        JCalibrateToT \
            -a ${DETECTOR_FILE}                  \
            -f ${INPUT_FILE}                     \
            -C ${TIMESLICE_SELECTOR}             \
            -o ${OUTPUT_CALTOT} --!
    fi


    if (( 1 )); then

        JFitToT \
            -w                                   \
            -a ${DETECTOR_FILE}                  \
            -f ${OUTPUT_CALTOT}                  \
            -o ${OUTPUT_FITTOT}                  \
            -P ${OUTPUT_PMT}                     \
            -x ${FIT_RANGE}                      \
            -O ${FIT_OPTIONS}                    \
            -d ${DEBUG} --! 2>&1 | tee ${LOG_FITTOT}
    fi
    
    set_array            OUTPUT_FITS     ${OUTPUT_FITS[@]} ${RUNID} ${OUTPUT_FITTOT}
done


# Retrieve high-voltage data

if (( 1 )); then

    JGetInputTuneHV \
        -f "${OUTPUT_FITS[*]}"                   \
        -o ${WORKDIR}/${OUTPUT_FILE/\%/.root}    \
        -a ${DETECTOR_FILE}                      \
        -d ${DEBUG} --! 2>&1 | tee ${WORKDIR}/${OUTPUT_FILE/\%/.log}
fi


# Fit high-voltage values

if (( 1 )); then
    
    JAsciiDB \
        -q upi                                   \
        -@pbs="3.4.2.3"                          \
        -d ${DEBUG} -- > ${WORKDIR}/upi.txt

    timer_stop

    JTuneHV \
        -f ${WORKDIR}/${OUTPUT_FILE/\%/.root}    \
        -o ${WORKDIR}/${OUTPUT_FILE/\%/.json}    \
        -a ${DETECTOR_FILE}                      \
        -b ${WORKDIR}/upi.txt                    \
        -#APIversion=${DB_APIVERSION}            \
        -#testType=${DB_TESTTYPE}                \
        -#login=${LOGIN}                         \
        -#locationID=${LOCATIONID}               \
        -#runNumbers="${RUN_NUMBERS[*]}"         \
        -#elapsedTime=${TIMER}                   \
        -d ${DEBUG} --! 2>&1 | tee -a ${WORKDIR}/${OUTPUT_FILE/\%/.log}

    rm -f ${WORKDIR}/upi.txt
fi


# Print summary

if (( 1 )); then

    JPrintTuneHV \
        -f ${WORKDIR}/${OUTPUT_FILE/\%/.json}    \
        -a ${DETECTOR_FILE}                      \
        -d ${DEBUG} --!
fi