JBallarat.sh

Go to the documentation of this file.

#!/bin/zsh
#
#
# \author mdejong
#
version=1.0
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR

set_variable:  DEBUG      COMPASS_DEBUG      2
set_variable:  WORKDIR    COMPASS_WORKDIR    ./
set_variable:  ANGLE_DEG  COMPASS_ANGLE_DEG  5.0

if do_usage $*; then
    usage "$script <detector file> (run[-run])+ <output file>"\
          "\nAuxiliary script to process AHRS data for dynamic orientation calibration."
fi

if (( $# < 2 )); then
    fatal "Wrong number of parameters."
fi

set_variable     DETECTOR                $argv[1]
set_array        RUNS                    $argv[2,-2]
set_variable     OUTPUT_FILE             $argv[-1]

set_variable     AHRS_CALIBRATION_FILE   $WORKDIR/ahrs_calibration.txt

eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`

typeset -a  INPUT_FILES

for RANGE in $RUNS[*]; do

    for (( RUN = ${RANGE%%-*}; $RUN <= ${RANGE##*-}; RUN += 1 )); do

        set_variable  INPUT_FILE   $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_ahrs.root

        INPUT_FILES+=($INPUT_FILE)

        if [[ ! -f $INPUT_FILE ]]; then

            echo -n "Writing $INPUT_FILE... "
    
            JConvertDB \
                -q "ahrs"                      \
                -@ "detid  = $DETECTOR_ID"     \
                -@ "minrun = $RUN"             \
                -@ "maxrun = $RUN"             \
                -o $INPUT_FILE                 \
                -d $DEBUG --

            echo "OK"
        fi
    done
done

if [[ ! -f $AHRS_CALIBRATION_FILE ]]; then

    JAHRSCalibration \
        -D $DETECTOR_ID                \
        -o $AHRS_CALIBRATION_FILE      \
        -d $DEBUG
fi

timer_start

JBallarat \
    -a  $DETECTOR                                \
    -c  $AHRS_CALIBRATION_FILE                   \
    -f "$INPUT_FILES[*]"                         \
    -o  $OUTPUT_FILE                             \
    -S  $ANGLE_DEG                               \
    -d  $DEBUG --!

timer_stop
timer_print