plot-equalizer.sh

Go to the documentation of this file.

#!/bin/zsh
#
#
# \author mdejong
#
version=1.0
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR

set_variable   DEBUG    2      
set_variable   WORKDIR  `pwd`  

if do_usage $*; then
    usage "$script <detector file> (input file)+"
fi

if (( $# < 2 )); then
    fatal "Wrong number of arguments."
fi

set_variable     DETECTOR               $argv[1]
set_array        INPUT_FILES            $argv[2,-1]

eval `JPrintDetector -a $DETECTOR -O SUMMARY`

kill_child_processes_at_exit

attach getModule -a $DETECTOR

for STRING in $STRINGS[*]; do

    rm -f /tmp/H1-${(l:4::0::0:)STRING}_*.gif

    echo -n "Creating graphics for string ${(l:4::0::0:)STRING}:"

    set_variable  FIRST_FLOOR  1

    for (( FLOOR = $FIRST_FLOOR; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do

        echo -n " ${FLOOR}"

        sput $STRING $FLOOR
        sget  MODULE

        JPlot1D \
            -f "${INPUT_FILES//root/root:H1\[${MODULE}\]}"            \
            -y "0.0 10.0"                                             \
            -\> "PMT"                                                 \
            -\^ "rate [Hz]"                                           \
            -T "(${(l:4::0::0:)STRING},${(l:2::0::0:)FLOOR})"         \
            -o /tmp/H1-${(l:4::0::0:)STRING}_${(l:2::0::0:)FLOOR}.gif -B
    done

    montage \
        -tile 6x3                               \
        -geometry +0+0                          \
        /tmp/H1-${(l:4::0::0:)STRING}_*.gif     \
        H1-${(l:4::0::0:)STRING}.gif            >& /dev/null

    echo
done


for STRING in $STRINGS[*]; do

    echo -n "Creating graphics for string ${(l:4::0::0:)STRING}"

    HISTOGRAMS=()

    for INPUT_FILE in $INPUT_FILES[*]; do

        set_variable  TOKEN         ${INPUT_FILE%%/*}
        set_variable  STRING_TXT    /tmp/H0\[${TOKEN}\].txt
        set_variable  STRING_ROOT   /tmp/H0\[${TOKEN}\].root

        rm -f $STRING_TXT $STRING_ROOT

        set_variable  FIRST_FLOOR  1

        for (( FLOOR = $FIRST_FLOOR; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do

            sput $STRING $FLOOR
            sget  MODULE

            set_variable P1 `JPrintResult -f "${INPUT_FILE}:H0\[${MODULE}\]" -F "GetMean"`
            set_variable P2  0.0
            
            printf "%2d %7.3f %7.4f\n" $FLOOR $P1 $P2  >>  $STRING_TXT

        done

        JGraph -f $STRING_TXT -o $STRING_ROOT

        HISTOGRAMS+=("${STRING_ROOT}:.*")

    done

    JPlot1D \
        -f "$HISTOGRAMS[*]"                          \
        -x "0.5 18.5"                                \
        -y "6.0 8.0"                                 \
        -> "floor"                                  \
        -\^ "rate [Hz]"                              \
        -T "${(l:4::0::0:)STRING}"                   \
        -o H0-${(l:4::0::0:)STRING}.gif              #-B
    
    echo

done

detach