JCompareDetector.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author mdejong
#
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#          Utility script to compare two detectors and to create graphics output.
#
# ------------------------------------------------------------------------------------------

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

set_variable   WORKDIR        /tmp
set_variable   DEBUG          1
set_variable:  TIME           PRECISION_TIME          0.01    # [ns]
set_variable:  ANGLE          PRECISION_ANGLE         0.01    # [deg]
set_variable:  POSITION       PRECISION_POSITION      0.01    # [m]
set_variable:  ORIENTATION    PRECISION_ORIENTATION   0.01    # [rad]
set_variable:  FORMAT         GRAPHICS_FORMAT         gif
set_variable+  BATCH          GRAPHICS_BATCH          -B

if do_usage $*; then
    usage "$script <detector file>  <detector file> [<lower floor>-<upper floor>]"\
          "\nIf the range of floors is specified, the first detector file is aligned to the second before the comparison."
fi

case $# in
    3) set_variable  RANGE          $argv[3];&
    2) set_array     DETECTOR       $argv[1] $argv[2];;
    *) fatal "Wrong number of arguments."
esac

if [[ "$RANGE" == [0-9]*"-"[0-9]* ]]; then

    JConvertDetectorFormat \
        -a $DETECTOR[1]                       \
        -o /tmp/detector.datx                 \
        -d $DEBUG

    echo "" > /tmp/tripod.txt 

    JAlignDetector \
        -a /tmp/detector.datx                 \
        -b $DETECTOR[2]                       \
        -AO                                   \
        -r "${RANGE%%-*} ${RANGE##*-}"        \
        -T /tmp/tripod.txt                    \
        -d $DEBUG --!

    DETECTOR[1]=/tmp/detector.datx
fi

JCompareDetector \
    -a $DETECTOR[1]                       \
    -b $DETECTOR[2]                       \
    -p "time        = $TIME"              \
    -p "angle       = $ANGLE"             \
    -p "position    = $POSITION"          \
    -p "orientation = $ORIENTATION"       \
    -o $WORKDIR/detector.root             \
    -d $DEBUG --!

typeset -A HISTOGRAMS

HISTOGRAMS[X2]="#Deltax [m]"
HISTOGRAMS[Y2]="#Deltay [m]"
HISTOGRAMS[Z2]="#Deltaz [m]"
#HISTOGRAMS[R2]="angle [deg]"

for KEY VALUE in ${(@kv)HISTOGRAMS}; do

    JPlot2D \
        -f $WORKDIR/detector.root:${KEY}  \
        -\> "string"                      \
        -\< "floor"                       \
        -\^ "$VALUE"                      \
        -O COLZ                           \
        -T "$KEY"                         \
        -o ${KEY}.$FORMAT                 $BATCH

done

eval `JPrintDetector -a $DETECTOR[1] -O SUMMARY`

for (( i = 1; $i <= ${#STRINGS}; ++i )); do

    set_variable STRING  $STRINGS[$i] 

    let XMIN="$i - 1 - 0.5"
    let XMAX="$i - 1 + 0.5"

    JProject2D \
        -f $WORKDIR/detector.root:Z2      \
        -P Y                              \
        -x "$XMIN $XMAX"                  \
        -o /tmp/py_\[${STRING}\].root     \
        -d 0

done

JPlot1D \
    -f/tmp/py_\[${^STRINGS}\].root:\.\*   \
    -\> "floor"                           \
    -\^ "#Deltaz [m]"                     \
    -x  "0.5 18.5"                        \
    -O "HIST ]["                          \
    -T  ""                                \
    -L BR                                 \
    -o Z1.$FORMAT                         $BATCH